Repaints Polynomial Regression Channel (PRC) / Quadratic Regression

[Sean_C]

Looking for a PRC for TOS Can anyone give some insight for this?

 

[hockeycoachdoug]

Does anyone have the TOS code to plot this? It would be a great first sort for prices near one of the extremes, then use the Ultimate Breakout indicator on a lower time frame and only take the buys when prices near bottom deviation and slope is positive and sells when at top deviation and negative slope.

 

[codydog]

@hockeycoachdoug -- if you look at the onenote which tos' thinkscript group has, and search for growex, I think you'll find some poly stuff

 

[hockeycoachdoug]

@codydog- thanks for pointing me in a direction, I just couldn't find the direction you were pointing. I tried searching "growex" and "polynomial" on the onenote site I was familiar with with no luck. Can you point me a bit more specifically. Thanks in advance for your help.

Also, @RobertPayne- any chance of a discount to usethinkscript members for your indicators for sale on your site?

 

[codydog]

@hockeycoachdoug - they are putting up his stuff with a "xxx_VM" instead of growex,

no idea why his stuff isnt posted by author as he's done some good stuff

 

[hockeycoachdoug]

codydog- I hate to seem stupid, but I searched for growex, xxx_VM, polynomial and still nothing shows. Am I looking in the right OneNote? I am using this one- ThinkScript Cloud

 

[markos]

@hockeycoachdoug
See if this is what you're looking for. I found it in the Thinkscript Cloud.

# Quadratic Regression
# Robert Payne
# funwiththinkscript.com

input length = 20;
def n = length;
def bn = BarNumber();
def lastBar = HighestAll(if IsNaN(close) then 0 else bn);
def x = bn;
def y = close;

# calculate summation values

def startBar = lastBar - (n - 1);
def sumX = if bn < startBar then 0 else x + sumX[1];
def sumY = if bn < startBar then 0 else y + sumY[1];
def sumX2 = if bn < startBar then 0 else Power(x, 2) + sumX2[1];
def sumX3 = if bn < startBar then 0 else Power(x, 3) + sumX3[1];
def sumX4 = if bn < startBar then 0 else Power(x, 4) + sumX4[1];
def sumXY = if bn < startBar then 0 else x * y + sumXY[1];
def sumX2Y = if bn < startBar then 0 else Power(x, 2) * y + sumX2Y[1];

# intermediary calculations

def xx = sumX2 - Power(sumX, 2) / n;
def xy = sumXY - (sumX * sumY / n);
def xx2 = sumX3 - (sumX2 * sumX / n);
def x2y = sumX2Y - (sumX2 * sumY / n);
def x2x2 = sumX4 - (Power(sumX2, 2) / n);

# calculate coefficients for the quadratic equation

def a0 = (x2y * xx - xy * xx2) / (xx * x2x2 - Power(xx2, 2));
def b0 = (xy * x2x2 - x2y * xx2) / (xx * x2x2 - Power(xx2, 2));
def c0 = sumY / n - b0 * sumX / n - a0 * sumX2 / n;

# for a, b, and c use the final value on the last bar of the chart for all calculations

def a = GetValue(a0, bn - lastBar);
def b = GetValue(b0, bn - lastBar);
def c = GetValue(c0, bn - lastBar);

# calculate and plot the regression curve

plot theCurve = if bn < startBar then Double.NaN else a * Power(x, 2) + b * x + c;
#####

If it works, please post a picture here!

 

[Jonas99]

@Jonas99 How is the TradingView version different from all the COGs, Hursts, and Polynomial Regression already written for ToS?
Given that these are the worst of the worst repainters, how do you use this in your strategy?

I was looking for a PRC but not seeing one? Don Monkey made one but it's not shared. It's a fancy LRC that fits the price better. I am a mean reversion trader so I would use them for range estimates.

https://imgur.com/a/qIQhrpC

 

[MerryDay]

@Jonas99 See it you can make this one work for you.
https://usethinkscript.com/threads/polynomial-regression-channel-prc.1491/#post-33306
(still repaints)

 

[vikram]

@hockeycoachdoug
See if this is what you're looking for. I found it in the Thinkscript Cloud.

# Quadratic Regression
# Robert Payne
# funwiththinkscript.com

