MTF Rate of Change

[msmmlee]

I am trying to figure out if the Rate of Change indicator can be modified to show three different time frames. I'm hoping for help... I'll be glad to buy a cup of coffee or lunch! I added the "input agg" tag into the ROC code below but it isn't working. I also tried ChatGPT but it is giving me three lengths, not three aggregation periods (below).

declare lower;

input agg = aggregationPeriod.FIVE_MIN;

input length = 14;
input colorNormLength = 14;
input price = close;

assert(length > 0, "'length' must be positive: " + length);

plot ROC = if price[length] != 0 then (price / price[length] - 1) * 100 else 0;
plot ZeroLine = 0;

ROC.DefineColor("Highest", Color.YELLOW);
ROC.DefineColor("Lowest", Color.LIGHT_RED);
ROC.AssignNormGradientColor(colorNormLength, ROC.color("Lowest"), ROC.color("Highest"));
ZeroLine.SetDefaultColor(GetColor(5));

ChatGPT:

# Define Inputsinput length1 = 14;input length2 = 21;input length3 = 28;# Calculate ROC for different aggregation periodsdef roc1 = close / close[length1] - 1;def roc2 = close / close[length2] - 1;def roc3 = close / close[length3] - 1;# Plotting the ROC linesplot ROC_Line1 = roc1;plot ROC_Line2 = roc2;plot ROC_Line3 = roc3;# Plot FormattingROC_Line1.SetDefaultColor(GetColor(1));ROC_Line2.SetDefaultColor(GetColor(2));ROC_Line3.SetDefaultColor(GetColor(3));

 

[SleepyZ]

I am trying to figure out if the Rate of Change indicator can be modified to show three different time frames. I'm hoping for help... I'll be glad to buy a cup of coffee or lunch! I added the "input agg" tag into the ROC code below but it isn't working. I also tried ChatGPT but it is giving me three lengths, not three aggregation periods (below).

declare lower;

input agg = aggregationPeriod.FIVE_MIN;

input length = 14;
input colorNormLength = 14;
input price = close;

assert(length > 0, "'length' must be positive: " + length);

plot ROC = if price[length] != 0 then (price / price[length] - 1) * 100 else 0;
plot ZeroLine = 0;

ROC.DefineColor("Highest", Color.YELLOW);
ROC.DefineColor("Lowest", Color.LIGHT_RED);
ROC.AssignNormGradientColor(colorNormLength, ROC.color("Lowest"), ROC.color("Highest"));
ZeroLine.SetDefaultColor(GetColor(5));

ChatGPT:

# Define Inputsinput length1 = 14;input length2 = 21;input length3 = 28;# Calculate ROC for different aggregation periodsdef roc1 = close / close[length1] - 1;def roc2 = close / close[length2] - 1;def roc3 = close / close[length3] - 1;# Plotting the ROC linesplot ROC_Line1 = roc1;plot ROC_Line2 = roc2;plot ROC_Line3 = roc3;# Plot FormattingROC_Line1.SetDefaultColor(GetColor(1));ROC_Line2.SetDefaultColor(GetColor(2));ROC_Line3.SetDefaultColor(GetColor(3));

This uses the script function to create 3 different agg plots of the ROC.

declare lower;

script rofc {
    input agg = AggregationPeriod.FIVE_MIN;

    input length = 14;
    input colorNormLength = 14;
    input price = FundamentalType.CLOSE;

    Assert(length > 0, "'length' must be positive: " + length);

    plot ROC = if Fundamental(price, period = agg)[length] != 0 then (Fundamental(price, period = agg) / Fundamental(price, period = agg)[length] - 1) * 100 else 0;
}
plot ZeroLine = 0;

input agg1 = AggregationPeriod.MIN;
input agg2 = AggregationPeriod.THREE_MIN;
input agg3 = AggregationPeriod.FIVE_MIN;
input length = 14;
input colorNormLength = 14;
input price = FundamentalType.CLOSE;

def na = Double.NaN;

plot roc1 = if IsNaN(close) then na else rofc(agg1, length = length, "color norm length" = colorNormLength, price = price);
roc1.DefineColor("Highest", Color.YELLOW);
roc1.DefineColor("Lowest", Color.LIGHT_RED);
roc1.AssignNormGradientColor(colorNormLength, roc1.Color("Lowest"), roc1.Color("Highest"));

plot roc2 = if IsNaN(close) then na else rofc(agg2, length = length, "color norm length" = colorNormLength, price = price);
roc2.DefineColor("Highest", Color.YELLOW);
roc2.DefineColor("Lowest", Color.LIGHT_RED);
roc2.AssignNormGradientColor(colorNormLength, roc2.Color("Lowest"), roc2.Color("Highest"));

plot roc3 = if IsNaN(close) then na else rofc(agg3, length = length, "color norm length" = colorNormLength, price = price);
roc3.DefineColor("Highest", Color.YELLOW);
roc3.DefineColor("Lowest", Color.LIGHT_RED);
roc3.AssignNormGradientColor(colorNormLength, roc3.Color("Lowest"), roc3.Color("Highest"));

ZeroLine.SetDefaultColor(GetColor(5));

input show_bubble = yes;
input bubblemover = 1;
def b = bubblemover;
def mover = show_bubble and IsNaN(close[b]) and !IsNaN(close[b + 1]);

AddChartBubble(mover, roc1[b + 1], agg1 / 60000 + "m", roc1.TakeValueColor());
AddChartBubble(mover, roc2[b + 1], agg2 / 60000 + "m", roc2.TakeValueColor());
AddChartBubble(mover, roc3[b + 1], agg3 / 60000 + "m", roc3.TakeValueColor());

#

 

[msmmlee]

This uses the script function to create 3 different agg plots of the ROC.

I just found your reply, SleepyZ. Thank you so much. This is better than what I was able to come up with on my own.