Slope Adaptive Moving Average For ThinkOrSwim

[TG1212]

Author states: This script is inspired from "Vitali Apirine (Stocks & Commodities V.36:5: Adaptive Moving Averages)" and a correction to Dynamic Volume Adaptive Moving Average (MZ DVAMA). I have used slope filtering in order to adapt trends more precisely for better trades.
Slope adaption makes it better for adaptive moving average to detect trend health; making it easier to make decisions based on market strong price momentums, consolidations or breakouts. This isn’t possible with only using simply Adaptive Moving Averages.
Adaptive Moving Averages curve doesn’t change its length based on Slope but it uses slope adaptive color for trend strength detection.

USAGE
To my experience, best way to use AMA is to consider using higher AMA lengths such as 365, 200, 100 or more than 50 for keeping smoothness intact and for Minor and Major lengths within lower range. For example, EMA 6 to 14 are better and faster options to detect recent price changes so I used these two. Similarly, these two lengths can be changed if market is more volatile and you need AMA to react slowly with price volatility.

Here is the original Tradingview code:
https://www.tradingview.com/v/Ies7Tygo/

For the new ThinkOrSwim code, you must scroll down to the next post

 

[samer800]

Hi,

Can somebody please convert this tradingview indicator to thinkscript.

https://www.tradingview.com/v/Ies7Tygo/

Thank you in advance

check the below:

#// Indicator for TOS
#// © MightyZinger
#indicator('Slope Adaptive Moving Average (MZ SAMA)', shorttitle='MZ SAMA', overlay=true)
# Converted by Sam4Cok@Samer800    - 03/2025

input timeframe = AggregationPeriod.MIN; # 'Chart Resolution')
input showSignals = yes; # 'Show Signals on Chart'
input Source = FundamentalType.CLOSE; #, 'Source')
input length = 200;      # 'Adaptive MA Length' // To check for Highest and Lowest value within provided period
input MajorLength = 14;  # 'Major Length' // For Major alpha calculations to detect recent price changes
input MinorLength = 6;   # 'Minor Length' // For Minor alpha calculations to detect recent price changes
input slopePeriod = 34;  # 'Slope Period'
input SlopeInitialRange = 25; # 'Slope Initial Range'
input slopeThreshold = 17;    # 'Consolidation area is when slope below:'

def na = Double.NaN;
def last = IsNaN(close);
def GAP = GetAggregationPeriod();
def tf = Max(GAP, timeframe);
def src = Fundamental(Source, Period = tf);
#//Slope calculation Function to check trend strength i.e. consolidating, choppy, or near reversal
script calcslope {
    input _ma = close;
    input src = close;
    input slope_period = 34;
    input range_1 = 25;
    input h = high;
    input l = low;
    def pi = ATan(1) * 4;
    def highestHigh = Highest(h, slope_period);
    def lowestLow = Lowest(l, slope_period);
    def slope_range = range_1 / (highestHigh - lowestLow) * lowestLow;
    def dt = (_ma[2] - _ma) / src * slope_range;
    def c = Sqrt(1 + dt * dt);
    def xAngle = Round(180 * ACos(1 / c) / pi, 0);
    def maAngle = if dt > 0 then -xAngle else xAngle;
    plot out = maAngle;
}
#//AMA Calculations
script ama {
    input src = close;
    input length = 200;
    input minLength = 6;
    input majLength = 14;
    input h = high;
    input l = low;
    def minAlpha = 2 / (minLength + 1);
    def majAlpha = 2 / (majLength + 1);
    def hh = Highest(h, length + 1);
    def ll = Lowest(l, length + 1);
    def mult = if hh - ll != 0 then AbsValue(2 * src - ll - hh) / (hh - ll) else 0;
    def final = mult * (minAlpha - majAlpha) + majAlpha;
    def final_alpha = Power(final, 2);
    def ema = ExpAverage(src, length);
    def _ama = if IsNaN(_ama[1]) then ema else if !_ama[1] then ema else
               (src - _ama[1]) * final_alpha + _ama[1];
    plot out = _ama;
}
#// SAMA Definition
def sama = ama(src, length, MinorLength, MajorLength, high(Period = tf), low(Period = tf));
#// Slope Calculation for Dynamic Coloring
def slope = calcslope(sama, src, slopePeriod, SlopeInitialRange, high(Period = tf), low(Period = tf));
#// BUY & SELL CONDITIONS AND ALERTS
def _up = slope > slopeThreshold;
def _dn = slope <= - slopeThreshold;
def buy  = _up and !_up[1];
def sell = _dn and !_dn[1];
def sig = if buy and sig[1] <= 0 then 1 else
          if sell and sig[1] >= 0 then -1 else sig[1];
def longsignal  = showSignals and sig ==  1 and (sig[1] !=  1);
def shortsignal = showSignals and sig == -1 and (sig[1] != -1);

#-- plot

plot mzSama = if !last then sama else na;
mzSama.SetLineWeight(2);
mzSama.AssignValueColor(if _up then Color.CYAN else
                        if _dn then Color.MAGENTA else Color.GRAY);

#-- Signals
plot sigUp = close == close(Period = tf) and longsignal;
plot sigDn = close == close(Period = tf) and shortsignal;

sigUp.SetPaintingStrategy(PaintingStrategy.BOOLEAN_WEDGE_DOWN);
sigDn.SetPaintingStrategy(PaintingStrategy.BOOLEAN_WEDGE_UP);
sigUp.SetDefaultColor(Color.CYAN);
sigDn.SetDefaultColor(Color.MAGENTA);


#-- END of CODE