Repaints MTF Awesome Oscillator For ThinkOrSwim

rajaodu1 · Dec 18, 2024

HI Script Gurus,

Can you please help me to create a Multi time frame (say 5, 15, 1 hour) Awesome Line oscillator in 1 min time frame candle chart? Thanks for your help in advance.

and have options to change the up and down color for each time frame, so that the awesome line oscillator can be easily identified.

@BenTen @SleepyZ any help please

SleepyZ · Dec 19, 2024

rajaodu1 said:
HI Script Gurus,

Can you please help me to create a Multi time frame (say 5, 15, 1 hour) Awesome Line oscillator in 1 min time frame candle chart? Thanks for your help in advance.

Code:

declare lower; declare zerobase; input Agg1 = AggregationPeriod.THREE_MIN; input Agg2 = AggregationPeriod.FIVE_MIN; input Agg3 = AggregationPeriod.FIFTEEN_MIN; input Agg4 = AggregationPeriod.Thirty_MIN; plot AO = Average(hl2, 5) - Average(hl2, 34); plot Zero = 0; #AO.SetPaintingStrategy(PaintingStrategy.HISTOGRAM); AO.SetLineWeight(2); AO.DefineColor("Up", Color.GREEN); AO.DefineColor("Down", Color.RED); AO.AssignValueColor(if AO > AO[1] then AO.color("Up") else if AO < AO[1] then AO.color("Down") else GetColor(1)); Zero.SetDefaultColor(COLOR.YELLOW);

View attachment 23583

and have options to change the up and down color for each time frame, so that the awesome line oscillator can be easily identified.

@BenTen @SleepyZ any help please

I have the colors for each agg green/red (you can change them at the input screen or within the code)
Optional labels and/or bubbles added

declare lower;
declare zerobase;

input Agg1 = AggregationPeriod.THREE_MIN;
input Agg2 = AggregationPeriod.FIVE_MIN;
input Agg3 = AggregationPeriod.FIFTEEN_MIN;
input Agg4 = AggregationPeriod.THIRTY_MIN;

plot AO = Average(hl2, 5) - Average(hl2, 34);
def A0 = if AO > AO[1] then 1 else if AO < AO[1] then 0 else A0[1];
plot AO1 = if IsNaN(close) then Double.NaN else Average(hl2(period = Agg1), 5) - Average(hl2(period = Agg1), 34);
def A1 = if AO1 > AO1[1] then 1 else if AO1 < AO1[1] then 0 else A1[1];
plot AO2 = if IsNaN(close) then Double.NaN else Average(hl2(period = Agg2), 5) - Average(hl2(period = Agg2), 34);
def A2 = if AO2 > AO2[1] then 1 else if AO2 < AO2[1] then 0 else A2[1];
plot AO3 = if IsNaN(close) then Double.NaN else Average(hl2(period = Agg3), 5) - Average(hl2(period = Agg3), 34);
def A3 = if AO3 > AO3[1] then 1 else if AO3 < AO3[1] then 0 else A3[1];
plot AO4 = if IsNaN(close) then Double.NaN else Average(hl2(period = Agg4), 5) - Average(hl2(period = Agg4), 34);
def A4 = if AO4 > AO4[1] then 1 else if AO4 < AO4[1] then 0 else A4[1];
plot Zero = 0;

#AO.SetPaintingStrategy(PaintingStrategy.HISTOGRAM);
AO.SetLineWeight(2);
AO.DefineColor("Up", Color.GREEN);
AO.DefineColor("Down", Color.RED);
AO.AssignValueColor(if A0 == 1 then AO.Color("Up") else AO.Color("Down"));
AO1.SetLineWeight(2);
AO1.DefineColor("Up1", Color.GREEN);
AO1.DefineColor("Down1", Color.RED);
AO1.AssignValueColor(if A1 == 1 then AO1.Color("Up1") else AO1.Color("Down1"));
AO2.SetLineWeight(2);
AO2.DefineColor("Up2", Color.GREEN);
AO2.DefineColor("Down2", Color.RED);
AO2.AssignValueColor(if A2 == 1 then AO2.Color("Up2") else AO2.Color("Down2"));
AO3.SetLineWeight(2);
AO3.DefineColor("Up3", Color.GREEN);
AO3.DefineColor("Down3", Color.RED);
AO3.AssignValueColor(if A3 == 1 then AO3.Color("Up3") else AO3.Color("Down3"));
AO4.SetLineWeight(2);
AO4.DefineColor("Up4", Color.GREEN);
AO4.DefineColor("Down4", Color.RED);
AO4.AssignValueColor(if A4 == 1 then AO4.Color("Up4") else AO4.Color("Down4"));
Zero.SetDefaultColor(Color.LIGHT_GRAY);

