Repaints MTF Arnaud Legoux Moving Average Bands For ThinkOrSwim

[squaredconfusion]

The Arnaud Legoux Moving Average (ALMA) Bands provide smooth moving average, reducing lag and noise. They help identify trends, spot trend reversals, and find dynamic support and resistance levels.
Key Inputs Must Be Optimized For Instrument and Timeframe

1. Period or Window Size:
   • Definition: This is the number of historical data points used in the ALMA calculation.
   • Impact:
     • Shorter Window: More responsive to recent price changes, but may increase noise and false signals.
     • Longer Window: Smoother line with less noise but more lag in reacting to price changes.
2. Shift or Offset:
   • Definition: This sets the position of the Gaussian filter used for weighting data points.
   • Impact:
     • Higher Offset: More responsive to recent price changes, but may increase noise.
     • Lower Offset: Smoother line with reduced noise but more lag.
3. Deviation or Sigma:
   • Definition: This is the standard deviation in the Gaussian distribution.
   • Impact:
     • Smaller Sigma: More responsive ALMA with higher chance of noise and false signals.
     • Larger Sigma: Smoother ALMA line with more lag.

Experiment with different settings to find the right balance between responsiveness and noise reduction.

Hey, if anyone can attempt this conversion, I've tried myself but can't seem to replicate the values, and computation on TV, into thinkscript. @samer800 Thanks for y'all's time.

https://www.tradingview.com/script/R5vo13dy-Arnaud-Legoux-Moving-Average-Bands-MTF-V3/

 

[samer800]

Hey, if anyone can attempt this conversion, I've tried myself but can't seem to replecate the values, and computation on TV, into thinkscript. @samer800 Thanks for yall's time.

https://www.tradingview.com/script/R5vo13dy-Arnaud-Legoux-Moving-Average-Bands-MTF-V3/

Here's a screenshot: View attachment 21966

study(title = "Arnaud Legoux Moving Average Bands MTF V3", shorttitle="ALMAB MTF V3", overlay=true)
// Default TF is 4 Hrs
source = close

windowsize = input(title="Window Size", type=integer, defval=100)
offset = input(title="Offset", type=float, defval=0.85)
sigma = input(title="Sigma", type=float, defval=6)
picktf = input(title="Pick TimeFrame", type=resolution, defval="240")

ATRlength = input(100, minval=1)
ATRMult = input(2, minval=1)
ATRMult2 = input(4, minval=1)
ATRMult3 = input(6, minval=1)
ATR = rma(tr(true), ATRlength)

almamed = alma(source, windowsize, offset, sigma)


emaup = almamed+(ATR*ATRMult)
emadw = almamed-(ATR*ATRMult)
emahigh = almamed+(ATR*ATRMult2)
emalow = almamed-(ATR*ATRMult2)
emahighx = almamed+(ATR*ATRMult3)
emalowx = almamed-(ATR*ATRMult3)
almatfpv = security(tickerid,picktf ,almamed)
almatfup = security(tickerid,picktf ,emaup)
almatfdw = security(tickerid,picktf ,emadw)
almatfhigh = security(tickerid,picktf ,emahigh)
almatflow = security(tickerid,picktf ,emalow)
almatfhighx = security(tickerid,picktf ,emahighx)
almatflowx = security(tickerid,picktf ,emalowx)


plot(emaup, title="EMAUP", color=red)
plot(emadw, title="EMADW", color=green)
plot(emahigh, title="EMAHigh", color=red)
plot(emalow, title="EMALow", color=green)
plot(emahighx, title="StopLossShort", color=silver)
plot(emalowx, title="StopLossLong", color=silver)

plot(almamed,linewidth=2,color=purple)
plot(almatfup,linewidth=2,color=blue)
plot(almatfdw,linewidth=2,color=blue)
plot(almatfpv,linewidth=2,color=blue)
plot(almatfhigh,linewidth=2,color=red)
plot(almatflow,linewidth=2,color=red)
plot(almatfhighx,linewidth=2,color=silver)
plot(almatflowx,linewidth=2,color=silver)

check below

# https://www.tradingview.com/v/R5vo13dy/
# @CapnOscar
#study(title = "Arnaud Legoux Moving Average Bands MTF V3", shorttitle="ALMAB MTF V3", overlay=true)
# converted by Sam4Cok@Samer800    - 06/2024

