Percent Change within time period

[danimaldasanimal]

I need some help creating a scan or study that can determine percentage change within a period. Specifically, I want a study/scan that can determine if a stock has had a 100% increase within 8 weeks/40 bars, including the percentage increase from low to high within that period. I have been looking throughout the site and can't seem to find code that will work with those parameters.

 

[Joshua]

Currently at that level of increase only, or also include instances where that level of increase occurred within the time period but has since subsided?

 

[danimaldasanimal]

Hi Joshua, I was hoping for the latter of those options

 

[Joshua]

Try this, it can be used as both a scan and study. Let me know how it goes.

input Percent = 100;
input Days = 40;
input Weeks = 8;
def iAgg =
    getAggregationPeriod()
;
def iOffset =
         if iAgg == aggregationPeriod.WEEK then Weeks
    else if iAgg == aggregationPeriod.Day then Days
    else 0
;
def bRange =
    isNaN(close[-iOffset])
;
def bEdge =
    bRange and !isNaN(close[-(iOffset - 1)]) 
;
def dBase =
    if !bRange then Double.NaN
    else if bEdge then low
    else dBase[1]
;
def dTop =
    dBase + (dBase * (Percent / 100)); 
;
def bBreach =
    if bRange and high > dTop then Yes else bBreach[1]
;
def dCloud =
    dBase + 0
;
AddCloud(
    dCloud,dTop,color.cyan
);
assignpriceColor(
    if bBreach then color.cyan
    else color.current
);
Plot Scan = bBreach and BarNumber() > iOffset and bRange;
Scan.hide();

 

[danimaldasanimal]

Try this, it can be used as both a scan and study. Let me know how it goes.

Hi Josh, quick update on the scan. From my observations, the scan works quite effectively, but a lot of the time it only picks up the move after it has happened. I was going to ask for some assistance in the timeframe and picking it up. I'll attach a picture of what I mean, but basically is it possible to change where the box is defined, from low to high within the 40 bars?

 

[Joshua]

This should move it down so that it starts at the lowest low within the range of bars.

input Percent = 100;
input Days = 40;
input Weeks = 8;
def iAgg =
    getAggregationPeriod()
;
def iOffset =
         if iAgg == aggregationPeriod.WEEK then Weeks
    else if iAgg == aggregationPeriod.Day then Days
    else 0
;
def bRange =
    isNaN(close[-iOffset])
;
def bEdge =
    bRange and !isNaN(close[-(iOffset - 1)])
;
def rTrackLow =
    if bEdge then Low
    else if bRange then Min(low,rTrackLow[1])
    else Double.NaN
;
def dSeekLow =
    if bEdge then GetValue(rTrackLow,-(iOffSet -1))
    else if bRange then dSeekLow[1]
    else Double.NaN;
;
def dBase =
    if !bRange then Double.NaN
    else if bEdge then dSeekLow
    else dBase[1]
;
def dTop =
    dBase + (dBase * (Percent / 100));
;
def bBreach =
    if bRange and high > dTop then Yes else bBreach[1]
;
def dCloud =
    dBase + 0
;
AddCloud(
    dCloud,dTop,color.cyan
);
assignpriceColor(
    if bBreach then color.cyan
    else color.current
);
Plot Scan = bBreach and BarNumber() > iOffset and bRange;
Scan.hide();