create multiple time clouds on a low time frame chart.

[IanBB]

Hi Coders,
I came across The post Highlight defined time range on chart https://usethinkscript.com/threads/highlight-defined-time-range-on-chart.1271/
By @BenTen and @SleepyZ

I was hoping someone could help me out by allowing people to add up to 6 different time zones and allow the user to change the colors on each zone?

I wanted to highlight 6 different times of the day with a few different color clouds or backgrounds on a 1 or 2 min. chart. Exact times every day. Any help would be much appreciated.

 

[GoLo]

Here's one that plots 4 time frames on the lower, to plot in upper chart just delete or # out the declare lower on line 12.

#Code
# shade_time_periods_02

# shade time periods, during a day

# https://usethinkscript.com/threads/preferred-time-slots.12736/
# Preferred time slots congamike 9/19

#------------------------------------
#if you want the shading to be on the upper chart

# .. disable this line ( by adding a # in front of it )
declare lower;
# .. and disable this plot
plot z = 0;
z.setdefaultcolor(color.black);

#------------------------------------

def na = Double.NaN;
def pos = Double.POSITIVE_INFINITY;
def neg = Double.NEGATIVE_INFINITY;

# define a color for all the time periods
DefineGlobalColor( "shade1" , color.orange);
DefineGlobalColor( "shade2" , color.green);
DefineGlobalColor( "shade3" , color.violet);
DefineGlobalColor( "shade4" , color.PLUM);


# define time periods (EST)
#/////////////////////////////////////
# copy this code segment for as many periods as desired, and change the variable names
input start1 = 1900;
input end1 = 2300;
def period1 = if SecondsFromTime(start1) >= 0 and SecondsTillTime(end1) > 0 then 1 else 0;
addcloud( (if period1 then pos else na), neg, GlobalColor( "shade1" ));
#/////////////////////////////////////

input start2 = 0200;
input end2 = 0500;
def period2 = if SecondsFromTime(start2) >= 0 and SecondsTillTime(end2) > 0 then 1 else 0;
addcloud( (if period2 then pos else na), neg, GlobalColor( "shade2" ));

input start3 = 0700;
input end3 = 1000;
def period3 = if SecondsFromTime(start3) >= 0 and SecondsTillTime(end3) > 0 then 1 else 0;
addcloud( (if period3 then pos else na), neg, GlobalColor( "shade3" ));

input start4 = 1330;
input end4 = 1600;
def period4 = if SecondsFromTime(start4) >= 0 and SecondsTillTime(end4) > 0 then 1 else 0;
addcloud( (if period4 then pos else na), neg, GlobalColor( "shade4" ));
#
#

 

[IanBB]

Thanks, Golo