input source = FundamentalType.CLOSE;
input windowSize = 100; #(title="Window Size", type=integer, defval=100)
input almaOffset = 0.85; #put(title="Offset", type=float, defval=0.85)
input almaSigma = 6; #(title="Sigma", type=float, defval=6)
input atrLength = 100; #, minval=1)
input atrMultiplier1 = 2.0; #, minval=1)
input atrMultiplier2 = 4.0; #, minval=1)
input atrMultiplier3 = 6.0; #, minval=1)
input showHigherTimeframe = yes;
input higherTimeframe = AggregationPeriod.FIFTEEN_MIN; # resolution


def na = Double.NaN;
def current = GetAggregationPeriod();
def picktf = Max(higherTimeframe, current);
def src = Fundamental(source);
def htfSrc = Fundamental(source, Period = picktf);
def htfCl = close(Period = picktf);
def htfHi = high(Period = picktf);
def htfLo = low(Period = picktf);
############## ALMA
script ALMA {
  input Data = close;
  input Window = 9;
  input Sigma = 6;
  input Offset = 0.85;
    def m = (Offset * (Window - 1));
    def s = Window/Sigma;
    def SumVectorData = fold y = 0 to Window with WS do
         WS + Exp(-(sqr(y-m))/(2*sqr(s))) * getvalue(Data, (Window-1)-y);
    def SumVector = fold z = 0 to Window with CW do
         CW + Exp(-(sqr(z-m))/(2*sqr(s)));
 plot ALMA = SumVectorData / SumVector;
}

def htfTR = TrueRange(htfHi, htfCl, htfLo);
def ATR = atr(Length = ATRlength);
def hATR = WildersAverage(htfTR, ATRlength);

def almamed = alma(src, windowsize, almaOffset, almaSigma);
def hAlma = alma(htfSrc, windowsize, almaOffset, almaSigma);

def emaup    = almamed + (ATR*atrMultiplier1);
def emadw    = almamed - (ATR*atrMultiplier1);
def emahigh  = almamed + (ATR*atrMultiplier2);
def emalow   = almamed - (ATR*atrMultiplier2);
def emahighx = almamed + (ATR*atrMultiplier3);
def emalowx  = almamed - (ATR*atrMultiplier3);
def almatfpv    = if showHigherTimeframe then hAlma else na;
def almatfup    = almatfpv + (hATR*atrMultiplier1);
def almatfdw    = almatfpv - (hATR*atrMultiplier1);
def almatfhigh  = almatfpv + (hATR*atrMultiplier3);
def almatflow   = almatfpv - (hATR*atrMultiplier3);
def almatfhighx = almatfpv + (hATR*atrMultiplier3);
def almatflowx  = almatfpv - (hATR*atrMultiplier3);

plot alma = almamed; #,linewidth=2,color=purple)
plot almaUp = emaup; #, title="EMAUP", color=red)
plot almaDn = emadw; #, title="EMADW", color=green)
plot almaHi = emahigh; #, title="EMAHigh", color=red)
plot almaLo = emalow; #, title="EMALow", color=green)
plot alamSLshort = emahighx; #, title="StopLossShort", color=silver)
plot alamSLlong = emalowx; #, title="StopLossLong", color=silver)

plot almaHTF = almatfpv; #,linewidth=2,color=blue)
plot TFalmaUp = almatfup; #,linewidth=2,color=blue)
plot TFalmaDn = almatfdw; #,linewidth=2,color=blue)
plot TFalmaHi = almatfhigh; #,linewidth=2,color=red)
plot TFalmaLo = almatflow; #,linewidth=2,color=red)
plot TFalamSLshort = almatfhighx; #,linewidth=2,color=silver)
plot TFalamSLlong = almatflowx; #,linewidth=2,color=silver)

alma.SetLineWeight(2);
almaHTF.SetLineWeight(2);
alma.SetDefaultColor(Color.MAGENTA);
almaUp.SetDefaultColor(Color.RED);
almaDn.SetDefaultColor(Color.GREEN);
almaHi.SetDefaultColor(Color.RED);
almaLo.SetDefaultColor(Color.GREEN);
alamSLshort.SetDefaultColor(Color.GRAY);
alamSLlong.SetDefaultColor(Color.GRAY);
almaHTF.SetDefaultColor(Color.CYAN);
TFalmaUp.SetDefaultColor(Color.CYAN);
TFalmaDn.SetDefaultColor(Color.CYAN);
TFalmaHi.SetDefaultColor(Color.RED);
TFalmaLo.SetDefaultColor(Color.RED);
TFalamSLshort.SetDefaultColor(Color.GRAY);
TFalamSLlong.SetDefaultColor(Color.GRAY);

#-- END of CODe