Typical Price Combo Average with ATR Bands and Matching %TPCA Indicators For ThinkOrSwim

[Jman831]

These are a couple of indicators I came up with that I've been practicing with using the OnDemand feature on ToS. I enjoy it a lot for scalping off of the 5 minute chart in combination with other indicators/averages. Maybe some of you will find use for it.

The first indicator on the price chart I call a "Typical Price Combo Average". I may or may not change the name to "Typical Price Combo Cloud" simply because I turned it into a clouded channel. It combines an exponential average of an exponential average of an exponential average of typical price with an average of your choosing into one average and adds ATR bands to that average. I prefer the default settings that I came up with but it's fully adjustable. The exponential factor of the typical price, the average type of the average you're combining it with, the length of the average you're combining it with, the ATR type, the ATR length, and the ATR "factor" or multiplier are all adjustable.

The second indicator at the bottom of the screenshots below I called a "Typical Price Combo Average Oscillator" but I'm thinking of calling that a "%TPCA" or a "%TPCC" instead because it is similar to the %B indicator for Bollinger Bands, but it gives a percentage based on where the high of the candle is, in relation to the upper half of the cloud if the close is above the Typical Price Combo Average, and it gives a negative percentage based on where the low of the candle is, in relation to the lower half of the cloud if the close is below the Typical Price Combo Average. Basically the red line at the top of the indicator represents the upper cloud line or 100%, the gray line in the middle represents the Typical Price Combo Average itself or 0%, and the green line at the bottom represents the lower cloud line or -100%. The histogram represents the highs and the lows in relation. It's just a way of getting a better look at where the price is in relation to the cloud. Typically when the green line is crossed (especially multiple times in a row), it's a good time to start thinking about buying, and when the red line is crossed, it's a good time to start thinking about selling.

Here are the screenshots I mentioned:

Here's the source code for the Typical Price Combo Average:

input AvgType = averageType.EXPONENTIAL;
input AvgLength = 18;
input Price = close;
input ExponentialFactor = 3;
input ATRType = averageType.SIMPLE;
input ATRLength = 9;
input ATRFactor = 2.0;

def exptypprice = ExpAverage(ExpAverage(ExpAverage((high + low + close) / 3, ExponentialFactor), ExponentialFactor), ExponentialFactor);
def movavg = MovingAverage(AvgType, Price, AvgLength);
def comboavg = (exptypprice + movavg) / 2;

def atr = MovingAverage(ATRType, trueRange(high, close, low), ATRLength);
def upchan = comboavg + atr * ATRFactor;
def lowchan = comboavg - atr * ATRFactor;

plot TypPriceComboAvg = comboavg;
plot UpperChannel = upchan;
plot LowerChannel = lowchan;

AddCloud(upchan, lowchan, color.BLUE);
TypPriceComboAvg.setDefaultColor(color.CYAN);
UpperChannel.setDefaultColor(color.LIGHT_RED);
LowerChannel.setDefaultColor(color.LIGHT_GREEN);

And here's the source code for the %TPCA:

declare lower;

input AvgType = AverageType.EXPONENTIAL;
input AvgLength = 18;
input Price = close;
input ExponentialFactor = 3;
input ATRType = AverageType.SIMPLE;
input ATRLength = 9;
input ATRFactor = 2.0;

def exptypprice = ExpAverage(ExpAverage(ExpAverage((high + low + close) / 3, ExponentialFactor), ExponentialFactor), ExponentialFactor);
def movavg = MovingAverage(AvgType, Price, AvgLength);
def comboavg = (exptypprice + movavg) / 2;

def atr = MovingAverage(ATRType, TrueRange(high, close, low), ATRLength);
def upchan = comboavg + atr * ATRFactor;
def lowchan = comboavg - atr * ATRFactor;

def priceper = if (close - comboavg) / (upchan - comboavg) > 0 then (high - comboavg) / (upchan - comboavg) * 100 else (low - comboavg) / (comboavg - lowchan) * 100;

plot OneHundred = 100;
plot Zero = 0;
plot NegativeOneHundred = -100;
plot PricePercentage = priceper;

OneHundred.setDefaultColor(color.LIGHT_RED);
Zero.setDefaultColor(color.GRAY);
NegativeOneHundred.setDefaultColor(color.LIGHT_GREEN);
PricePercentage.setPaintingStrategy(paintingStrategy.HISTOGRAM);
PricePercentage.assignValueColor(if priceper > 0 then color.GREEN else color.RED);

Hopefully my contribution will find use among some of you. Good luck and happy trading!

Oh and if you come up with any settings that you like especially or have any input on the indicators, please let me know!