Second highest high within 42 days

[mark91345]

It's easy to draw the "highest high" over a 42-day period (approx 2 months); instead, I want to draw the "second highest" high over a 42-day period. I appreciate the help.

 

[halcyonguy]

It's easy to draw the "highest high" over a 42-day period (approx 2 months); instead, I want to draw the "second highest" high over a 42-day period. I appreciate the help.

this can plot 3 price levels,
the highest price over x past bars
the highest price over x past bars, that is less than highest
the highest price over x past bars, that is less than 2nd highest

default is 42 bars
set chart to day

# second_hi_xdays_00

#https://usethinkscript.com/threads/second-highest-high-within-42-days.15009/
# set chart to day

def na = double.nan;
def bn = barnumber();

input days = 42;
def hi1 = highest(high, days);

def hi2 = fold i2 = 0 to days
 with p2
 do if getvalue(high, i2) < hi1 and getvalue(high, i2) > p2 then getvalue(high, i2) else p2;

def hi3 = fold i3 = 0 to days
 with p3
 do if getvalue(high, i3) < hi2 and getvalue(high, i3) > p3 then getvalue(high, i3) else p3;

input line1 = no;
input line2 = yes;
input line3 = no;

plot z1 = if line1 then hi1 else na;
z1.SetDefaultColor(getColor(1));
z1.hidebubble();
plot z2 = if line2 then hi2 else na;
z2.SetDefaultColor(getColor(2));
z2.hidebubble();
plot z3 = if line3 then hi3 else na;
z3.SetDefaultColor(getColor(3));
z3.hidebubble();


#--------------------------

input test_bubble = no;
addchartbubble(test_bubble, low,
hi1 + "  1\n" +
hi2 + "  2\n" +
hi3 + "  3"
, color.yellow, no);
#