Previous Periods H/L drawn at Candle

cngo · Friday at 12:20 PM

Hi,

looking for some help on modifying on an indicator that would draw the previous period's (month & week) high & low with a horizontal line beginning from that specified candle to the right of the chart.

The current indicator only shows the high and low levels drawn beginning at the current month (second screengrab & code below).

Desired output (white lines there for reference)

Current

Code:

input aggregationPeriod1 = aggregationPeriod.WEEK;
input aggregationPeriod2 = aggregationPeriod.MONTH;
input show_lines   = yes;
input show_bubbles = yes;
input showOnlyLastPeriod = yes;
input length = 1;
input displace = -1;
input bubble_displace = 2;



def prevOpen2 = open(period = AggregationPeriod.WEEK)[-1];
def priceOpen2 = open(period = AggregationPeriod.WEEK);
plot currentOpenWeek = if !IsNaN(prevOpen2) then Double.NaN else priceOpen2;
currentOpenWeek.SetDefaultColor(Color.CYAN);
currentOpenWeek.SetPaintingStrategy(PaintingStrategy.HORIZONTAL);


plot aggPer1High;
plot aggPer1Low;


#fill next next AggPeriod1 with previous period High
def DH1 = HighestAll(if IsNaN(close(period = aggregationPeriod1)[-1]) and !IsNaN(close(period=aggregationPeriod1))
    then high(period = aggregationPeriod1)[length]
    else Double.NaN);

#fill next next AggPeriod1 with previous period Low
def DL1 = LowestAll(if IsNaN(close[-1]) and !IsNaN(close)
    then low(period = aggregationPeriod1)[length]
    else Double.NaN);


if showOnlyLastPeriod and !IsNaN(close(period = aggregationPeriod1)[-1]) {
    aggPer1High = Double.NaN;
    aggPer1Low  = Double.NaN;
} else {
    aggPer1High = DH1;
    aggPer1Low  = DL1;
}

aggPer1High.SetDefaultColor(GetColor(4));
aggPer1High.SetPaintingStrategy(PaintingStrategy.HORIZONTAL);
aggPer1High.SetHiding(!show_lines);
aggPer1Low.SetDefaultColor(GetColor(4));
aggPer1Low.SetPaintingStrategy(PaintingStrategy.HORIZONTAL);
aggPer1Low.SetHiding(!show_lines);

def bn = BarNumber();


#AddChartBubble(show_bubbles and bn == HighestAll(bn - bubble_displace),  aggPer1High, "w " + Astext(aggPer1High), Color.Light_GREEN);
#AddChartBubble(show_bubbles and bn == HighestAll(bn - bubble_displace), aggPer1Low, "w " + Astext(aggPer1Low), Color.light_RED);



def prevOpen1 = open(period = AggregationPeriod.MONTH)[-1];
def priceOpen1 = open(period = AggregationPeriod.MONTH);
plot currentOpenMonth = if !IsNaN(prevOpen1) then Double.NaN else priceOpen1;
currentOpenMonth.SetDefaultColor(Color.YELLOW);
currentOpenMonth.SetPaintingStrategy(PaintingStrategy.HORIZONTAL);


plot aggPer2High;
plot aggPer2Low;

def DH2 = if IsNaN(close(period = aggregationPeriod2)[-1])
    then DH2[1]
    else Highest(high(period = aggregationPeriod2)[-displace], length);


def DL2 = if IsNaN(close(period = aggregationPeriod2)[-1])
    then DL2[1]
    else Lowest(low(period = aggregationPeriod2)[-displace], length);


if showOnlyLastPeriod and !IsNaN(close(period = aggregationPeriod2)[-1])
    {
        aggPer2High = Double.NaN;
        aggPer2Low  = Double.NaN;
    }
    else {
        aggPer2High = DH2;
        aggPer2Low  = DL2;
          }

aggPer2High.SetDefaultColor(GetColor(4));
aggPer2High.SetPaintingStrategy(PaintingStrategy.HORIZONTAL);
aggPer2High.SetHiding(!show_lines);

aggPer2Low.SetDefaultColor(GetColor(4));
aggPer2Low.SetPaintingStrategy(PaintingStrategy.HORIZONTAL);
aggPer2Low.SetHiding(!show_lines);