input length = 20;
def n = length;
def bn = BarNumber();
def lastBar = HighestAll(if IsNaN(close) then 0 else bn);
def x = bn;
def y = close;

# calculate summation values

def startBar = lastBar - (n - 1);
def sumX = if bn < startBar then 0 else x + sumX[1];
def sumY = if bn < startBar then 0 else y + sumY[1];
def sumX2 = if bn < startBar then 0 else Power(x, 2) + sumX2[1];
def sumX3 = if bn < startBar then 0 else Power(x, 3) + sumX3[1];
def sumX4 = if bn < startBar then 0 else Power(x, 4) + sumX4[1];
def sumXY = if bn < startBar then 0 else x * y + sumXY[1];
def sumX2Y = if bn < startBar then 0 else Power(x, 2) * y + sumX2Y[1];

# intermediary calculations

def xx = sumX2 - Power(sumX, 2) / n;
def xy = sumXY - (sumX * sumY / n);
def xx2 = sumX3 - (sumX2 * sumX / n);
def x2y = sumX2Y - (sumX2 * sumY / n);
def x2x2 = sumX4 - (Power(sumX2, 2) / n);

# calculate coefficients for the quadratic equation

def a0 = (x2y * xx - xy * xx2) / (xx * x2x2 - Power(xx2, 2));
def b0 = (xy * x2x2 - x2y * xx2) / (xx * x2x2 - Power(xx2, 2));
def c0 = sumY / n - b0 * sumX / n - a0 * sumX2 / n;

# for a, b, and c use the final value on the last bar of the chart for all calculations

def a = GetValue(a0, bn - lastBar);
def b = GetValue(b0, bn - lastBar);
def c = GetValue(c0, bn - lastBar);

# calculate and plot the regression curve

plot theCurve = if bn < startBar then Double.NaN else a * Power(x, 2) + b * x + c;
#####

If it works, please post a picture here!

@markos This Quad regression line looks impressive. Any idea how can to make two lines like a channel instead of single line ? higher line touching highs and lower line touching lows

 

[amalia]

## PolynomialQuadraticMA_JQ
## v01.10.2021 version 01 dated October 2021
## based on
## Polynomial Quadratic Moving Average
## Mobius
## V01.09.2021
## JQ adulterations;
## the Y from close to (close + vwap)/2
## added a label identifying Y and n
##
## use with SingleBar VWAP to visualize the single bar VWAP
## mobius' comments and header
#15:33 Mobius: Bored so fooling around with close to zero lag moving averages again.
# Polynomial Quadratic Moving Average
# Mobius
# V01.09.2021

input n = 20; # mobius default was 20
script E
{
input y = 1;
input n = 10;
def t = fold i = 0 to n
with s
do s + getValue(y, i);
plot output = t;
}
def y = (close + VWAP )/2; #mobius y = close
def x = compoundValue(1, x[1] + 1, 1);

def Ex = E(x, n);
def Ey = E(y, n);
def Ex2 = E(sqr(x), n);
def Ex3 = E(power(x, 3), n);
def Ex4 = E(power(x, 4), n);
def Exy = E(x*y, n);
def Ex2y = E(sqr(x)*Y, n);
def Exx = Ex2 - (sqr(Ex)/n);
def Ex_y = Exy - ((Ex * Ey)/n);
def Exx2 = Ex3 - ((Ex2 * Ex)/n);
def Ex2_y = Ex2y - ((Ex2 * Ey)/n);
def Ex2x2 = Ex4 - (sqr(Ex2)/n);

def a = ((Ex2_y * Exx) - (Ex_y * Exx2)) / ((Exx * Ex2x2) - sqr(Exx2));
def b = ((Ex_y * Ex2x2) - (Ex2_y * Exx2)) / ((Exx * Ex2x2) - Sqr(Exx2));
def c = (Ey / n) - (b * (Ex / n)) - (a * (Ex2 / n));

plot poly = (a*sqr(x)) + (b*x) + c;

#label by JQ
addlabel (1, "Polynomial Quadratic Moving Average y=(close +vwap)/2 n=" + n + " ", poly.takevaluecolor());

# End Code Polynomial Quadratic Moving Average