Time Period Shading

[MarcVUM]

Is there a way to have ToS automatically shade particular time periods on the chart each day? I have found that particular time periods such as 10am to 10:30am produce great trade opportunities but I don't want to have to remember them but would rather be "alerted" by a shade on the chart.

 

[Joshua]

def t =
    secondsFromTime(1000) >= 0
    && secondsFromTime(1030) <= 0;
def pi =
    if(t, double.positive_infinity,double.nan);
def ni =
    if(t, double.negative_infinity,double.nan);
 
    defineglobalColor("shade",color.white);
    addcloud(pi,ni,globalcolor("shade"));

 

[Williasmsmd19]

Thanks for this. Could you also add horizontal lines to indicate the high and low levels?

 

[halcyonguy]

Thanks for this. Could you also add horizontal lines to indicate the high and low levels?

i added code to joshuas code,
..to find the first bar in the time period,
..then loop to find the highest and lowest

#time_period_shading_hilo
#https://usethinkscript.com/threads/time-period-shading.20584/
#Time Period Shading

#Joshua
def t = secondsFromTime(1000) >= 0 && secondsFromTime(1030) <= 0;
def pi = if(t and !isnan(close), double.positive_infinity,double.nan);
def ni = if(t and !isnan(close), double.negative_infinity,double.nan);
 
defineglobalColor("shade",color.white);
addcloud(pi,ni,globalcolor("shade"));

#---------------------
def na = double.nan;
def bn = barnumber();
def big = 99999;
def n = 400;
def hi;
def lo;
if !t[1] and t then {
 hi = fold a = 0 to n
   with b
   while getvalue(t,-a)
   do max(b, getvalue(high,-a));
 lo = fold c = 0 to n
   with d = big
   while getvalue(t,-c)
   do min(d, getvalue(low,-c));
} else if t then {
 hi = hi[1];
 lo = lo[1];
} else {
 hi = 0;
 lo = 0;
}

plot z1 = if hi > 0 then hi else na;
plot z2 = if lo > 0 then lo else na;
#z1.SetDefaultColor(Color.blue);
z1.SetDefaultColor(Color.yellow);
z1.hidebubble();
#z2.SetDefaultColor(Color.blue);
z2.SetDefaultColor(Color.yellow);
z2.hidebubble();
#