input bubbles = yes;
def bubblemover = 1;
def mover = bubbles and IsNaN(close[bubblemover]) and !IsNaN(close[bubblemover + 1]);
AddChartBubble(mover, AO[bubblemover + 1], GetAggregationPeriod() / 60000 , if A0[bubblemover + 1] == 1 then AO.Color("Up") else AO.Color("Down"), no);
AddChartBubble(bubbles and IsNaN(close[bubblemover + 1]) and !IsNaN(close[bubblemover + 1 + 1]), AO1[bubblemover + 1 + 1], Agg1 / 60000 , if A1[bubblemover + 1 + 1] == 1 then AO1.Color("Up1") else AO1.Color("Down1"));
AddChartBubble(bubbles and IsNaN(close[bubblemover + 2]) and !IsNaN(close[bubblemover + 1 + 2]), AO2[bubblemover + 1 + 2], Agg2 / 60000 , if A2[bubblemover + 1 + 2] == 1 then AO2.Color("Up2") else AO2.Color("Down2"));
AddChartBubble(bubbles and IsNaN(close[bubblemover + 3]) and !IsNaN(close[bubblemover + 1 + 3]), AO3[bubblemover + 1 + 3], Agg3 / 60000 , if A3[bubblemover + 1 + 3] == 1 then AO3.Color("Up3") else AO3.Color("Down3"));
AddChartBubble(bubbles and IsNaN(close[bubblemover + 4]) and !IsNaN(close[bubblemover + 1 + 4]), AO4[bubblemover + 1 + 4], Agg4 / 60000 , if A4[bubblemover + 1 + 4] == 1 then AO4.Color("Up4") else AO4.Color("Down4"));

input labels = yes;
AddLabel(labels, GetAggregationPeriod() / 60000 + "m", if A0 == 1 then AO.Color("Up") else AO.Color("Down"));
AddLabel(labels, Agg1 / 60000 + "m", if A1 == 1 then AO1.Color("Up1") else AO1.Color("Down1"));
AddLabel(labels, Agg2 / 60000 + "m", if A2 == 1 then AO2.Color("Up2") else AO2.Color("Down2"));
AddLabel(labels, Agg3 / 60000 + "m", if A3 == 1 then AO3.Color("Up3") else AO3.Color("Down3"));
AddLabel(labels, Agg4 / 60000 + "m", if A4 == 1 then AO4.Color("Up4") else AO4.Color("Down4"));

#

rajaodu1 · Dec 19, 2024

@SleepyZ I love it. Thank you. You are great. Thanks again

rajaodu1 · Dec 19, 2024

@SleepyZ

At 5 min or above instead of smooth AO curve, it shows like lines. Will it be possible to get smooth lines just like it is shown in 1 min? This will help to see the divergence in 5 min AO line also (just like in 1 min AO line)

rad14733 · Dec 19, 2024

rajaodu1 said:
@SleepyZ

At 5 min or above instead of smooth AO curve, it shows like lines. Will it be possible to get smooth lines just like it is shown in 1 min? This will help to see the divergence in 5 min AO line also (just like in 1 min AO line)

View attachment 23597

@rajaodu1 While @SleepyZ would be able to incorporate smoothing of the results of higher timeframes, by incorporating an averaged result, doing so would not reflect the actual results, skewing the representative values... Stair-stepping is a very common occurrence with MTF indicators... This is something we, as traders, generally take into consideration... The more we try to smooth results, the further from actual values we get... It's a balancing act... Just sharing logic here but we'll see if @SleepyZ chimes in on your request...

rajaodu1 · Dec 19, 2024

@rad14733 thanks for your reply. I see your point. I am in learning stage on trading, so I need to learn the stair stepping method.

