Relative Opening Range Stats For ThinkOrSwim

[rlohmeyer]

Thanks to the rather brilliant code by @korygill for locating the first and last bar of the day located HERE and @Svanoy for relative volume located HERE I was able to cobble together a relative opening range stats indicator, which I find helpful in trading the 30 minute opening range, which I find is reliably significant to day trade as support or resistance.

Below is an image of the Relative Opening Range Stats. And below that is the code. Notice on the chart the location of todays Opening Range and how price traded at this area (4/6/2022 Fed Day).

#first bar of day range
#Code Logic: Kory Gill, @korygill
def isRollover = GetYYYYMMDD() != GetYYYYMMDD()[1];
def beforeStart = GetTime() < RegularTradingStart(GetYYYYMMDD());
def afterEnd = GetTime() > RegularTradingEnd(GetYYYYMMDD());
def firstBarOfDay = if (beforeStart[1] == 1 and beforeStart == 0) or (isRollover and beforeStart == 0) then 1 else 0;
input ag = aggregationPeriod.five_MIN;
def rng = if firstBarOfDay then round(high(period = ag)-low(period = ag),2) else rng[1];

#avg range of x days back
#Code Logic @Svanoy
input Number_Of_Values = 5;
def Value = rng;
def NotToday = GetDay() <> GetLastDay();
def cond = (secondsFromTime(0930)==0) and NotToday;
def ValueCount = if cond then ValueCount[1] + 1 else ValueCount[1];
def bar = BarNumber();
def BarNum = if !IsNaN(close) and BarNumber()>0 then bar else BarNum[1];
def VBar = HighestAll(BarNum);
def FinalCount = fold b = 0 to VBar while !IsNaN(GetValue(close, -b)) do GetValue(ValueCount, -b);

def ValueRangeTotal;
if BarNumber() == 0 {ValueRangeTotal = 0;}
else if FinalCount - ValueCount < Number_Of_Values and cond
 {ValueRangeTotal = ValueRangeTotal[1] + Value;
} else {ValueRangeTotal = ValueRangeTotal[1];}

def RangeAverage = if (ValueRangeTotal /  Number_Of_Values) > 0 and (FinalCount - ValueCount) <= 0 then (ValueRangeTotal /  Number_Of_Values) else Double.NaN;

def Average = fold c = 0 to VBar while !IsNaN(GetValue(close, -c)) do GetValue(RangeAverage, -c);

addlabel(yes,"OR Stats: " + " Bar Agg|" + ag/60000 +" Min" + "  Bars In Avg|"+ Number_Of_Values +"  AOR|$"+round(average,2) + "   OR|$" + round(rng,2),color.LIME);

 

[Trend Trader]

Thanks to the rather brilliant code by @korygill for locating the first and last bar of the day located HERE and @Svanoy for relative volume located HERE I was able to cobble together a relative opening range stats indicator, which I find helpful in trading the 30 minute opening range, which I find is reliably significant to day trade as support or resistance.

Below is an image of the Relative Opening Range Stats. And below that is the code. Notice on the chart the location of todays Opening Range and how price traded at this area (4/6/2022 Fed Day).

View attachment 14221

Something wrong with this part of code.

addlabel(yes,"OR Stats: " + " Bar Agg|" + ag/60000 +" Min" + " Bars In Avg|"+ Number_Of_Values +" AOR|$"+round(average,2) + " OR|$" + round(rng,2),color.LIME)

 

[MerryDay]

Something wrong with this part of code.

addlabel(yes,"OR Stats: " + " Bar Agg|" + ag/60000 +" Min" + " Bars In Avg|"+ Number_Of_Values +" AOR|$"+round(average,2) + " OR|$" + round(rng,2),color.LIME)

A "Something wrong" post does not provide enough information to say where you went astray.

This shared chart link has the indicator applied to it successfully.

Import this link to add the chart and indicator to your app: http://tos.mx/v6OloIU
Click here for --> Easiest way to load shared links

 

[sindhu19]

Can this study be converted into watchlist coloumn? i find it very useful to know which stock is "tradeable" based on their volatility in the first 15 mins compare to avg of orb 5 days ago. thank you.

 

[MerryDay]

Can this study be converted into watchlist coloumn? i find it very useful to know which stock is "tradeable" based on their volatility in the first 15 mins compare to avg of orb 5 days ago. thank you.

Sure, you can.
Obviously, you need to create a separate column script for each of the stats in the label.

Here is the script for an AOR column, copy it and create additional script for OR
by changing the last line:

plot AOR = round(average,2);

to:

plot OR = round(rng,2) ;

AOR Watchlist Column Script:

#first bar of day range
#Code Logic: Kory Gill, @korygill
def isRollover = GetYYYYMMDD() != GetYYYYMMDD()[1];
def beforeStart = GetTime() < RegularTradingStart(GetYYYYMMDD());
def afterEnd = GetTime() > RegularTradingEnd(GetYYYYMMDD());
def firstBarOfDay = if (beforeStart[1] == 1 and beforeStart == 0) or (isRollover and beforeStart == 0) then 1 else 0;
input ag = aggregationPeriod.five_MIN;
def rng = if firstBarOfDay then round(high(period = ag)-low(period = ag),2) else rng[1];

#avg range of x days back
#Code Logic @Svanoy
input Number_Of_Values = 5;
def Value = rng;
def NotToday = GetDay() <> GetLastDay();
def cond = (secondsFromTime(0930)==0) and NotToday;
def ValueCount = if cond then ValueCount[1] + 1 else ValueCount[1];
def bar = BarNumber();
def BarNum = if !IsNaN(close) and BarNumber()>0 then bar else BarNum[1];
def VBar = HighestAll(BarNum);
def FinalCount = fold b = 0 to VBar while !IsNaN(GetValue(close, -b)) do GetValue(ValueCount, -b);

def ValueRangeTotal;
if BarNumber() == 0 {ValueRangeTotal = 0;}
else if FinalCount - ValueCount < Number_Of_Values and cond
 {ValueRangeTotal = ValueRangeTotal[1] + Value;
} else {ValueRangeTotal = ValueRangeTotal[1];}

def RangeAverage = if (ValueRangeTotal /  Number_Of_Values) > 0 and (FinalCount - ValueCount) <= 0 then (ValueRangeTotal /  Number_Of_Values) else Double.NaN;

def Average = fold c = 0 to VBar while !IsNaN(GetValue(close, -c)) do GetValue(RangeAverage, -c);
plot AOR = round(average,2);