#

AddChartBubble(
    show_bubbles and bn == HighestAll(bn - bubble_displace),
    aggPer2High,
    "m" + AsText(aggPer2High),
    createColor(0,153,255),yes
);


#AddChartBubble(
#    show_bubbles and bn == HighestAll(bn - bubble_displace),
#    aggPer1High,
#    "w" + AsText(aggPer1High),
#    createColor(0,153,153),no
#);


#AddChartBubble(
#    show_bubbles and bn == HighestAll(bn - bubble_displace),
#    aggPer1low,
#    "w" + AsText(aggPer1Low),
#    createColor(153,0,255),yes
#);


AddChartBubble(
    show_bubbles and bn == HighestAll(bn - bubble_displace),
    aggPer2Low,
    "m " + AsText(aggPer2Low),
    createColor(153,0,255),no
);

BenTen · Friday at 3:19 PM

Is this something you're looking for? https://usethinkscript.com/threads/multi-timeframe-candles-overlay-for-thinkorswim.1425/

halcyonguy · Friday at 10:33 PM

cngo said:

Hi,

looking for some help on modifying on an indicator that would draw the previous period's (month & week) high & low with a horizontal line beginning from that specified candle to the right of the chart.

The current indicator only shows the high and low levels drawn beginning at the current month (second screengrab & code below).

Desired output (white lines there for reference)
View attachment 24588

Current
View attachment 24589

Code:

input aggregationPeriod1 = aggregationPeriod.WEEK;
input aggregationPeriod2 = aggregationPeriod.MONTH;
input show_lines   = yes;
input show_bubbles = yes;
input showOnlyLastPeriod = yes;
input length = 1;
input displace = -1;
input bubble_displace = 2;



def prevOpen2 = open(period = AggregationPeriod.WEEK)[-1];
def priceOpen2 = open(period = AggregationPeriod.WEEK);
plot currentOpenWeek = if !IsNaN(prevOpen2) then Double.NaN else priceOpen2;
currentOpenWeek.SetDefaultColor(Color.CYAN);
currentOpenWeek.SetPaintingStrategy(PaintingStrategy.HORIZONTAL);


plot aggPer1High;
plot aggPer1Low;


#fill next next AggPeriod1 with previous period High
def DH1 = HighestAll(if IsNaN(close(period = aggregationPeriod1)[-1]) and !IsNaN(close(period=aggregationPeriod1))
    then high(period = aggregationPeriod1)[length]
    else Double.NaN);

#fill next next AggPeriod1 with previous period Low
def DL1 = LowestAll(if IsNaN(close[-1]) and !IsNaN(close)
    then low(period = aggregationPeriod1)[length]
    else Double.NaN);


if showOnlyLastPeriod and !IsNaN(close(period = aggregationPeriod1)[-1]) {
    aggPer1High = Double.NaN;
    aggPer1Low  = Double.NaN;
} else {
    aggPer1High = DH1;
    aggPer1Low  = DL1;
}

aggPer1High.SetDefaultColor(GetColor(4));
aggPer1High.SetPaintingStrategy(PaintingStrategy.HORIZONTAL);
aggPer1High.SetHiding(!show_lines);
aggPer1Low.SetDefaultColor(GetColor(4));
aggPer1Low.SetPaintingStrategy(PaintingStrategy.HORIZONTAL);
aggPer1Low.SetHiding(!show_lines);

def bn = BarNumber();


#AddChartBubble(show_bubbles and bn == HighestAll(bn - bubble_displace),  aggPer1High, "w " + Astext(aggPer1High), Color.Light_GREEN);
#AddChartBubble(show_bubbles and bn == HighestAll(bn - bubble_displace), aggPer1Low, "w " + Astext(aggPer1Low), Color.light_RED);



def prevOpen1 = open(period = AggregationPeriod.MONTH)[-1];
def priceOpen1 = open(period = AggregationPeriod.MONTH);
plot currentOpenMonth = if !IsNaN(prevOpen1) then Double.NaN else priceOpen1;
currentOpenMonth.SetDefaultColor(Color.YELLOW);
currentOpenMonth.SetPaintingStrategy(PaintingStrategy.HORIZONTAL);