If you see the chart below, they are 5 min and 1 min. I added AO and the AO line. I was visualizing to see the AO line from 5 min on 1 min. Same format.

If this is not easy and more complicated, then I will learn to use stair stepping.

useThinkScript · Dec 19, 2024

Explanation of the Repainting Stairs of MTF Indicators.

If you're viewing the 5-minute and 15-minute values on a 1-minute chart, each 15-minute bar represents 15 consecutive 1-minute bars. The value of the HTF indicator remains flat or "plateaued" during those 15 minutes because it is a reflection of the single value of the higher timeframe bar.

NOTE: until the 15-minute bar closes, its value is recalculated with every tick of incoming price data. This recalculation causes the indicator to "repaint" its plotted values for all 15 bars within that 15-minute window.

Key Points:

Flat Plots: of course, the HTF values appear stepped on LTF charts. If the value of the 15-min bar is -13 then that same -13 has to plot on 15 of one-minute bars to represent the 15-min bar value.
Repainting: Those 15 one-minute bars will repaint on every tick. Until the 15-min bar closes; at which time, there will be one final repaint.

Why This Matters for Trading:
Repainting indicators can give misleading signals if you base decisions on values that are still forming.

rajaodu1 · Dec 20, 2024

useThinkScript said:
Explanation of the Repainting Stairs of MTF Indicators.

If you're viewing the 5-minute and 15-minute values on a 1-minute chart, each 15-minute bar represents 15 consecutive 1-minute bars. The value of the HTF indicator remains flat or "plateaued" during those 15 minutes because it is a reflection of the single value of the higher timeframe bar.

NOTE: until the 15-minute bar closes, its value is recalculated with every tick of incoming price data. This recalculation causes the indicator to "repaint" its plotted values for all 15 bars within that 15-minute window.

Key Points:

Flat Plots: of course, the HTF values appear stepped on LTF charts. If the value of the 15-min bar is -13 then that same -13 has to plot on 15 of one-minute bars to represent the 15-min bar value.

Repainting: Those 15 one-minute bars will repaint on every tick. Until the 15-min bar closes; at which time, there will be one final repaint.

Why This Matters for Trading:
Repainting indicators can give misleading signals if you base decisions on values that are still forming.

Wow. Thanks for the explanation. I can understand now, why stair step is coming. Thanks again.

Thanks @SleepyZ and @rad14733

SleepyZ · Dec 20, 2024

rajaodu1 said:
Wow. Thanks for the explanation. I can understand now, why stair step is coming. Thanks again.

Thanks @SleepyZ and @rad14733

You're welcome and thanks to everyone for their replies.

The lines could be smoothed with extra code as in this link. However, it is merely visual, not necessarily accurate, as others explained. https://usethinkscript.com/threads/...rage-indicator-for-thinkorswim.135/post-66656

Also, there was a correction to the label code coloring made in the post above. See https://usethinkscript.com/threads/mtf-awesome-oscillator-for-thinkorswim.20169/post-148854

TOS007 · Jan 1, 2025

Can anyone help me to write a MTF Awesome Oscillator? Truly appreciated.

I manage to get to this, but I cant make it look like on the left. Any help is appreciated.

# Multi Timeframe Awesome Oscillator with Correct Color Assignment

declare lower;

input aggregationPeriod = AggregationPeriod.DAY; # Choose the timeframe: DAY, WEEK, MONTH

def data = close(period = aggregationPeriod);

# Median Price Calculation
def medianPrice = (high(period = aggregationPeriod) + low(period = aggregationPeriod)) / 2;

# Simple Moving Average of Median Price for 5 periods
def smaMedian5 = Average(medianPrice, 5);

# Simple Moving Average of Median Price for 34 periods
def smaMedian34 = Average(medianPrice, 34);

# Awesome Oscillator Calculation
def awesomeOscillator = smaMedian5 - smaMedian34;

# Plotting the Awesome Oscillator with correct color assignment
plot AO = awesomeOscillator;
AO.SetPaintingStrategy(PaintingStrategy.HISTOGRAM);
AO.SetLineWeight(3);
AO.AssignValueColor(if AO > 0 then Color.GREEN else Color.RED);

# Add labels for clarity
AddLabel(yes, "Multi Timeframe Awesome Oscillator", Color.WHITE);

TOS007 · Jan 6, 2025

