vwap

[neyland]

My goal is to have two separate plots VWAP on the same chart. Oh, and yes, I would like the plots to appear throughout the day.

Does anyone have a script I can use on TOS?

Help with VWAP for day trading. Daily one minute (or 2 Min) and previous day VWAP on same chart

 

[SleepyZ]

My goal is to have two separate plots VWAP on the same chart. Oh, and yes, I would like the plots to appear throughout the day.

Does anyone have a script I can use on TOS?

Help with VWAP for day trading. Daily one minute (or 2 Min) and previous day VWAP on same chart

Perhaps this will do what you want.

1. It places 2 versions of the following script on the chart.
2. One's input num_days_to_show, equals 2, the other equals 1;
3. The Vwap from the pervious day will continue to plot on the current day and use the current day's data there to compute the Vwap.

#Anchored_VWAP_Continuous_from_DaysBack_Start_Time

input num_days_to_show  = 2;
input start_time        = 0400;
input numdeviations1    = 1.0;
input numdeviations2    = 2.0;
input numdeviations3    = 3.0;
input show_deviations   = yes;
def ymd                 = GetYYYYMMDD();
def candles  = !IsNaN(close);
def capture  = candles and ymd != ymd[1] ;
def dayCount = CompoundValue(1, if capture then dayCount[1] + 1 else dayCount[1], 0);
def thisDay  = (HighestAll(dayCount) - dayCount) ;
def sec      = SecondsFromTime(start_time);
def time     = sec[1] <= 0 and sec >= 0 or
               sec < sec[1] and sec > 0;
def start = if thisDay <= num_days_to_show - 1 and time then 1 else start[1];
def isperiodrolled = thisDay <= num_days_to_show - 1 and start;


rec volumeSum;
rec volumeVwapSum;
rec volumeVwap2Sum;

if !(isperiodrolled) {
    volumeSum = volume;
    volumeVwapSum = volume * vwap;
    volumeVwap2Sum = volume * Sqr(vwap);
} else {
    volumeSum = CompoundValue(1, volumeSum[1] + volume, volume);
    volumeVwapSum = CompoundValue(1, volumeVwapSum[1] + volume * vwap, volume * vwap);
    volumeVwap2Sum = CompoundValue(1, volumeVwap2Sum[1] + volume * Sqr(vwap), volume * Sqr(vwap));
}
def price = volumeVwapSum / volumeSum;
def deviation = Sqrt(Max(volumeVwap2Sum / volumeSum - Sqr(price), 0));

rec v  = if IsNaN(reference VWAP()) then v[1] else price;

plot VWAP = if isperiodrolled then v else Double.NaN;
plot UpperBand1 = if show_deviations and isperiodrolled then price + numdeviations1 * deviation else Double.NaN;
plot LowerBand1 = if show_deviations and isperiodrolled then price - numdeviations1 * deviation else Double.NaN;

VWAP.SetDefaultColor(Color.CYAN);
VWAP.SetLineWeight(2);
UpperBand1.SetDefaultColor(Color.YELLOW);
LowerBand1.SetDefaultColor(Color.YELLOW);
UpperBand1.SetStyle(Curve.SHORT_DASH);
LowerBand1.SetStyle(Curve.SHORT_DASH);

plot UpperBand2 = if show_deviations and isperiodrolled then price + numdeviations2 * deviation else Double.NaN;
plot LowerBand2 = if show_deviations and isperiodrolled then price - numdeviations2 * deviation else Double.NaN;

UpperBand2.SetDefaultColor(Color.WHITE);
LowerBand2.SetDefaultColor(Color.WHITE);
UpperBand2.SetStyle(Curve.SHORT_DASH);
LowerBand2.SetStyle(Curve.SHORT_DASH);

plot UpperBand3 = if show_deviations and isperiodrolled then price + numdeviations3 * deviation else Double.NaN;
plot LowerBand3 = if show_deviations and isperiodrolled then price - numdeviations3 * deviation else Double.NaN;

