#// Indicator for TOS
#// © satayev
#indicator("[#ps #mtf] RDT's Real Relative Strength", "RDT's RRS", max_bars_back = 500, timeframe = "5")
# Converted by Sam4Cok@Samer800 - 03/2025
declare lower;
input timeframe1 = AggregationPeriod.DAY;
input timeframe2 = AggregationPeriod.FIFTEEN_MIN;
input timeframe3 = AggregationPeriod.FIVE_MIN;
input Benchmark = "SPY"; # "Benchmark")
input Source = FundamentalType.CLOSE; #, "Source")
input period1 = 5; #, "Length", group = "1 day", tooltip = "How many bars to use for price change calculation?")
input atrPeriod1 = 20; #, "ATR length", group = "1 day", tooltip = "How many bars to use to determine ATR?")
input period2 = 26; #, "Length", group = "15 minute", tooltip = "How many bars? 26 is 1 day")
input atrPeriod2 = 130; #, "ATR length", group = "15 minute", tooltip = "How many bars? 130 is 5 days")
input period3 = 12; #, "Length", group = "5 minute", tooltip = "How many bars? 12 is 1 hour")
input atrPeriod3 = 390; #, "ATR length", group = "5 minute", tooltip = "How many bars? 390 is 5 days")
def na = Double.NaN;
def last = IsNaN(close);
def GAP = GetAggregationPeriod();
def tf1D = Max(GAP, timeframe1);
def tf15 = Max(GAP, timeframe2);
def tf05 = Max(GAP, timeframe3);
#// -- Relative Strength --
script powerIndexCurr {
input src = FundamentalType.CLOSE;
input period = 5;
input atrLength = 20;
input tf = 300000;
def last = IsNaN(close(Period = tf));
def h = if !last then high(Period = tf)[1] else high(Period = tf);
def c = if !last then close(Period = tf)[1] else close(Period = tf);
def l = if !last then low(Period = tf)[1] else low(Period = tf);
def tr = TrueRange(h, c, l)[1];
def source0 = if !last then Fundamental(src, Period = tf)[1] else Fundamental(src, Period = tf);
def source1 = if !last then Fundamental(src, Period = tf)[period+1] else Fundamental(src, Period = tf)[period];
def priceChange = source0 - source1;
def atr = WildersAverage(tr, atrLength);
def powerIndex = priceChange / atr;
plot out = powerIndex;
}
script powerIndex {
input symb = "SPY";
input src = FundamentalType.CLOSE;
input period = 5;
input atrLength = 20;
input tf = 300000;
def last = IsNaN(close(symb, Period = tf));
def h = if !last then high(symb, Period = tf)[1] else high(symb, Period = tf);
def c = if !last then close(symb, Period = tf)[1] else close(symb, Period = tf);
def l = if !last then low(symb, Period = tf)[1] else low(symb, Period = tf);
def tr = TrueRange(h, c, l)[1];
def source0 = if !last then Fundamental(src, symb, tf)[1] else Fundamental(src, symb, tf);
def source1 = if !last then Fundamental(src, symb, tf)[period+1] else Fundamental(src, symb, tf)[period];
def priceChange = source0 - source1;
def atr = WildersAverage(tr, atrLength);
def powerIndex = priceChange / atr;
plot out = powerIndex;
}
def symPI1d = powerIndexCurr(Source, period1, atrPeriod1 , tf1D);
def symPI15m = powerIndexCurr(Source, period2, atrPeriod2, tf15);
def symPI5m = powerIndexCurr(Source, period3, atrPeriod3 , tf05);
#--
def mktPI1d = powerIndex(Benchmark, Source, period1, atrPeriod1 , tf1D);
def mktPI15m = powerIndex(Benchmark, Source, period2, atrPeriod2, tf15);
def mktPI5m = powerIndex(Benchmark, Source, period3, atrPeriod3 , tf05);
def rrs1d = (symPI1d) - (mktPI1d);
def rrs15m = (symPI15m) - (mktPI15m);
def rrs5m = (symPI5m) - (mktPI5m);
plot rs05 = if !last then rrs5m else na;
plot rs15 = if !last then rrs15m else na;
plot rs1D = if !last then rrs1d else na;
plot zero = if !last then 0 else na;
rs1D.SetLineWeight(2);
zero.SetStyle(Curve.SHORT_DASH);
rs05.AssignValueColor(if rrs5m>0 then Color.GREEN else if rrs5m < 0 then Color.RED else Color.GRAY);
rs15.AssignValueColor(if rrs15m>0 then Color.CYAN else if rrs15m < 0 then Color.MAGENTA else Color.GRAY);
rs1D.AssignValueColor(if rrs1d>0 then Color.DARK_GREEN else if rrs1d < 0 then Color.DARK_RED else Color.GRAY);
zero.SetDefaultColor(Color.GRAY);
#-- END of CODE