Thanks to this member and I modified to my need.
https://usethinkscript.com/threads/mtf-awesome-oscillator-for-thinkorswim.20169/post-148854

declare lower;
declare zerobase;

input Agg1 = AggregationPeriod.month;

plot AO = Average(hl2, 5) - Average(hl2, 34);
def A0 = if AO > AO[1] then 1 else if AO < AO[1] then 0 else A0[1];
ao.hide();
plot AO1 = if IsNaN(close) then Double.NaN else Average(hl2(period = Agg1), 5) - Average(hl2(period = Agg1), 34);
def A1 = if AO1 > AO1[1] then 1 else if AO1 < AO1[1] then 0 else A1[1];
plot Zero = 0;

#AO.SetPaintingStrategy(PaintingStrategy.HISTOGRAM);
AO.SetLineWeight(2);
AO.DefineColor("Up", Color.GREEN);
AO.DefineColor("Down", Color.RED);
AO.AssignValueColor(if A0 == 1 then AO.Color("Up") else AO.Color("Down"));
AO1.SetLineWeight(2);
AO1.DefineColor("Up1", Color.cyan);
AO1.DefineColor("Down1", Color.magenta);
AO1.AssignValueColor(if A1 == 1 then AO1.Color("Up1") else AO1.Color("Down1"));

Zero.SetDefaultColor(Color.LIGHT_GRAY);

input bubbles = yes;
def bubblemover = 1;
def mover = bubbles and IsNaN(close[bubblemover]) and !IsNaN(close[bubblemover + 1]);
AddChartBubble(mover, AO[bubblemover + 1], GetAggregationPeriod() / 60000 , if A0[bubblemover + 1] == 1 then AO.Color("Up") else AO.Color("Down"), no);
AddChartBubble(bubbles and IsNaN(close[bubblemover + 1]) and !IsNaN(close[bubblemover + 1 + 1]), AO1[bubblemover + 1 + 1], Agg1 / 60000 , if A1[bubblemover + 1 + 1] == 1 then AO1.Color("Up1") else AO1.Color("Down1"));

input labels = yes;
AddLabel(labels, GetAggregationPeriod() / 60000 + "m", if A0 == 1 then AO.Color("Up") else AO.Color("Down"));
AddLabel(labels, Agg1 / 60000 + "m", if A1 == 1 then AO1.Color("Up1") else AO1.Color("Down1"));
#

ferdie · Nov 19, 2025

TOS007 said:
Thanks to this member and I modified to my need.
https://usethinkscript.com/threads/mtf-awesome-oscillator-for-thinkorswim.20169/post-148854

declare lower;
declare zerobase;

input Agg1 = AggregationPeriod.month;

plot AO = Average(hl2, 5) - Average(hl2, 34);
def A0 = if AO > AO[1] then 1 else if AO < AO[1] then 0 else A0[1];
ao.hide();
plot AO1 = if IsNaN(close) then Double.NaN else Average(hl2(period = Agg1), 5) - Average(hl2(period = Agg1), 34);
def A1 = if AO1 > AO1[1] then 1 else if AO1 < AO1[1] then 0 else A1[1];
plot Zero = 0;

#AO.SetPaintingStrategy(PaintingStrategy.HISTOGRAM);
AO.SetLineWeight(2);
AO.DefineColor("Up", Color.GREEN);
AO.DefineColor("Down", Color.RED);
AO.AssignValueColor(if A0 == 1 then AO.Color("Up") else AO.Color("Down"));
AO1.SetLineWeight(2);
AO1.DefineColor("Up1", Color.cyan);
AO1.DefineColor("Down1", Color.magenta);
AO1.AssignValueColor(if A1 == 1 then AO1.Color("Up1") else AO1.Color("Down1"));

Zero.SetDefaultColor(Color.LIGHT_GRAY);

input bubbles = yes;
def bubblemover = 1;
def mover = bubbles and IsNaN(close[bubblemover]) and !IsNaN(close[bubblemover + 1]);
AddChartBubble(mover, AO[bubblemover + 1], GetAggregationPeriod() / 60000 , if A0[bubblemover + 1] == 1 then AO.Color("Up") else AO.Color("Down"), no);
AddChartBubble(bubbles and IsNaN(close[bubblemover + 1]) and !IsNaN(close[bubblemover + 1 + 1]), AO1[bubblemover + 1 + 1], Agg1 / 60000 , if A1[bubblemover + 1 + 1] == 1 then AO1.Color("Up1") else AO1.Color("Down1"));

