Only show last 4 hour high, low and close

[SJP07]

I'd like to only have these lines shown for the last full four-hour session. Here's what I have so far:

################FOUR HOUR############################
input Four_Hour_Aggregation = AggregationPeriod.FOUR_HOURS;

plot Four_Hour_h = high(period= Four_Hour_Aggregation);
plot Four_Hour_l = low(period= Four_Hour_Aggregation);
plot Four_Hour_c = close(period= Four_Hour_Aggregation);

Four_Hour_h.SetDefaultColor(Color.Red);
Four_Hour_h.SetPaintingStrategy(PaintingStrategy.HORIZONTAL);
Four_Hour_l.SetLineWeight(3);

Four_Hour_l.SetDefaultColor(Color.Uptick);
Four_Hour_l.SetPaintingStrategy(PaintingStrategy.HORIZONTAL);
Four_Hour_l.SetLineWeight(3);

Four_Hour_c.SetDefaultColor(Color.Orange);
Four_Hour_c.SetPaintingStrategy(PaintingStrategy.HORIZONTAL);
Four_Hour_c.SetLineWeight(3);

 

[SleepyZ]

I'd like to only have these lines shown for the last full four-hour session. Here's what I have so far:

################FOUR HOUR############################
input Four_Hour_Aggregation = AggregationPeriod.FOUR_HOURS;

plot Four_Hour_h = high(period= Four_Hour_Aggregation);
plot Four_Hour_l = low(period= Four_Hour_Aggregation);
plot Four_Hour_c = close(period= Four_Hour_Aggregation);

Four_Hour_h.SetDefaultColor(Color.Red);
Four_Hour_h.SetPaintingStrategy(PaintingStrategy.HORIZONTAL);
Four_Hour_l.SetLineWeight(3);

Four_Hour_l.SetDefaultColor(Color.Uptick);
Four_Hour_l.SetPaintingStrategy(PaintingStrategy.HORIZONTAL);
Four_Hour_l.SetLineWeight(3);

Four_Hour_c.SetDefaultColor(Color.Orange);
Four_Hour_c.SetPaintingStrategy(PaintingStrategy.HORIZONTAL);
Four_Hour_c.SetLineWeight(3);

Try this

################FOUR HOUR############################
input display_x = {default x, all};
input x_number  = 4;
input Four_Hour_Aggregation = AggregationPeriod.FOUR_HOURS;

def count = if close(period = Four_Hour_Aggregation) then count[1] + 1 else count[1];

plot Four_Hour_h = if display_x == display_x.x 
                   then
                       if HighestAll(count) - count <= x_number - 1
                       then high(period = Four_Hour_Aggregation)
                       else Double.NaN
                   else high(period = Four_Hour_Aggregation) ;
plot Four_Hour_l = if display_x == display_x.x 
                   then
                       if HighestAll(count) - count <= x_number - 1
                       then low(period = Four_Hour_Aggregation)
                       else Double.NaN
                   else low(period = Four_Hour_Aggregation) ;
plot Four_Hour_c = if display_x == display_x.x 
                   then
                       if HighestAll(count) - count <= x_number - 1
                       then close(period = Four_Hour_Aggregation)
                       else Double.NaN
                   else close(period = Four_Hour_Aggregation) ;

Four_Hour_h.SetDefaultColor(Color.RED);
Four_Hour_h.SetPaintingStrategy(PaintingStrategy.HORIZONTAL);
Four_Hour_l.SetLineWeight(3);

Four_Hour_l.SetDefaultColor(Color.UPTICK);
Four_Hour_l.SetPaintingStrategy(PaintingStrategy.HORIZONTAL);
Four_Hour_l.SetLineWeight(3);

Four_Hour_c.SetDefaultColor(Color.ORANGE);
Four_Hour_c.SetPaintingStrategy(PaintingStrategy.HORIZONTAL);
Four_Hour_c.SetLineWeight(3);

 

[Mytrades1979]

Try this

can we get this code to only show the last 4 hour not the current?

 

[SleepyZ]

can we get this code to only show the last 4 hour not the current?

The above script has been modified to plot a 'specific', x_number's input of HLC Aggregation lines.
The default is to extend the specific HLC lines to the right.

To only show the last 4 hour and not the current: input display = specific, and input x_number = 2.

#HLC_DisplayLines
input display = {default x, specific, all};
input x_number  = 2;
input Aggregation = AggregationPeriod.FOUR_HOURS;
input Extend_specific = yes;

def count = if close(period = Aggregation) then count[1] + 1 else count[1];

def h = high(period = Aggregation);
def l = low(period = Aggregation);
def c = close(period = Aggregation);

plot Agg_high = if display == display.x
                   then
                       if HighestAll(count) - count <= x_number - 1
                       then h
                       else Double.NaN
                else if display == display.specific
                     then if Extend_specific == yes and HighestAll(count) - count < x_number - 1
                          then HighestAll (if HighestAll(count) - count == x_number - 1
                                           then h
                                           else Double.NaN)
                          else if HighestAll(count) - count == x_number - 1
                               then h
                               else Double.NaN
                else h;

plot Agg_low = if display == display.x
                   then
                       if HighestAll(count) - count <= x_number - 1
                       then l
                       else Double.NaN
               else if display == display.specific
                    then if Extend_specific == yes and HighestAll(count) - count < x_number - 1
                         then HighestAll (if HighestAll(count) - count == x_number - 1
                                          then l
                                          else Double.NaN)
                         else if HighestAll(count) - count == x_number - 1
                              then l
                              else Double.NaN
               else l ;

plot Agg_close = if display == display.x
                    then
                        if HighestAll(count) - count <= x_number - 1
                        then c
                        else Double.NaN
                 else if display == display.specific
                      then if Extend_specific == yes and HighestAll(count) - count < x_number - 1
                           then HighestAll (if HighestAll(count) - count == x_number - 1
                                            then c
                                            else Double.NaN)
                           else if HighestAll(count) - count == x_number - 1
                                then c
                                else Double.NaN
                 else c ;

Agg_high.SetDefaultColor(Color.RED);
Agg_high.SetPaintingStrategy(PaintingStrategy.HORIZONTAL);
Agg_high.SetLineWeight(3);

Agg_low.SetDefaultColor(Color.UPTICK);
Agg_low.SetPaintingStrategy(PaintingStrategy.HORIZONTAL);
Agg_low.SetLineWeight(3);

Agg_close.SetDefaultColor(Color.ORANGE);
Agg_close.SetPaintingStrategy(PaintingStrategy.HORIZONTAL);
Agg_close.SetLineWeight(3);

#

 

[halcyonguy]

can we get this code to only show the last 4 hour not the current?

the last 4 hours and the current 4 hours is the same thing.
do you mean the previous 4 hour period?