UpperBand3.SetDefaultColor(Color.WHITE);
LowerBand3.SetDefaultColor(Color.WHITE);
UpperBand3.SetStyle(Curve.SHORT_DASH);
LowerBand3.SetStyle(Curve.SHORT_DASH);

input showvertical = yes;
AddVerticalLine(showvertical and isperiodrolled != isperiodrolled[1], "", Color.CYAN);

#

 

[neyland]

Thank you.
Help with VWAP script with 3 indicators:
YTD Low and YTD high and just YTD

 

[SleepyZ]

Thank you.
Help with VWAP script with 3 indicators:
YTD Low and YTD high and just YTD

On intraday charts make sure you have enough days displayed to have all 3 points plot
The image shows a 1h 360d chart with the Vwaps plot starting on the day when the condition occurred

#Anchored_VWAP_Continuous_from_YTD_Points

input select_start  = {default YTD, YTDHigh, YTDlow};
input showlabel     = no;
input showverticals = no;

def bn  = BarNumber();
def ymd = GetYYYYMMDD();
def yy  = if GetYear()[1] == GetYear() - 1 and GetYear() then 1  else yy[1] + 1;
def hh  = if yy == 1 then high else if yy > 1 and high > hh[1] then high else hh[1];
def ll  = if yy == 1 then low  else if yy > 1 and low < ll[1]  then low  else  ll[1];

def ytdhigh = HighestAll(if high == hh then ymd else Double.NaN);
def ytdlow  = HighestAll(if bn == 1 then Double.NaN else if low  == ll then ymd else Double.NaN);
def ytd     = HighestAll(if GetYear()[1] != GetLastYear() then ymd else Double.NaN);

AddLabel(showlabel, AsPrice(GetYear()) + " YTD High " + AsText(hh) + " @ " + AsPrice(ytdhigh) , Color.LIGHT_GREEN);
AddLabel(showlabel, AsPrice(GetYear()) + " YTD Low  " + AsText(ll) + " @ " + AsPrice(ytdlow), Color.LIGHT_RED);

AddVerticalLine(showverticals and ymd[1] != ytd and ymd == ytd, AsPrice(ytd) + "    START", Color.WHITE);
AddVerticalLine(showverticals and ymd[1] != ytdhigh and ymd == ytdhigh, AsPrice(ytdhigh) + "   HIGH", Color.WHITE);
AddVerticalLine(showverticals and ymd[1] != ytdlow and ymd == ytdlow,   AsPrice(ytdlow)  + "   LOW" , Color.WHITE);

def start;
input numDevDn  = -2.0;
input numDevUp  = 2.0;
switch (select_start) {
case YTD:
    start = ytd;
case YTDHigh:
    start = ytdhigh;
case YTDlow:
    start = ytdlow;
}

def   anchor    = GetYYYYMMDD() >= start;
def volumeSum   = if anchor then CompoundValue(1, volumeSum[1] + volume, volume) else 0;
def volumeVwapSum  = if anchor then CompoundValue(1, volumeVwapSum[1] + volume * vwap, volume * vwap) else 0;
def volumeVwap2Sum = if anchor then CompoundValue(1, volumeVwap2Sum[1] + volume * Sqr(vwap), volume * Sqr(vwap)) else 0;
def price     = volumeVwapSum / volumeSum;
def deviation = Sqrt(Max(volumeVwap2Sum / volumeSum - Sqr(price), 0));

plot VWAP       = price;
input showbands = yes;
plot UpperBand  = if !showbands then Double.NaN else price + numDevUp * deviation;
plot LowerBand  = if !showbands then Double.NaN else price + numDevDn * deviation;

VWAP.SetDefaultColor(GetColor(0));
UpperBand.SetDefaultColor(GetColor(2));
LowerBand.SetDefaultColor(GetColor(4));

#