plot aggPer2High;
plot aggPer2Low;

def DH2 = if IsNaN(close(period = aggregationPeriod2)[-1])
    then DH2[1]
    else Highest(high(period = aggregationPeriod2)[-displace], length);


def DL2 = if IsNaN(close(period = aggregationPeriod2)[-1])
    then DL2[1]
    else Lowest(low(period = aggregationPeriod2)[-displace], length);


if showOnlyLastPeriod and !IsNaN(close(period = aggregationPeriod2)[-1])
    {
        aggPer2High = Double.NaN;
        aggPer2Low  = Double.NaN;
    }
    else {
        aggPer2High = DH2;
        aggPer2Low  = DL2;
          }

aggPer2High.SetDefaultColor(GetColor(4));
aggPer2High.SetPaintingStrategy(PaintingStrategy.HORIZONTAL);
aggPer2High.SetHiding(!show_lines);

aggPer2Low.SetDefaultColor(GetColor(4));
aggPer2Low.SetPaintingStrategy(PaintingStrategy.HORIZONTAL);
aggPer2Low.SetHiding(!show_lines);

#

AddChartBubble(
    show_bubbles and bn == HighestAll(bn - bubble_displace),
    aggPer2High,
    "m" + AsText(aggPer2High),
    createColor(0,153,255),yes
);


#AddChartBubble(
#    show_bubbles and bn == HighestAll(bn - bubble_displace),
#    aggPer1High,
#    "w" + AsText(aggPer1High),
#    createColor(0,153,153),no
#);


#AddChartBubble(
#    show_bubbles and bn == HighestAll(bn - bubble_displace),
#    aggPer1low,
#    "w" + AsText(aggPer1Low),
#    createColor(153,0,255),yes
#);


AddChartBubble(
    show_bubbles and bn == HighestAll(bn - bubble_displace),
    aggPer2Low,
    "m " + AsText(aggPer2Low),
    createColor(153,0,255),no
);

this plots lines from ohlc, from 2 different aggregation times, week and month
can choose which agg period, default is 1 agg bar back

Code:

#agg_prev_hilo_mo_week
#https://usethinkscript.com/threads/previous-periods-h-l-drawn-at-candle.20914/
#Previous Periods H/L drawn at Candle

def na = double.nan;
def bn = barnumber();
def isyr = (GetYear() == GetLastYear());

addlabel(1, " ", color.black);
input agg1 = aggregationPeriod.WEEK;
def agg1min =  agg1/60000;
AddLabel(yes, "Agg1 " + (if agg1min < 60 then (agg1min + " m")
              else if agg1min < 1440 then ((agg1min/60) + " H")
              else if agg1min < 10080 then (agg1min/(60*24) + " D")
              else if agg1 == aggregationPeriod.WEEK then "Wk"
              else if agg1 == aggregationPeriod.MONTH then "Mo"
              else "") + " dot", Color.cyan);

input agg1_bars_back = 1;

def o1 = open(period = agg1);
def h1 = high(period = agg1);
def l1 = low(period = agg1);
def c1 = close(period = agg1);

def o2;
def h2;
def l2;
def c2;
if bn == 1 then {
 o2 = na;
 h2 = na;
 l2 = na;
 c2 = na;
} else if isyr and (getweek() + agg1_bars_back) == GetLastWeek() then {
 o2 = if open == o1 then open else o2[1];
 h2 = if high == h1 then high else h2[1];
 l2 = if low == l1 then low else l2[1];
 c2 = if close == c1 then close else c2[1];
} else {
 o2 = o2[1];
 h2 = h2[1];
 l2 = l2[1];
 c2 = c2[1];
}

input show_agg1_lines = yes;
# lines from candle matching agg price
plot yo2 = if show_agg1_lines then o2 else na;
plot yh2 = if show_agg1_lines then h2 else na;
plot yl2 = if show_agg1_lines then l2 else na;
plot yc2 = if show_agg1_lines then c2 else na;
yo2.SetDefaultColor(Color.cyan);
yh2.SetDefaultColor(Color.light_gray);
yl2.SetDefaultColor(Color.light_gray);
yc2.SetDefaultColor(Color.yellow);
yo2.SetStyle(Curve.short_DASH);
yh2.SetStyle(Curve.short_DASH);
yl2.SetStyle(Curve.short_DASH);
yc2.SetStyle(Curve.short_DASH);


