OnBalance Volume For ThinkOrSwim

[Mike]

Hi. Can someone help me code or point me in the right direction to create a label for On Balance Volume Closing Above or Below a Moving Average? If closing above color Dark_Green if closing below color Dark_Red. Thanks!

 

[useThinkScript]

On Balance Volume Modified (OBVM) is a variation of On Balance Volume (OBV) that adds a signal line and smooths out the OBV with an exponential moving average.

OBV is a momentum indicator that tracks changes in trading volume to predict price movements and market player strategies.

OBVM can help determine when major market moves might occur, and can be most useful as an entry filter when an instrument is testing a major support or resistance level.

Here are some scripts that provide different options. These studies should further your quest.

Upper Chart Label:

## ########################################################
#ToS OnBalanceVolumeModified
## ########################################################

input signalLength = 10;
input averageType = "exponential" ;

def obvm = OnBalanceVolumeModified().obVM;
def ema = OnBalanceVolumeModified("signal length" = signalLength, "average type" = averageType).Signal; ;

def crossUP = if  obvm crosses above ema  then ema else double.NaN ;
def crossDN = if  obvm crosses below ema  then obvm else double.NaN ;

## ########################################################
# Charting & Formatting

DefineGlobalColor("bull", Color.green) ;
DefineGlobalColor("bear", Color.red) ;
DefineGlobalColor("crossup", Color.cyan) ;
DefineGlobalColor("crossdn", Color.magenta) ;

AddLabel(yes,
if  obvm crosses above ema then "obv cross up!" else
if  obvm crosses below ema then "obv cross down!" else
if obvm > ema then "obv trending above" else " |  obv trending below",

if  obvm crosses above ema then GlobalColor("crossup") else
if  obvm crosses below ema then GlobalColor("crossdn") else
if obvm > ema then GlobalColor("bull") else GlobalColor("bear"));

input paintCandles = yes ;
AssignPriceColor(
if !paintCandles then color.current else
if  obvm crosses above ema then GlobalColor("crossup") else
if  obvm crosses below ema then GlobalColor("crossdn") else
if obvm > ema then GlobalColor("bull") else GlobalColor("bear"));

Lower Chart :

## ########################################################
#ToS OnBalanceVolumeModified
## ########################################################
declare lower;
declare real_size;
DefineGlobalColor("bull", Color.green) ;
DefineGlobalColor("bear", Color.red) ;
DefineGlobalColor("crossup", Color.cyan) ;
DefineGlobalColor("crossdn", Color.magenta) ;

input signalLength = 10;
input averageType = "exponential" ;

plot obvm = OnBalanceVolumeModified().obVM;
plot ema = OnBalanceVolumeModified("signal length" = signalLength, "average type" = averageType).Signal; ;

addcloud(obvm, ema, GlobalColor("bull"), GlobalColor("bear"));

plot crossUP = if  obvm crosses above ema  then ema else double.NaN ;
crossUP.SetPaintingStrategy(PaintingStrategy.ARROW_up);
crossUP.SetDefaultColor(GlobalColor("crossup")) ;
crossUP.SetLineWeight(3);

plot crossDN = if  obvm crosses below ema  then obvm else double.NaN ;
crossDN.SetPaintingStrategy(PaintingStrategy.ARROW_down);
crossDN.SetDefaultColor(GlobalColor("crossdn")) ;
crossDN.SetLineWeight(3);

input showLabel = yes ;
AddLabel(showLabel,
if  obvm crosses above ema then "obv cross up!" else
if  obvm crosses below ema then "obv cross down!" else
if obvm > ema then "obv trending above" else " |  obv trending below",

if  obvm crosses above ema then GlobalColor("crossup") else
if  obvm crosses below ema then GlobalColor("crossdn") else
if obvm > ema then GlobalColor("bull") else GlobalColor("bear"));

input paintCandles = yes ;
AssignPriceColor(
if !paintCandles then color.current else
if  obvm crosses above ema then GlobalColor("crossup") else
if  obvm crosses below ema then GlobalColor("crossdn") else
if obvm > ema then GlobalColor("bull") else GlobalColor("bear"));

 

