Stoch, RSI, MACD bullish

[rajaodu1]

HI Script Guru's,

Can you please help to create a script with the logic as follows. Add

(1) Slow stochastic (%K) with 14 and 3 parameter.
(2) RSI
(3) MACD (12,26,9)

If Slow stochastic is above 50% AND RSI is above 50% and MACD is above signal then candle color turns to GREEN
If slow stochastic is below 50% AND RSI is below 50% and MACD is below signal then candle color turns to RED
If all 3 conditions do not meet, then the candle color turns to Yellow.

Thanks in advance for your help

 

[Svanoy]

plot RSI = reference RSI().RSI;
RSI.Hide();
plot SlowK = reference StochasticFull(80,20,14,3,high,low,close,3,AverageType.SIMPLE).FullK;
SlowK.Hide();
plot MACD = reference MACD(12,26,9,AverageType.EXPONENTIAL).Value;
MACD.Hide();

AssignPriceColor(if SlowK > 50 && RSI > 50 && MACD > 0 then Color.Green else if SlowK< 50 && RSI < 50 && MACD < 0 then Color.Red else Color.Yellow);

 

[rajaodu1]

Wow @Svanoy that was fast. Thank you very much. Let me check them

 

[Ajordan930]

Give this a try.

# === Candle Color + Arrows for Stoch/RSI/MACD Alignment ===

# === INPUTS ===
input colorCandles = yes;
input rsiLength = 14;
input stochKLength = 14;
input stochDLength = 3;
input stochSlowing = 3;
input macdFastLength = 12;
input macdSlowLength = 26;
input macdSignalLength = 9;
input arrowOffsetATRmult = 1.0;
input atrLength = 14;

# === INDICATORS ===

# RSI
def rsi = RSI(rsiLength);

# MACD
def macdValue = MACD(macdFastLength, macdSlowLength, macdSignalLength).Value;
def macdSignal = MACD(macdFastLength, macdSlowLength, macdSignalLength).Avg;

# Slow Stochastic %K
def fullK = StochasticFull(stochKLength, stochDLength, stochSlowing).FullK;

# ATR for offsetting arrows
def atr = Average(TrueRange(high, close, low), atrLength);

# === CONDITIONS ===
def isBullish = fullK > 50 and rsi > 50 and macdValue > macdSignal;
def isBearish = fullK < 50 and rsi < 50 and macdValue < macdSignal;

# === CANDLE COLORING ===
AssignPriceColor(
if !colorCandles then Color.CURRENT
else if isBullish then Color.GREEN
else if isBearish then Color.RED
else Color.YELLOW
);

# === ARROWS ===

plot bullishArrow = if isBullish then low - atr * arrowOffsetATRmult else Double.NaN;
bullishArrow.SetPaintingStrategy(PaintingStrategy.ARROW_UP);
bullishArrow.SetDefaultColor(Color.GREEN);
bullishArrow.SetLineWeight(3);

plot bearishArrow = if isBearish then high + atr * arrowOffsetATRmult else Double.NaN;
bearishArrow.SetPaintingStrategy(PaintingStrategy.ARROW_DOWN);
bearishArrow.SetDefaultColor(Color.RED);
bearishArrow.SetLineWeight(3);

 

[rajaodu1]

Thank you @Ajordan930 Its helpful.