Multiple Time Frame RSI

[Skippidooo]

Could someone please add necessary code to make this script multiple time frame?
Thank You In Advance.








declare lower;

input length = 14;
input price = close;
input averageType = AverageType.WILDERS;

def NetChgAvg = MovingAverage(averageType, price - price[1], length);
def TotChgAvg = MovingAverage(averageType, AbsValue(price - price[1]), length);
def ChgRatio = if TotChgAvg != 0 then NetChgAvg / TotChgAvg else 0;

plot RSI = 50 * (ChgRatio + 1);



input average1Type = AverageType.SIMPLE;
input average1Length = 9;
input average2Type = AverageType.WILDERS;
input average2Length = 45;

plot avg1 = MovingAverage(average1Type, RSI, average1Length);
avg1.setDefaultColor(Color.GREEN);
plot avg2 = MovingAverage(average2Type, RSI, average2Length);
avg2.setDefaultColor(Color.RED);

avg1.SetPaintingStrategy(PaintingStrategy.LINE_VS_POINTS);
avg1.SetLineWeight(2);

avg1.DefineColor("Up", Color.GREEN);
avg1.DefineColor("Down", Color.RED);
avg1.DefineColor("Flat", Color.GRAY);

avg1.AssignValueColor(if avg1[0] > avg1[1] then avg1.Color("Up") else if avg1[0] <
avg1[1] then avg1.Color("Down") else avg1.Color("Flat"));
def cond1 = if rsi > avg1
then Double.POSITIVE_INFINITY
else Double.NEGATIVE_INFINITY;
def cond2 = if rsi < avg1
then Double.POSITIVE_INFINITY
else Double.NEGATIVE_INFINITY;

input showclouds = yes;
AddCloud(if showclouds
then cond1
else Double.NaN,
cond2,
Color.dark_GREEN, Color.Dark_RED);

 

[SleepyZ]

Could someone please add necessary code to make this script multiple time frame?
Thank You In Advance.








declare lower;

input length = 14;
input price = close;
input averageType = AverageType.WILDERS;

def NetChgAvg = MovingAverage(averageType, price - price[1], length);
def TotChgAvg = MovingAverage(averageType, AbsValue(price - price[1]), length);
def ChgRatio = if TotChgAvg != 0 then NetChgAvg / TotChgAvg else 0;

plot RSI = 50 * (ChgRatio + 1);



input average1Type = AverageType.SIMPLE;
input average1Length = 9;
input average2Type = AverageType.WILDERS;
input average2Length = 45;

plot avg1 = MovingAverage(average1Type, RSI, average1Length);
avg1.setDefaultColor(Color.GREEN);
plot avg2 = MovingAverage(average2Type, RSI, average2Length);
avg2.setDefaultColor(Color.RED);

avg1.SetPaintingStrategy(PaintingStrategy.LINE_VS_POINTS);
avg1.SetLineWeight(2);

avg1.DefineColor("Up", Color.GREEN);
avg1.DefineColor("Down", Color.RED);
avg1.DefineColor("Flat", Color.GRAY);

avg1.AssignValueColor(if avg1[0] > avg1[1] then avg1.Color("Up") else if avg1[0] <
avg1[1] then avg1.Color("Down") else avg1.Color("Flat"));
def cond1 = if rsi > avg1
then Double.POSITIVE_INFINITY
else Double.NEGATIVE_INFINITY;
def cond2 = if rsi < avg1
then Double.POSITIVE_INFINITY
else Double.NEGATIVE_INFINITY;

input showclouds = yes;
AddCloud(if showclouds
then cond1
else Double.NaN,
cond2,
Color.dark_GREEN, Color.Dark_RED);

Choose the mode, either current or agg
Choose the agg to whatever aggregation period desired

The image shows a 1m chart with mode = agg and agg = aggregationperiod.five_min in the upper chart and below a 5min chart with mode = current. The RSI in both are the same.

declare lower;

input mode = {default current, agg};
input agg = AggregationPeriod.FIVE_MIN;
input length = 14;
input price = FundamentalType.CLOSE;
input averageType = AverageType.WILDERS;


def modeperiod = if mode == mode.agg then agg else GetAggregationPeriod();
def NetChgAvg = MovingAverage(averageType, Fundamental(price, period = modeperiod) - Fundamental(price, period = modeperiod)[1], length);
def TotChgAvg = MovingAverage(averageType, AbsValue(Fundamental(price, period = modeperiod) - Fundamental(price, period = modeperiod)[1]), length);
def ChgRatio = if TotChgAvg != 0 then NetChgAvg / TotChgAvg else 0;

plot RSI = 50 * (ChgRatio + 1);

input average1Type = AverageType.SIMPLE;
input average1Length = 9;
input average2Type = AverageType.WILDERS;
input average2Length = 45;

plot avg1 = MovingAverage(average1Type, RSI, average1Length);
avg1.SetDefaultColor(Color.GREEN);
plot avg2 = MovingAverage(average2Type, RSI, average2Length);
avg2.SetDefaultColor(Color.RED);

avg1.SetPaintingStrategy(PaintingStrategy.LINE_VS_POINTS);
avg1.SetLineWeight(2);

avg1.DefineColor("Up", Color.GREEN);
avg1.DefineColor("Down", Color.RED);
avg1.DefineColor("Flat", Color.GRAY);

avg1.AssignValueColor(if avg1[0] > avg1[1] then avg1.Color("Up") else if avg1[0] <
avg1[1] then avg1.Color("Down") else avg1.Color("Flat"));
def cond1 = if RSI > avg1
then Double.POSITIVE_INFINITY
else Double.NEGATIVE_INFINITY;
def cond2 = if RSI < avg1
then Double.POSITIVE_INFINITY
else Double.NEGATIVE_INFINITY;

input showclouds = yes;
AddCloud(if showclouds
then cond1
else Double.NaN,
cond2,
Color.DARK_GREEN, Color.DARK_RED);

#