Volume Pressure Demarcations

[npthr33]

im looking to create a script that will allow me to plot a green or red icon of some sort (ideally just a small circle) above or below respectively if specific criteria are met. i dont think im explaining it well enough to chatgpt, or what im looking for just doesnt exist. i am looking to have a green dot plotted above each candle if that candle or the last dominance candle was bullish. if the last dominant candle was bearish i would like for a red dot to be plotted below that candle.

i have added below what ive completed (possibly incorrect) thus far:

# 5 period average volume
Def 5avgvol = average(volume,5);
Def domcan = volume >= 5avgvol;

# Each candle has a certain amount of buying volume and selling volume
Def Buyingvolume = ((close – low) / (high – low)) * volume;
Def Sellingvolume = ((high – close) / (high – low)) * volume;

# Each individual candle is defined as “Bullish” or “Bearish”
Def Bullish = Buyingvolume > Sellingvolume;
Def Bearish = Sellingvolume > Buyingvolume;
Def Neutral = Buyingvolume = Sellingvolume;

# is the prior dominant candle bullish or bearish
Def BullDom = domcan and bullish;
Def BearDom = domcan and bearish;
Def NeutDom = domcan and Neutral;

 

[Svanoy]

# 5 period average volume
Def Fiveavgvol = average(volume,5);
Def domcan = volume >= Fiveavgvol;

# Each candle has a certain amount of buying volume and selling volume
Def Buyingvolume = ((close – low) / (high – low)) * volume;
Def Sellingvolume = ((high – close) / (high – low)) * volume;

# Each individual candle is defined as “Bullish” or “Bearish”
Def Bullish = Buyingvolume > Sellingvolume;
Def Bearish = Sellingvolume > Buyingvolume;
Def Neutral = Buyingvolume == Sellingvolume;

# is the prior dominant candle bullish or bearish
Def BullDom = domcan and bullish;
Def BearDom = domcan and bearish;
Def NeutDom = domcan and Neutral;

Def DotDom = If BullDom then 1 else if BearDom then 0 else DotDom[1];

Plot DotDomPlot = If DotDom then high+ticksize() else low-ticksize();
DotDomPlot.SetPaintingStrategy(PaintingStrategy.POINTS);
DotDomPlot.AssignValueColor(if DotDom then Color.GREEN else Color.RED)

 

[netarchitech]

Updated the script to account for unfilled gaps...

# Specify volume period to generate average volume
Input volume_period = 5;
Def Fiveavgvol = average(volume, volume_period);
Def domcan = volume >= Fiveavgvol;

# Calculate buying/selling volume accounting for unfilled gaps
def H = high;
def C = close;
def L = low;
def V = volume;

# Unfilled Gap down: Use prior close as high
def equivHi = if H < C[1] then C[1] else H;
# Unfilled Gap up: Use prior close as low
def equivLo = if L > C[1] then C[1] else L;

def Buyingvolume = Round(V * (C - equivLo) / (equivHi - equivLo), 0);
def Sellingvolume = Round(V * (equivHi - C) / (equivHi - equivLo), 0);

# Each individual candle is defined as “Bullish” or “Bearish”
Def Bullish = Buyingvolume > Sellingvolume;
Def Bearish = Sellingvolume > Buyingvolume;
Def Neutral = Buyingvolume == Sellingvolume;

# is the prior dominant candle bullish or bearish
Def BullDom = domcan and bullish;
Def BearDom = domcan and bearish;
Def NeutDom = domcan and Neutral;

Def DotDom = If BullDom then 1 else if BearDom then 0 else DotDom[1];

Plot DotDomPlot = If DotDom then high+ticksize() else low-ticksize();
DotDomPlot.SetPaintingStrategy(PaintingStrategy.POINTS);
DotDomPlot.AssignValueColor(if DotDom then Color.GREEN else Color.RED);

Hope this helps...

Good Luck and Good Trading