#hook_peak_dip_upmove_00
#https://usethinkscript.com/threads/j-hook-emerging-pattern-indicator.15802/
#J hook emerging pattern indicator
#toobit 6/28
#Im new to the forum but would love to know where I can get started to look at scrips for J hook emerging patterns? I see that you can create a script but Im not that good at it for TOS. Is there any area you can point me to so I can do diligence and possibly make an indicator for something as complex as a J hook?
#The J-hook pattern gets its name from the shape it creates on a chart, resembling the letter "J." It consists of three main parts:
#Initial Uptrend: The pattern begins with a strong upward move in the price of an asset. This could be the result of positive news, a breakout from a previous resistance level, or other factors driving buying pressure.
#Pullback/Consolidation: After the initial uptrend, the price retraces or consolidates, forming a downward-sloping curve resembling the letter "J." This pullback can be caused by profit-taking, market corrections, or a decrease in buying pressure.
#Resumption of Uptrend: Once the pullback phase is complete, the price reverses and resumes its upward movement. This breakout from the consolidation phase is often accompanied by increased trading volume, indicating renewed buying interest.
#------------------------
#https://usethinkscript.com/threads/zigzag-high-low-with-supply-demand-zones-for-thinkorswim.172/#post-7048
# define swing low points , robert payne
# modifified by halcyonguy to ignore last bar
#------------------------
def bn = BarNumber();
def na = double.nan;
input length = 4;
def lastBar = HighestAll(if IsNaN(close) then 0 else bn);
def offset = Min(length - 1, lastBar - bn);
input ignore_last_bar = yes;
def ignorelast = if (ignore_last_bar and bn == lastbar) then 0 else 1;
def peak = ignorelast and high > highest(high[1], length - 1) and high == GetValue(highest(high, length), -offset);
def valley = ignorelast and low < Lowest(low[1], length - 1) and low == GetValue(Lowest(low, length), -offset);
#-------------------------------------
input show_dots_on_peaks_valleys = no;
def vert = 0.002;
plot z1 = if show_dots_on_peaks_valleys and peak then high*(1+vert) else na;
z1.SetPaintingStrategy(PaintingStrategy.POINTS);
z1.SetDefaultColor(Color.cyan);
z1.setlineweight(3);
z1.hidebubble();
plot z2 = if show_dots_on_peaks_valleys and valley then low*(1-vert) else na;
z2.SetPaintingStrategy(PaintingStrategy.POINTS);
z2.SetDefaultColor(Color.cyan);
z2.setlineweight(3);
z2.hidebubble();
#--------------------------
# rule 1
# up trend
input up_trend_higher_high_per = 0.04;
input up_trend_min_bars = 3;
def up_per = 100*(high - high[1])/high[1];
def up1 = (high > (high[1] * (1 + (up_trend_higher_high_per/100))));
#def upcnt = sum(up1, 10);
def upcnt = fold i = 0 to 100
with p
while (getvalue(high, i) > (getvalue(high, i+1) * (1 + (up_trend_higher_high_per/100))))
do p + 1;
def rule1_up = (upcnt >= up_trend_min_bars);
plot z3 = if rule1_up and peak then high * 1.001 else na;
z3.SetPaintingStrategy(PaintingStrategy.POINTS);
z3.SetDefaultColor(Color.green);
z3.setlineweight(3);
z3.hidebubble();
#------------------------
# rule2 - cross above rule1 peak
def rule1_peak = if bn == 1 then 0
else if rule1_up then high
else rule1_peak[1];
plot z4 = if isnan(close) then na else if rule1_peak > 0 then rule1_peak else na;
z4.SetDefaultColor(Color.cyan);
def rule2_cross = if close crosses above rule1_peak then 1 else 0;
plot z5 = if rule2_cross then low*0.998 else na;
z5.SetPaintingStrategy(PaintingStrategy.ARROW_UP);
z5.SetDefaultColor(Color.green);
z5.setlineweight(3);
z5.hidebubble();
#--------------------------
input show_all_bubbles = no;
input test1 = no;
addchartbubble(show_all_bubbles or (rule1_up and test1), low*0.998,
up_per + "\n" +
up1 + "\n" +
upcnt
, (if rule1_up and peak then color.yellow else color.gray), no);
#, (if rule1_up and peak then color.yellow else color.gray), no);
#