#------------------
input agg2 = aggregationPeriod.MONTH;
def agg2min =  agg2/60000;
AddLabel(yes, "Agg2 " + (if agg2min < 60 then (agg2min + " m")
              else if agg2min < 1440 then ((agg2min/60) + " H")
              else if agg2min < 10080 then (agg2min/(60*24) + " D")
              else if agg2 == aggregationPeriod.WEEK then "Wk"
              else if agg2 == aggregationPeriod.MONTH then "Mo"
              else "") + " dash", Color.cyan);

input agg2_bars_back = 1;

def o3 = open(period = agg2);
def h3 = high(period = agg2);
def l3 = low(period = agg2);
def c3 = close(period = agg2);

def o4;
def h4;
def l4;
def c4;
if bn == 1 then {
 o4 = na;
 h4 = na;
 l4 = na;
 c4 = na;
} else if isyr and (getmonth() + agg2_bars_back) == GetLastmonth() then {
 o4 = if open == o3 then open else o4[1];
 h4 = if high == h3 then high else h4[1];
 l4 = if low == l3 then low else l4[1];
 c4 = if close == c3 then close else c4[1];
} else {
 o4 = o4[1];
 h4 = h4[1];
 l4 = l4[1];
 c4 = c4[1];
}

input show_agg2_lines = yes;
# lines from candle matching agg price
plot yo4 = if show_agg2_lines then o4 else na;
plot yh4 = if show_agg2_lines then h4 else na;
plot yl4 = if show_agg2_lines then l4 else na;
plot yc4 = if show_agg2_lines then c4 else na;
yo4.SetDefaultColor(Color.cyan);
yh4.SetDefaultColor(Color.light_gray);
yl4.SetDefaultColor(Color.light_gray);
yc4.SetDefaultColor(Color.yellow);
yo4.SetStyle(Curve.MEDIUM_DASH);
yh4.SetStyle(Curve.MEDIUM_DASH);
yl4.SetStyle(Curve.MEDIUM_DASH);
yc4.SetStyle(Curve.MEDIUM_DASH);


#------------------
# test stuff

input test_agg1_hilo_lines = no;
plot z1 = if test_agg1_hilo_lines then h1 else na;
plot z2 = if test_agg1_hilo_lines then l1 else na;
z1.SetPaintingStrategy(PaintingStrategy.HORIZONTAL);
z2.SetPaintingStrategy(PaintingStrategy.HORIZONTAL);
z1.SetDefaultColor(Color.cyan);
z2.SetDefaultColor(Color.cyan);
#z1.hidebubble();
#z2.hidebubble();

input test_agg2_hilo_lines = no;
plot z3 = if test_agg2_hilo_lines then h3 else na;
plot z4 = if test_agg2_hilo_lines then l3 else na;
z3.SetPaintingStrategy(PaintingStrategy.HORIZONTAL);
z4.SetPaintingStrategy(PaintingStrategy.HORIZONTAL);
z3.SetDefaultColor(Color.yellow);
z4.SetDefaultColor(Color.yellow);
#z3.hidebubble();
#z4.hidebubble();
#

Thread starter	Similar threads	Forum	Replies	Date
L	Previous day high and low for the last 10 days script with lines on the chart.	Questions	2	Monday at 1:12 PM
J	Previous Bar High Low	Questions	2	Apr 26, 2025
	shows the previous day's premarket high and low instead of the previous day's regular trading hours high/low.	Questions	1	Apr 3, 2025
S	Plot post-market high from previous day	Questions	1	Apr 2, 2025
C	if close of previous candle > $10 and current price <= $10	Questions	3	Apr 1, 2025

Previous Periods H/L drawn at Candle

cngo

New member

halcyonguy

BenTen

Administrative

halcyonguy

Moderator - Expert

Attachments

Similar threads

Not the exact question you're looking for?

Similar threads

Similar threads

The Market Trading Game Changer

Frequently Asked Questions