[Mike]

I've reviewed the code (#3) above and have the following comments/questions:

1) I'd like to code an upper OBV chart label. How can I modify the code to identify the moving average type, the moving average length, and color the label dark_green if the OBV closes above the moving average else color the label dark_red if the OBV closes below the moving average. Thanks...

 

[merryDay]

I've reviewed the code (#3) above and have the following comments/questions:

1) I'd like to code an upper OBV chart label. How can I modify the code to identify the moving average type, the moving average length, and color the label dark_green if the OBV closes above the moving average else color the label dark_red if the OBV closes below the moving average. Thanks...

Modified OBV labels to identify the moving average type, the moving average length
See bottom of post for instructions to adjust the colors used in these scripts.

## ########################################################
# OnBalanceVolumeModified
# mike request
## ########################################################

input signalLength = 10;
input averageType = "exponential" ;

def obvm = OnBalanceVolumeModified().obVM;
def ema = OnBalanceVolumeModified("signal length" = signalLength, "average type" = averageType).Signal; ;

def crossUP = if  obvm crosses above ema  then ema else double.NaN ;
def crossDN = if  obvm crosses below ema  then obvm else double.NaN ;

## ########################################################
# Charting & Formatting

DefineGlobalColor("bull", Color.dark_green) ;
DefineGlobalColor("bear", Color.dark_red) ;
DefineGlobalColor("crossup", Color.cyan) ;
DefineGlobalColor("crossdn", Color.magenta) ;

AddLabel(yes,
"OBVm average used: "  +averageType +" | average length: " +signalLength+
if  obvm crosses above ema then " |  obv cross up!" else
if  obvm crosses below ema then " |  obv cross down!" else
if obvm > ema then " |  obv trending above" else " |  obv trending below",

if  obvm crosses above ema then GlobalColor("crossup") else
if  obvm crosses below ema then GlobalColor("crossdn") else
if obvm > ema then GlobalColor("bull") else GlobalColor("bear"));

input paintCandles = no ;
AssignPriceColor(
if !paintCandles then color.current else
if  obvm crosses above ema then GlobalColor("crossup") else
if  obvm crosses below ema then GlobalColor("crossdn") else
if obvm > ema then GlobalColor("bull") else GlobalColor("bear"));

Adjusting Global Colors:
1. click on studies beaker
2. click on gear to the right of the study placed on the chart
3. click on Globals
4. click on the color to be changed
5. change color and save

MAKE SURE to click on "Save as default" to save your settings to be used on future charts.

 

[jrj4774]

Hello All,

Would it be possible to add in a label to tell me how much of the numerical difference and percentage? Sometimes I like to see values changes to determine my exit.

obvm - ema = positive value or negative value

thanks,
jrj4774

 

[useThinkScript]

Hello All,

Would it be possible to add in a label to tell me how much of the numerical difference and percentage? Sometimes I like to see values changes to determine my exit.

obvm - ema = positive value or negative value

thanks,
jrj4774

You must put your math for your definition of numerical difference and percentage into these two lines:

def numerical Difference = put your definition here ;
def percentage = put your definition here ;

And then the label syntax would be:

AddLabel(yes, "difference: " +numerical Difference +" | pct: " +percentage,
if percentage>0 then color.green else color.red);

 

[jrj4774]

I'm completely a newbie here, and I'm trying to find similar syntax in how the line/logic statement.

But I am getting an error message on the value differences. I tried both way I can think of.

and then the label, I'm completely lost.




Thanks,
jrj4774

 

[merryDay]

I'm completely a newbie here, and I'm trying to find similar syntax in how the line/logic statement.

But I am getting an error message on the value differences. I tried both way I can think of.

and then the label, I'm completely lost.




Thanks,
jrj4774

You left off a semicolon
change:

def numerical Difference = obvm - ema

to

def numerical Difference = obvm - ema ;

Every thinkscript statement must end with a semicolon.

Excellent job! You are officially a ToS scripter!