RSI-ADX Strategy For ThinkOrSwim

[Takata]

https://imgur.com/a/LECnQW9

Who can take the challenge to make this a strategy?

 

[Pensar]

@Takata It seems there are no defined parameters for the RSI length or for the exit criteria. Here is a rough draft for you to adjust. Change the exit criteria accordingly.

input RSI_length = 14;
input price = close;
input RSI_avg = AverageType.wilders;
def NetChgAvg = MovingAverage(RSI_avg, price - price[1], RSI_length);
def TotChgAvg = MovingAverage(RSI_avg, AbsValue(price - price[1]), RSI_length);
def ChgRatio = if TotChgAvg != 0 then NetChgAvg / TotChgAvg else 0;
def RSI = 50 * (ChgRatio + 1);
def buy = RSI < RSI[1] and RSI[1] < RSI[2] and RSI[2] < RSI[3];

input ADX_length = 10;
input ADX_avg = AverageType.WILDERS;
def hiDiff = high - high[1];
def loDiff = low[1] - low;
def plusDM = if hiDiff > loDiff and hiDiff > 0 then hiDiff else 0;
def minusDM =  if loDiff > hiDiff and loDiff > 0 then loDiff else 0;
def ATR = MovingAverage(ADX_avg, TrueRange(high, close, low), ADX_length);
def "DI+" = 100 * MovingAverage(ADX_avg, plusDM, ADX_length) / ATR;
def "DI-" = 100 * MovingAverage(ADX_avg, minusDM, ADX_length) / ATR;
def DX = if ("DI+" + "DI-" > 0) then 100 * AbsValue("DI+" - "DI-") / ("DI+" + "DI-") else 0;
def ADX = MovingAverage(ADX_avg, DX, ADX_length);

addOrder(OrderType.buy_to_open, buy and ADX > 20,
tickcolor = color.blue, arrowcolor = color.blue, name = "buy");
addOrder(OrderType.sell_to_close, close > average(close,5),
tickcolor = color.cyan, arrowcolor = color.cyan, name = "xit");

 

[Takata]

@Takata It seems there are no defined parameters for the RSI length or for the exit criteria. Here is a rough draft for you to adjust. Change the exit criteria accordingly.

Thanks that was awesome!!!