VWAP Label with Upper/Lower Bands for ThinkorSwim

[J007RMC]

I want to display the VWAP line and its label to show the current VWAP value on my chart. Is it possible to add VWAP as a label in ThinkorSwim?

#HINT: The Volume-Weighted Average Price (VWAP) is calculated where size x is the volume traded at price x.
# The VWAP plot is accompanied with two bands serving as overbought and oversold levels. The Upper band (overbought level) is plotted a specified number of standard deviations above the VWAP, and the Lower band (oversold level) is plotted similarly below the VWAP. Standard deviations are based upon the difference between the price and VWAP.
input numDevDn = -2.0;
input numDevUp = 2.0;
input timeFrame = {default DAY, WEEK, MONTH};
input show_VWAP_label = yes;
input VWAP_Label_Color_Choice = {default "magenta", "green", "pink", "cyan", "orange", "red", "blue", "gray", "violet"};
input show_VWAP_bands_label = no;
input Bands_Label_Color_Choice = {default "magenta", "green", "pink", "cyan", "orange", "red", "blue", "gray", "violet"};

def cap = getAggregationPeriod();
def errorInAggregation =
timeFrame == timeFrame.DAY and cap >= AggregationPeriod.WEEK or
timeFrame == timeFrame.WEEK and cap >= AggregationPeriod.MONTH;
assert(!errorInAggregation, "timeFrame should be not less than current chart aggregation period");
def yyyyMmDd = getYyyyMmDd();
def periodIndx;
switch (timeFrame) {
case DAY:
periodIndx = yyyyMmDd;
case WEEK:
periodIndx = Floor((daysFromDate(first(yyyyMmDd)) + getDayOfWeek(first(yyyyMmDd))) / 7);
case MONTH:
periodIndx = roundDown(yyyyMmDd / 100, 0);
}
def isPeriodRolled = compoundValue(1, periodIndx != periodIndx[1], yes);
def volumeSum;
def volumeVwapSum;
def volumeVwap2Sum;
if (isPeriodRolled) {
volumeSum = volume;
volumeVwapSum = volume * vwap;
volumeVwap2Sum = volume * Sqr(vwap);
} else {
volumeSum = compoundValue(1, volumeSum[1] + volume, volume);
volumeVwapSum = compoundValue(1, volumeVwapSum[1] + volume * vwap, volume * vwap);
volumeVwap2Sum = compoundValue(1, volumeVwap2Sum[1] + volume * Sqr(vwap), volume * Sqr(vwap));
}
def price = volumeVwapSum / volumeSum;
def deviation = Sqrt(Max(volumeVwap2Sum / volumeSum - Sqr(price), 0));
plot VWAP = price;
VWAP.hide();

 

[costagmbr]

Hi there
How can I get a label that displays the daily, weekly and monthy VWAP values at the top left corner ? Thanks !

 

[BenTen]

@costagmbr This will display the Daily VWAP as a label.

Duplicate it and change the timeframe to Weekly and Monthly.

#
# TD Ameritrade IP Company, Inc. (c) 2011-2021
#

input numDevDn = -2.0;
input numDevUp = 2.0;
input timeFrame = {default DAY, WEEK, MONTH};

def cap = getAggregationPeriod();
def errorInAggregation =
    timeFrame == timeFrame.DAY and cap >= AggregationPeriod.WEEK or
    timeFrame == timeFrame.WEEK and cap >= AggregationPeriod.MONTH;
assert(!errorInAggregation, "timeFrame should be not less than current chart aggregation period");

def yyyyMmDd = getYyyyMmDd();
def periodIndx;
switch (timeFrame) {
case DAY:
    periodIndx = yyyyMmDd;
case WEEK:
    periodIndx = Floor((daysFromDate(first(yyyyMmDd)) + getDayOfWeek(first(yyyyMmDd))) / 7);
case MONTH:
    periodIndx = roundDown(yyyyMmDd / 100, 0);
}
def isPeriodRolled = compoundValue(1, periodIndx != periodIndx[1], yes);

def volumeSum;
def volumeVwapSum;
def volumeVwap2Sum;

if (isPeriodRolled) {
    volumeSum = volume;
    volumeVwapSum = volume * vwap;
    volumeVwap2Sum = volume * Sqr(vwap);
} else {
    volumeSum = compoundValue(1, volumeSum[1] + volume, volume);
    volumeVwapSum = compoundValue(1, volumeVwapSum[1] + volume * vwap, volume * vwap);
    volumeVwap2Sum = compoundValue(1, volumeVwap2Sum[1] + volume * Sqr(vwap), volume * Sqr(vwap));
}
def price = volumeVwapSum / volumeSum;
def deviation = Sqrt(Max(volumeVwap2Sum / volumeSum - Sqr(price), 0));

def VWAP = price;
AddLabel(yes, Concat("VWAP = ", VWAP), color.orange);

 

[brad10281]

I was able to simply copy the VWAP code and create a new VWAP indicator and add a label to the bottom of the code for that indicator and it works fine. Oddly enough I can't use the round function to round it to 2 decimal places. I can round it to 1, 3 or 4 but when I try to round to 2, it rounds it to 1 decimal place.

 

[rad14733]

@brad10281 The Round() function is working as designed... Round() will round to a maximum of n decimals but trims off trailing zeros... While it may seem quirky, that's how it works... Only AsDollars() forces two decimal places...

 

[SleepyZ]

I have the following code to put a VWAP label on my chart but it doesn't seem to work on an intraday timeframe. Any ideas on how to fix this?

AddLabel(yes, "VWAP: " + Round(VWAP (period = AggregationPeriod.DAY),2),CreateColor(255, 102, 255));

Brad, your original code above was the price function VWAP. It appears you wanted the study VWAP, which requires reference VWAP. so Thinkscript can differentiate the two. Try the following to see if it works for you:

AddLabel(1, "VWAP: " + AsText(reference VWAP()), CreateColor(255, 102, 255));

The astext function should also help with your rounding concern as shown in the image

 

[Stock Tradin]

Hello Forum...

So today I was screwing around and trying to clean up my chart/window and it happened! I had an awesome custom label that I can only presume that I got it here somewhere (I only use this site to get ideas, indicators and labels)...I looked everywhere to retrieve it....I searched the forum here, my latest opened shared items on my platform, I went 1 by 1 unlocked indicators in the studies, I checked maybe it was saved under previous workspace etc....I spent close to 3 hours and I am exactly where I was....I'm so ****ed!

Anyways....the label was:

Green and said current price "above VWAP" and it changed to red when price went or was "Below VWAP".

I do have the watchlist indicator/scanner but this label was very accurate.....sometimes when you open a chart, you have to spent time to actually see or find the VWAP and this was in your face! I miss it....I hope someone here has it or can direct me to the exact chat where it was posted? I soooo appreciate it.....it was an awesome tool!!!!!

 

[MerryDay]

def VWAP = reference VWAP()."VWAP"  ;
DefineGlobalColor("LabelRed",  CreateColor(225, 0, 0)) ;
DefineGlobalColor("LabelGreen",  CreateColor(0, 165, 0)) ;
AddLabel(yes, " VWAP = " + Round(VWAP, 2), if VWAP > close then GlobalColor("LabelRed") else GlobalColor("LabelGreen"));