TPOProfile study edit

[Naranja187]

Hey guys/gals, does anyone know if the default TPO study can be edited so that when the profile is displayed on extension the POC and the VAhigh/VAlow will extend their lines to the left..? I'd like for that to be the case so those lines will be dynamic instead of me haveing to snap a line on the chart and adjust it manually throughout the day. Thanks!

 

[SleepyZ]

Hey guys/gals, does anyone know if the default TPO study can be edited so that when the profile is displayed on extension the POC and the VAhigh/VAlow will extend their lines to the left..? I'd like for that to be the case so those lines will be dynamic instead of me haveing to snap a line on the chart and adjust it manually throughout the day. Thanks!

Choose yes at the input extendlines_across_chart to extend the expansion lines to the left.

#
# TD Ameritrade IP Company, Inc. (c) 2010-2022
#

input extendlines_across_chart = yes;
input pricePerRowHeightMode = {default AUTOMATIC, TICKSIZE, CUSTOM};
input customRowHeight = 1.0;
input timePerProfile = {default CHART, MINUTE, HOUR, DAY, WEEK, MONTH, "OPT EXP", BAR};
input multiplier = 1;
input onExpansion = yes;
input profiles = 1000;
input showPointOfControl = yes;
input showValueArea = yes;
input valueAreaPercent = 70;
input opacity = 50;

def period;
def yyyymmdd = getYyyyMmDd();
def seconds = secondsFromTime(0);
def month = getYear() * 12 + getMonth();
def day_number = daysFromDate(first(yyyymmdd)) + getDayOfWeek(first(yyyymmdd));
def dom = getDayOfMonth(yyyymmdd);
def dow = getDayOfWeek(yyyymmdd - dom + 1);
def expthismonth = (if dow > 5 then 27 else 20) - dow;
def exp_opt = month + (dom > expthismonth);
switch (timePerProfile) {
case CHART:
    period = 0;
case MINUTE:
    period = floor(seconds / 60 + day_number * 24 * 60);
case HOUR:
    period = floor(seconds / 3600 + day_number * 24);
case DAY:
    period = countTradingDays(Min(first(yyyymmdd), yyyymmdd), yyyymmdd) - 1;
case WEEK:
    period = floor(day_number / 7);
case MONTH:
    period = floor(month - first(month));
case "OPT EXP":
    period = exp_opt - first(exp_opt);
case BAR:
    period = barNumber() - 1;
}

def count = CompoundValue(1, if period != period[1] then (count[1] + period - period[1]) % multiplier else count[1], 0);
def cond = count < count[1] + period - period[1];
def height;
switch (pricePerRowHeightMode) {
case AUTOMATIC:
    height = PricePerRow.AUTOMATIC;
case TICKSIZE:
    height = PricePerRow.TICKSIZE;
case CUSTOM:
    height = customRowHeight;
}

profile tpo = timeProfile("startNewProfile" = cond, "onExpansion" = onExpansion, "numberOfProfiles" = profiles, "pricePerRow" = height, "value area percent" = valueAreaPercent);
def con = compoundValue(1, onExpansion, no);
def pc = if IsNaN(tpo.getPointOfControl()) and con then pc[1] else tpo.getPointOfControl();
def hVA = if IsNaN(tpo.getHighestValueArea()) and con then hVA[1] else tpo.getHighestValueArea();
def lVA = if IsNaN(tpo.getLowestValueArea()) and con then lVA[1] else tpo.getLowestValueArea();

def hProfile = if IsNaN(tpo.getHighest()) and con then hProfile[1] else tpo.getHighest();
def lProfile = if IsNaN(tpo.getLowest()) and con then lProfile[1] else tpo.getLowest();
def plotsDomain = IsNaN(close) == onExpansion;

plot POC = if extendlines_across_chart then highestall(pc) else if plotsDomain then (pc) else Double.NaN;
plot ProfileHigh =  if extendlines_across_chart then highestall(hprofile) else if plotsDomain then hProfile else Double.NaN;
plot ProfileLow =  if extendlines_across_chart then highestall(lprofile) else if plotsDomain then lProfile else Double.NaN;
plot VAHigh =  if extendlines_across_chart then highestall(hva) else if plotsDomain then hVA else Double.NaN;
plot VALow =  if extendlines_across_chart then highestall(lva) else if plotsDomain then lVA else Double.NaN;

DefineGlobalColor("Profile", GetColor(1));
DefineGlobalColor("Point Of Control", GetColor(5));
DefineGlobalColor("Value Area", GetColor(8));

tpo.show(globalColor("Profile"), if showPointOfControl then globalColor("Point Of Control") else color.current, if showValueArea then globalColor("Value Area") else color.current, opacity);
POC.SetDefaultColor(globalColor("Point Of Control"));
POC.SetPaintingStrategy(PaintingStrategy.HORIZONTAL);
VAHigh.SetPaintingStrategy(PaintingStrategy.HORIZONTAL);
VALow.SetPaintingStrategy(PaintingStrategy.HORIZONTAL);
VAHigh.SetDefaultColor(globalColor("Value Area"));
VALow.SetDefaultColor(globalColor("Value Area"));
ProfileHigh.SetPaintingStrategy(PaintingStrategy.HORIZONTAL);
ProfileLow.SetPaintingStrategy(PaintingStrategy.HORIZONTAL);
ProfileHigh.SetDefaultColor(GetColor(3));
ProfileLow.SetDefaultColor(GetColor(3));
ProfileHigh.hide();
ProfileLow.hide();

 

[Naranja187]

Choose yes at the input extendlines_across_chart to extend the expansion lines to the left.

Thanks for the reply, but I don't see that setting anywhere..? Can you provide a screenshot of where you ticked that box? Thanks.

 

[Naranja187]

Also, I think I see what you were trying to tell me. I'm not asking about extending a line I place on the chart. I'm asking about the study itself extending it's own POC and VAhigh/VAlow lines to the left when you enable the study to be displayed on expansion.

 

[SleepyZ]

Thanks for the reply, but I don't see that setting anywhere..? Can you provide a screenshot of where you ticked that box? Thanks.

Click the wheel icon to the right of the study in edit studies.

 

[SleepyZ]

Also, I think I see what you were trying to tell me. I'm not asking about extending a line I place on the chart. I'm asking about the study itself extending it's own POC and VAhigh/VAlow lines to the left when you enable the study to be displayed on expansion.

The code in the study in the link above https://usethinkscript.com/threads/tpoprofile-study-edit.12718/post-108341 automatically extends the poc, vah and val lines. Those are not manually extended lines. The TOS study does not have an option to extend the lines, which is why I needed to add that capability to the original TOS study.

 

[Naranja187]

Yes, I see, that makes sense. What was the syntax you added as an input to get that function..?

 

[Naranja187]

Yeesh... my bad. I see where you posted the code now. I didn't scroll down far enough to see it. Thank you very much, btw.