Opening price horizontal plot

[Kokebaaas]

Hello y'all!

I'm trying to get a script going that plots a horizontal line for the opening print, meaning the open price of the 9:30 am EST candle. I have this code going but it's ploting the line before the candle. Any idea how to have it just at that candle and expanding to the right?

Thanks in advance!

input showOnlyLastPeriod = yes;
def label = yes;

def isOpen = GetTime() crosses above RegularTradingStart(GetYYYYMMDD());
# def isClosed = GetTime() crosses RegularTradingEnd(GetYYYYMMDD());

# def prevClose = close[1];
def firstBarOpen = if isOpen and !isOpen[1] then open else firstBarOpen[1];
# def firstBarClose = if isClosed and !isClosed[1] then open else firstBarClose[1];

plot OpeningPrice;
OpeningPrice.SetPaintingStrategy(PaintingStrategy.LINE);
OpeningPrice.SetDefaultColor(Color.CYAN);
OpeningPrice.SetLineWeight(2);

def shouldHidePlot = showOnlyLastPeriod and !IsNaN(close(period = AggregationPeriod.DAY)[-1]);

if shouldHidePlot {
    OpeningPrice = Double.NaN;
} else {
    OpeningPrice = firstBarOpen;
}

AddLabel(label, "OP: " + AsDollars(OpeningPrice), Color.CYAN);

 

[SleepyZ]

Hello y'all!

I'm trying to get a script going that plots a horizontal line for the opening print, meaning the open price of the 9:30 am EST candle. I have this code going but it's ploting the line before the candle. Any idea how to have it just at that candle and expanding to the right?

Thanks in advance!

input showOnlyLastPeriod = yes;
def label = yes;

def isOpen = GetTime() crosses above RegularTradingStart(GetYYYYMMDD());
# def isClosed = GetTime() crosses RegularTradingEnd(GetYYYYMMDD());

# def prevClose = close[1];
def firstBarOpen = if isOpen and !isOpen[1] then open else firstBarOpen[1];
# def firstBarClose = if isClosed and !isClosed[1] then open else firstBarClose[1];

plot OpeningPrice;
OpeningPrice.SetPaintingStrategy(PaintingStrategy.LINE);
OpeningPrice.SetDefaultColor(Color.CYAN);
OpeningPrice.SetLineWeight(2);

def shouldHidePlot = showOnlyLastPeriod and !IsNaN(close(period = AggregationPeriod.DAY)[-1]);

if shouldHidePlot {
    OpeningPrice = Double.NaN;
} else {
    OpeningPrice = firstBarOpen;
}

AddLabel(label, "OP: " + AsDollars(OpeningPrice), Color.CYAN);

This modification to your code approach (there are various ways to solve this) will limit the plot of the open to when isopen is true. The plot you were seeing before the open in your previous code was actually the extension of the open from the previous day as there was no end defined for it.

I like how you posted your code, a chart image and how you were approaching to solve it. Thank you!

input showOnlyLastPeriod = yes;
def label = yes;

def isOpen = GetTime() >= RegularTradingStart(GetYYYYMMDD()) and GetTime() <= RegularTradingEnd(GetYYYYMMDD());

def firstBarOpen = if isOpen and !isOpen[1] then open else if !isOpen then Double.NaN else firstBarOpen[1];

plot OpeningPrice;
OpeningPrice.SetPaintingStrategy(PaintingStrategy.HORIZONTAL);
OpeningPrice.SetDefaultColor(Color.CYAN);
OpeningPrice.SetLineWeight(2);

def shouldHidePlot = showOnlyLastPeriod and !IsNaN(close(period = AggregationPeriod.DAY)[-1]);

if shouldHidePlot {
    OpeningPrice = Double.NaN;
} else {
    OpeningPrice = firstBarOpen;
}

AddLabel(label, "OP: " + AsDollars(OpeningPrice), Color.CYAN);

 

[sungbeen]

This modification to your code approach (there are various ways to solve this) will limit the plot of the open to when isopen is true. The plot you were seeing before the open in your previous code was actually the extension of the open from the previous day as there was no end defined for it.

I like how you posted your code, a chart image and how you were approaching to solve it. Thank you!

For some reason when I try to use it, it ends up staying at 0, unlike the screenshot you sent.

 

[SleepyZ]

For some reason when I try to use it, it ends up staying at 0, unlike the screenshot you sent.

Just saw this.

Without your providing what chart settings you were using, the above used gettime() to establish the open. Gettime() in this instance needs extended hours displayed to work properly.

These modifications using secondsfromtime(0930) == 0 instead of gettime() should work whether extended hours are displayed or not.

The image below does not display extended hours.

input showOnlyLastPeriod = no;
def label = yes;

def isOpen = secondsfromTime(0930) == 0;#GetTime() >= RegularTradingStart(GetYYYYMMDD()) and GetTime() <= RegularTradingEnd(GetYYYYMMDD());

def firstBarOpen = if isOpen then open else  firstBarOpen[1];#if isOpen and !isOpen[1] then open else if !isOpen then Double.NaN else firstBarOpen[1];

plot OpeningPrice;
OpeningPrice.SetPaintingStrategy(PaintingStrategy.HORIZONTAL);
OpeningPrice.SetDefaultColor(Color.CYAN);
OpeningPrice.SetLineWeight(2);

def shouldHidePlot = showOnlyLastPeriod and !IsNaN(close(period = AggregationPeriod.DAY)[-1]);

if shouldHidePlot {
    OpeningPrice = Double.NaN;
} else {
    OpeningPrice = firstBarOpen;
}

AddLabel(label, "OP: " + AsDollars(OpeningPrice), Color.CYAN);