Price Average Crossover Signal

[MAC]

Just curious if anyone can help?
Is there a way to just show most recent crossover signals and block the past signals, just to clean chart up a bit
input price = close;
input length = 15;
input averageType = AverageType.Simple;
input crossingType = {default above, below};

def avg = MovingAverage(averageType, price, length);

plot signal = crosses(price, avg, crossingType == CrossingType.above);

signal.DefineColor("Above", GetColor(6));
signal.DefineColor("Below", GetColor(7));
signal.AssignValueColor(if crossingType == CrossingType.above then signal.color("Above") else signal.color("Below"));

signal.SetPaintingStrategy(if crossingType == CrossingType.above
then PaintingStrategy.BOOLEAN_ARROW_UP
else PaintingStrategy.BOOLEAN_ARROW_DOWN);

 

[SleepyZ]

Just curious if anyone can help?
Is there a way to just show most recent crossover signals and block the past signals, just to clean chart up a bit
input price = close;
input length = 15;
input averageType = AverageType.Simple;
input crossingType = {default above, below};

def avg = MovingAverage(averageType, price, length);

plot signal = crosses(price, avg, crossingType == CrossingType.above);

signal.DefineColor("Above", GetColor(6));
signal.DefineColor("Below", GetColor(7));
signal.AssignValueColor(if crossingType == CrossingType.above then signal.color("Above") else signal.color("Below"));

signal.SetPaintingStrategy(if crossingType == CrossingType.above
then PaintingStrategy.BOOLEAN_ARROW_UP
else PaintingStrategy.BOOLEAN_ARROW_DOWN);

Use the input number_signals_displayed = 2; to choose how many signals will plot.

This is done by assigning a count to each cross through the def signals from 1 to 68
Then the def cond then finds the highestall count and reorders the count from 68 to 1. See the yellow bubbles in the first image below that show the original count and then the reordered count.

Then in the arrow plot statement signal, any arrow plots greater than input number_signals_displayed = 2, these are set to not display (double.nan).

addchartBubble(Crosses(price, avg, crossingType == crossingType.above), low, signals + "\n" + cond, color.yellow, no);

Here is the full code with the 2 arrows displayed.

input number_signals_displayed = 2;

input price = close;
input length = 15;
input averageType = AverageType.Simple;
input crossingType = {default above, below};

def avg = MovingAverage(averageType, price, length);

def signals = compoundValue(1,
              if crosses(price, avg, crossingType == CrossingType.above)
              then signals[1] + 1
              else signals[1], 0);
def cond    = highestall(signals) - signals + 1;
plot signal = if cond > number_signals_displayed
              then double.nan
              else crosses(price, avg, crossingType == CrossingType.above);

signal.DefineColor("Above", GetColor(6));
signal.DefineColor("Below", GetColor(7));
signal.AssignValueColor(if crossingType == CrossingType.above then signal.color("Above") else signal.color("Below"));

signal.SetPaintingStrategy(if crossingType == CrossingType.above
then PaintingStrategy.BOOLEAN_ARROW_UP
else PaintingStrategy.BOOLEAN_ARROW_DOWN);