input labels = yes;
AddLabel(labels, GetAggregationPeriod() / 60000 + "m", if A0 == 1 then AO.Color("Up") else AO.Color("Down"));
AddLabel(labels, Agg1 / 60000 + "m", if A1 == 1 then AO1.Color("Up1") else AO1.Color("Down1"));
#

I would like to request assistance in MTF Awesome Oscillator I made. There is an error in the color.

Code:

declare lower;

input agg1 = AggregationPeriod.TWO_MIN;
input agg2 = AggregationPeriod.FIVE_MIN;
input agg3 = AggregationPeriod.FIFTEEN_MIN;

def chartagg = GetAggregationPeriod();
def chartmin = chartagg / 60000;

#Agg1
def AO1X = Average(hl2(period = agg1), 5) - Average(hl2(period = agg1), 34);
plot AO1 = if close(period = agg1) then 1 else Double.NaN;
AO1.SetPaintingStrategy(PaintingStrategy.POINTS);
AO1.SetLineWeight(2);
AO1.AssignValueColor(if AO1X > 0 then if AO1X > AO1X[1] then Color.CYAN else Color.BLUE else if AO1X < AO1X[1] then Color.LIGHT_RED else Color.YELLOW);

#Agg2
def AO2X = Average(hl2(period = agg2), 5) - Average(hl2(period = agg2), 34);
plot AO2 = if close(period = agg2) then 2 else Double.NaN;
AO2.SetPaintingStrategy(PaintingStrategy.POINTS);
AO2.SetLineWeight(2);
AO2.AssignValueColor(if AO2X > 0 then if AO2X > AO2X[1] then Color.CYAN else Color.BLUE else if AO2X < AO2X[1] then Color.LIGHT_RED else Color.YELLOW);

#Agg3
def AO3X = Average(hl2(period = agg3), 5) - Average(hl2(period = agg3), 34);
plot AO3 = if close(period = agg3) then 3 else Double.NaN;
AO3.SetPaintingStrategy(PaintingStrategy.POINTS);
AO3.SetLineWeight(2);
AO3.AssignValueColor(if AO3X > 0 then if AO3X > AO3X[1] then Color.CYAN else Color.BLUE else if AO3X < AO3X[1] then Color.LIGHT_RED else Color.YELLOW);

merryDay · Nov 19, 2025

Color Key:

CYAN — AO > 0 and AO is rising vs prior bar

→ Bullish momentum gaining (strongest bullish signal)

BLUE — AO > 0 and AO is not rising (≤ prior)

→ Bullish but stalling or weakening (still positive bias, but watch)

LIGHT_RED — AO < 0 and AO is falling vs prior bar

→ Bearish momentum increasing (strongest bearish signal)

YELLOW — AO < 0 and AO is not falling (≥ prior)

→ Bearish but recovering / losing bearish momentum (still negative, but watch for reversal)

GRAY — AO == 0

→ Neutral / exactly zero

MTF Awesome Oscillator Dashboard – How to Set It Up the Right Way
When you use a dashboard that pulls information from multiple timeframes, Thinkorswim needs enough historical data on your chart to build those timeframes correctly in order for the colors to plot correctly.

Don’t worry — this is easy once you know the rules:

Rule #1 – Your chart must use the same or smaller timeframe
If the dashboard includes a 2-minute timeframe, then your chart must be:

➜ 2-minute, or

➜ 1-minute

Anything larger (like 3m, 5m, etc.) won’t work, because TOS can’t “go backward” and assemble smaller bars from bigger ones.

Rule #2 – Your chart must have enough days of data for the largest timeframe’s lookback
The dashboard uses higher timeframes (like 5m, 15m) and long moving averages (like 34 periods).
Those require a lot of historical bars.

So your chart needs to be loaded with enough days to cover that.

Easy examples
If you’re using a 2-minute chart. Your chart should be set to:

➤ 10D 2m

This gives Thinkorswim enough history to build the 5-minute and 15-minute calculations behind the scenes.

If you’re using a 1-minute chart
Your chart should be set to:

➤ 20D 1m

Because smaller timeframes need even more bars to build the higher-timeframe studies properly.

In short:
Your dashboard will work beautifully as long as your chart:

✦ Uses the same or a smaller timeframe

✦ Loads enough days to satisfy the largest lookback period

Follow those two simple rules, and the colors with plot correctly!

Code:

declare lower;

input agg1 = AggregationPeriod.TWO_MIN;
input agg2 = AggregationPeriod.FIVE_MIN;
input agg3 = AggregationPeriod.FIFTEEN_MIN;


def AO1X = Average(hl2(period = agg1), 5) - Average(hl2(period = agg1), 34);
def AO2X = Average(hl2(period = agg2), 5) - Average(hl2(period = agg2), 34);
def AO3X = Average(hl2(period = agg3), 5) - Average(hl2(period = agg3), 34);


plot AO1 = if IsNaN(close) then Double.NaN else 1.0;
AO1.SetPaintingStrategy(PaintingStrategy.POINTS);
AO1.SetLineWeight(5);
AO1.AssignValueColor(
    if AO1X > 0 then
        if AO1X > AO1X[1] then Color.CYAN else Color.BLUE
    else if AO1X < 0 then
        if AO1X < AO1X[1] then Color.LIGHT_RED else Color.YELLOW
    else Color.GRAY);
AO1.HideBubble() ; AO1.HideTitle();

plot AO2 = if IsNaN(close) then Double.NaN else 2.0;
AO2.SetPaintingStrategy(PaintingStrategy.POINTS);
AO2.SetLineWeight(5);
AO2.AssignValueColor(
    if AO2X > 0 then
        if AO2X > AO2X[1] then Color.CYAN else Color.BLUE
    else if AO2X < 0 then
        if AO2X < AO2X[1] then Color.LIGHT_RED else Color.YELLOW
    else Color.GRAY);
AO2.HideBubble() ; AO2.HideTitle();

plot AO3 = if IsNaN(close) then Double.NaN else 3.0;
AO3.SetPaintingStrategy(PaintingStrategy.POINTS);
AO3.SetLineWeight(5);
AO3.AssignValueColor(
    if AO3X > 0 then
        if AO3X > AO3X[1] then Color.CYAN else Color.BLUE
    else if AO3X < 0 then
        if AO3X < AO3X[1] then Color.LIGHT_RED else Color.YELLOW
    else Color.GRAY);
AO3.HideBubble() ; AO3.HideTitle();

plot lessONE = if IsNaN(close) then Double.NaN else -1;
lessONE.SetDefaultColor(color.dark_gray);
lessONE.HideBubble() ; lessONE.HideTitle();

plot five = if IsNaN(close) then Double.NaN else 5;
five.SetDefaultColor(color.dark_gray);
five.HideBubble() ; five.HideTitle();

@ferdie

Thread starter	Similar threads	Forum	Replies	Date
G	How can I add MTF to my VPN cloud?	Questions	2	Nov 16, 2025
J	Need MTF for MACD Bands Squeezes	Questions	1	Sep 2, 2025
B	Convert Volume Pressure To MTF	Questions	5	Aug 3, 2025
	MTF evaluation of Strategy	Questions	3	Jun 20, 2025
E	MTF Bar Counting	Questions	1	May 6, 2025

Repaints MTF Awesome Oscillator For ThinkOrSwim

rajaodu1

Member

SleepyZ

SleepyZ

Moderator - Expert

rajaodu1

Member

rajaodu1

Member

rad14733

Options Expert

rajaodu1

Member

useThinkScript

Administrative

rajaodu1

Member

SleepyZ

Moderator - Expert

TOS007

New member

Attachments

TOS007

New member

ferdie

New member

merryDay

Administrative

Similar threads

Not the exact question you're looking for?

Similar threads

Similar threads

The Market Trading Game Changer

Frequently Asked Questions

Repaints MTF Awesome Oscillator For ThinkOrSwim

Member

Moderator - Expert

Member

Member

Options Expert

Member

Administrative

Member

Moderator - Expert

New member

Attachments

New member

New member

Administrative

​

Similar threads

Not the exact question you're looking for?

Similar threads

Similar threads

The Market Trading Game Changer

Frequently Asked Questions