Label to only appear if true

[cappermac]

def isInsideBar = high < high[1] and low > low[1];
AssignPriceColor(if isInsideBar then Color.YELLOW else Color.CURRENT);

I am trying to have the code above appear as a label, only if true, when x number of days/candles is true. Otherwise no label is shown. And a WL if it's possible. Thank you.

 

[SleepyZ]

def isInsideBar = high < high[1] and low > low[1];
AssignPriceColor(if isInsideBar then Color.YELLOW else Color.CURRENT);

I am trying to have the code above appear as a label, only if true, when x number of days/candles is true. Otherwise no label is shown. And a WL if it's possible. Thank you.

Added optional label and bubble for you

def isInsideBar = high < high[1] and low > low[1];
AssignPriceColor(if isInsideBar then Color.YELLOW else Color.CURRENT);

input showlabel = yes;
AddLabel(showlabel and isInsideBar, "WL", Color.YELLOW);
input showbubble = yes;
addchartBubble(showbubble and isnan(close[2]) and !isnan(close[3]) and isinsidebar[3],close[3],"WL", color.yellow);

 

[cappermac]

This is perfect. Now I'm trying to set this to only aggregate for Daily time frame regardless of timeframe is on the chart. I thought I could select it. Thank you @SleepyZ

 

[cappermac]

Sorry was trying to see if this could show previous day inside bar as well if that helps.

 

[SleepyZ]

Sorry was trying to see if this could show previous day inside bar as well if that helps.

I think this may be more what you wanted. There are optional labels and bubbles that will only display when true.

There is a current vs prior input. The current will include today's inside bar, if any. The prior will exclude it.

The input xbarsinside will then test the sum function to see if there are at least that number in the input in_xdays lookback. If true, then the label and/or bubble will display.

input xbarsinside = 2;
input in_xdays    = 5;

input agg        = AggregationPeriod.DAY;
def isInsideBar  = high(period = agg) < high(period = agg)[1] and
                   low(period = agg) > low(period = agg)[1];
input pricecolor = yes;
AssignPriceColor(  if !pricecolor
                   then color.current       
                   else if isInsideBar
                   then Color.YELLOW else Color.CURRENT);

#Current includes inside bar today; Prior excludes today's inside bar, if any
input display        = {default current, prior};
def xdaysinside      = Sum(isInsideBar, in_xdays) >= xbarsinside;
def xpriordaysinside = Sum(isInsideBar[1], in_xdays) >= xbarsinside;

input showlabels = yes;
AddLabel(showlabels and display == display.current and xdaysinside, "Current", Color.YELLOW);
AddLabel(showlabels and display == display.prior and xpriordaysinside, "Prior", Color.YELLOW);

input showbubbles = yes;
AddChartBubble(showbubbles and IsNaN(close[2]) and !IsNaN(close[3]) and display == display.current and xdaysinside[3], close[3], "Current", Color.YELLOW);
AddChartBubble(showbubbles and IsNaN(close[2]) and !IsNaN(close[3]) and display == display.prior and xpriordaysinside[3], close[3], "Prior", Color.YELLOW);
;