price crosses close then plots one arrow

[adamsj1267]

### i need help with this code

### this code plots one arrow if true i would like to continue plotting the arrow until its false. thanks

input price = close;
input length = 15;
input averageType = averageType.simple;
input crossingType = {default above, below};

def avg = MovingAverage(averageType, price, length);

plot signal = crosses(price, avg, crossingType == CrossingType.above);

signal.DefineColor("above", GetColor(1));
signal.DefineColor("below", GetColor(1));
signal.AssignValueColor(if crossingType == CrossingType.above then signal.color("above") else signal.color("below"));

signal.SetPaintingStrategy(if crossingType == CrossingType.above
then PaintingStrategy.boolean_arrow_up
else PaintingStrategy.boolean_arrow_dn);

 

[SleepyZ]

### i need help with this code

### this code plots one arrow if true i would like to continue plotting the arrow until its false. thanks

input price = close;
input length = 15;
input averageType = averageType.simple;
input crossingType = {default above, below};

def avg = MovingAverage(averageType, price, length);

plot signal = crosses(price, avg, crossingType == CrossingType.above);

signal.DefineColor("above", GetColor(1));
signal.DefineColor("below", GetColor(1));
signal.AssignValueColor(if crossingType == CrossingType.above then signal.color("above") else signal.color("below"));

signal.SetPaintingStrategy(if crossingType == CrossingType.above
then PaintingStrategy.boolean_arrow_up
else PaintingStrategy.boolean_arrow_dn);

To plot multiple arrows you can simply change the signal to 'greater than' instead of 'crosses above'. You could also use a recursive where the value of the prior bar is used unless in your case, the signal is 'crosses below'

Greater than --->

input price = close;
input length = 15;
input averageType = AverageType.SIMPLE;
input crossingType = {default above, below};

def avg = MovingAverage(averageType, price, length);

plot signal = price > avg;#crosses(price, avg, crossingType == CrossingType.above);
signal.DefineColor("above", GetColor(1));
signal.DefineColor("below", GetColor(1));
signal.AssignValueColor(if crossingType == crossingType.above then signal.Color("above") else signal.Color("below"));
signal.SetPaintingStrategy(PaintingStrategy.BOOLEAN_ARROW_UP);

Recursive ----->

input price = close;
input length = 15;
input averageType = AverageType.SIMPLE;
input crossingType = {default above, below};

def avg = MovingAverage(averageType, price, length);
def signal = if Crosses(price, avg, crossingType == crossingType.above) then 1
             else if Crosses(price, avg, crossingType == crossingType.below) then 0
             else signal[1] ;

plot arrowup = signal;
arrowup.DefineColor("above", GetColor(1));
arrowup.AssignValueColor(arrowup.Color("above"));
arrowup.SetPaintingStrategy(PaintingStrategy.BOOLEAN_ARROW_UP);