• LIMITED TIME ONLY: Take $40 off VIP with code: BTD40.

Looking for DTOSC indicator

M

metaller

New member
VIP
Hi !
Does anybody know where to find thinkScript version if DTOSC indicator (Dynamic Trader OSCillator) from Robert C. Miner book "High probability trading strategies" ?
 
Sort by date Sort by votes
M

metaller

New member
VIP
Here is my version of DTOSC for ThinkOrSwim :
Code: 
declare lower;

input paramSet = 2;
input MAType = AverageType.EXPONENTIAL;

# parameter sets
def a = if paramSet == 1 then 8
   else if paramSet == 2 then 13
   else if paramSet == 3 then 21
                         else 34;

def b = if paramSet == 1 then 5
   else if paramSet == 2 then 8
   else if paramSet == 3 then 13
                         else 21;

def c = if paramSet == 1 then 3
   else if paramSet == 2 then 5
   else if paramSet == 3 then 8
                         else 13;

def d = if paramSet == 1 then 3
   else if paramSet == 2 then 5
   else if paramSet == 3 then 8
                         else 13;

# debug
# AddLabel(visible = Yes, text = "a=" + a + " b=" + b + " c=" + c + " d=" + d, color = Color.WHITE);

# logic
def storsi = 100 * ((rsi(a) - lowest(rsi(a), b))) / (highest(rsi(a), b) - lowest(rsi(a), b));

# main plots
plot dtosck = MovingAverage(MAType, storsi, c);
dtosck.SetDefaultColor(color.red);
dtosck.setLineWeight(1);

plot dtoscd = MovingAverage(MAType, dtosck, d);
dtoscd.SetDefaultColor(color.cyan);
dtoscd.setLineWeight(1);

# indicator lines cross - reversal
def bullish = dtosck crosses above dtoscd;
def bearish = dtosck crosses below dtoscd;

plot bullishArrow = if bullish then dtoscd else double.NaN;
bullishArrow.SetDefaultColor(color.white);
bullishArrow.SetLineWeight(5);
bullishArrow.SetPaintingStrategy(PaintingStrategy.ARROW_UP);

plot bearishArrow = if bearish then dtoscd else double.NaN;
bearishArrow.SetDefaultColor(color.white);
bearishArrow.SetLineWeight(5);
bearishArrow.SetPaintingStrategy(PaintingStrategy.ARROW_DOWN);

# static plots
plot overbought = 75;
overbought.SetDefaultColor(color.light_gray);
overbought.setLineWeight(1);
overbought.hideBubble();
overbought.hideTitle();

plot oversold = 25;
oversold.SetDefaultColor(color.light_gray);
oversold.setLineWeight(1);
oversold.hideBubble();
oversold.hideTitle();

# alerts
alert(bullish, "Bullish cross", alert.bar, sound.ring);
alert(bearish, "Bearish cross", alert.bar, sound.ring);
 
Upvote 1 Downvote
D

Dazeinhjk

New member
VIP
metaller said:
This is stochastic oscillator where input is RSI. This indicator was mentioned in "High probability trading strategies" book by Robert C. Miner. You can buy this book or download from Academia.edu for free.
Click to expand...

Great! Im reading the book. "A trade execution may be made following a smaller time
frame momentum reversal in the direction of the larger time frame momentum
trend."

Very good indicator you got it. I appreciated too much.
 
Upvote 0 Downvote
D

Dazeinhjk

New member
VIP
metaller said:
Could you explain your idea in more details ?
Click to expand...
The goal of this study, is to follow a smaller time frame momentum in the direction of the large timeframe momentum. If so, I imagine an indicator showing this situation between two timeframes. For example, a bullish arrow and bearish arrow appear in the study. The indicator that I was thinking is one where if in certain timeframes, the same arrow appears; it would be a buy signal. If and only if, it is above or below the white lines (oversold and overbought).
 
Upvote 0 Downvote
M

metaller

New member
VIP
Dazeinhjk said:
The goal of this study, is to follow a smaller time frame momentum in the direction of the large timeframe momentum. If so, I imagine an indicator showing this situation between two timeframes. For example, a bullish arrow and bearish arrow appear in the study. The indicator that I was thinking is one where if in certain timeframes, the same arrow appears; it would be a buy signal. If and only if, it is above or below the white lines (oversold and overbought).
Click to expand...
I see.
You have core functionality in script above. Feel free to update it according to your plan.
 
Upvote 0 Downvote
D

DaysOff

New member
Hi,

I revised the code above for the DTOSC to allow input of the four parameters rather than only having a few set choices.

Enjoy!

Code: 
declare lower;

input paramSet = 2;
input MAType = AverageType.EXPONENTIAL;
input RSIperiod = 8;
input StochPeriod = 5;
input StochSlowing = 3;
input StochSignal = 3;



# debug
# AddLabel(visible = Yes, text = "a=" + a + " b=" + b + " c=" + c + " d=" + d, color = Color.WHITE);

# logic
def storsi = 100 * ((rsi(RSIPeriod) - lowest(rsi(RSIPeriod), StochPeriod))) / (highest(rsi(RSIPeriod), StochPeriod) - lowest(rsi(RSIPeriod), StochPeriod));

# main plots
plot dtosck = MovingAverage(MAType, storsi, StochSlowing);
dtosck.SetDefaultColor(color.red);
dtosck.setLineWeight(1);

plot dtoscd = MovingAverage(MAType, dtosck, StochSignal);
dtoscd.SetDefaultColor(color.cyan);
dtoscd.setLineWeight(1);

# indicator lines cross - reversal
def bullish = dtosck crosses above dtoscd;
def bearish = dtosck crosses below dtoscd;

plot bullishArrow = if bullish then dtoscd else double.NaN;
bullishArrow.SetDefaultColor(color.white);
bullishArrow.SetLineWeight(5);
bullishArrow.SetPaintingStrategy(PaintingStrategy.ARROW_UP);

plot bearishArrow = if bearish then dtoscd else double.NaN;
bearishArrow.SetDefaultColor(color.white);
bearishArrow.SetLineWeight(5);
bearishArrow.SetPaintingStrategy(PaintingStrategy.ARROW_DOWN);

# static plots
plot overbought = 75;
overbought.SetDefaultColor(color.light_gray);
overbought.setLineWeight(1);
overbought.hideBubble();
overbought.hideTitle();

plot oversold = 25;
oversold.SetDefaultColor(color.light_gray);
oversold.setLineWeight(1);
oversold.hideBubble();
oversold.hideTitle();

# alerts
alert(bullish, "Bullish cross", alert.bar, sound.ring);
alert(bearish, "Bearish cross", alert.bar, sound.ring);
 
Upvote 0 Downvote
You must log in or register to reply here.
Thread starter Similar threads Forum Replies Date
G ripster watchlist using ema bands with macd been looking for a complete tos script i got ttm and macd but not sure how to add his chart logic Questions 4
manxtrader Looking for a drawing tool like TV/TC2000's Box/Profit Questions 2
B Looking for a Pre-Market Gap scanner that works Questions 0
F Looking for channel lanes? Or support/resistance? Questions 0
3AMBH Looking for FINAL code MTF MACD from Completed Heikin_Ashi Indicator pages Questions 3

Similar threads

Top