Label-1st 1min bar higher than prev close show green label with word "UP"

[cc4digital]

Hi all,
Criteria- if 1st one-minute bar closes is higher than the previous close, then show a green label with the word "UP".

I know this can be done by comparing the current bar to the previous bar. But that is not what. I only want to compare the 1st one-minute bar to the previous day's close regardless of the current price after the 1st 1-minute bar.

Example:
The previous day's close was $100. The 1st one-minute close bar of today is $101 Therefore, the label would be green and have the word "UP" on it. But let's say that 2 hours later, the current one-minute bar close is $80. The label would still show the word UP as it does not look at any of the bars past the 1st one-minute bar until the next day.
)
I am unaware if this can be done, and I am hoping someone can give me some insight or even a small example to get me started. (If this is possible

Thank you for your time

Chuck

 

[halcyonguy]

Hi all,
Criteria- if 1st one-minute bar closes is higher than the previous close, then show a green label with the word "UP".

I know this can be done by comparing the current bar to the previous bar. But that is not what. I only want to compare the 1st one-minute bar to the previous day's close regardless of the current price after the 1st 1-minute bar.

Example:
The previous day's close was $100. The 1st one-minute close bar of today is $101 Therefore, the label would be green and have the word "UP" on it. But let's say that 2 hours later, the current one-minute bar close is $80. The label would still show the word UP as it does not look at any of the bars past the 1st one-minute bar until the next day.
)
I am unaware if this can be done, and I am hoping someone can give me some insight or even a small example to get me started. (If this is possible

Thank you for your time

Chuck

show a label,
if 1st x min bar is higher than prev day close, then green label with word UP
else red and down.

# compare_first_bar_prevday_00

# https://usethinkscript.com/threads/label-1st-1min-bar-higher-than-prev-close-show-green-label-with-word-up.14141/
#Label-1st 1min bar higher than prev close show green label with word "UP"

def na = double.nan;
def bn = barnumber();

#def diffday = if getday() != getday()[1] then 1 else 0;
def istoday = if GetLastDay() == GetDay() then 1 else 0;
def aftertoday = ( GetDay() > GetLastDay() );

#===============
# https://usethinkscript.com/threads/finding-the-first-and-last-bar-of-the-day-in-thinkorswim.526/
# korygill
def offset = 0;
def isRollover = GetYYYYMMDD() != GetYYYYMMDD()[1];
def beforeStart = GetTime() < RegularTradingStart(GetYYYYMMDD());
def afterEnd = GetTime() > RegularTradingEnd(GetYYYYMMDD());
def firstBarOfDay = if
    (beforeStart[1+offset] == 1 and beforeStart[offset] == 0) or
    (isRollover[offset] and beforeStart[offset] == 0) then 1
    else 0;
def lastBarOfDay = if
    (afterEnd[-1-offset] == 1 and afterEnd[offset] == 0) or
    (isRollover[-1-offset] and firstBarOfDay[-1-offset]) then 1
    else 0;
#====================


def prevday = if bn == 1 or aftertoday then na
 else if istoday then prevday[1]
 else if lastBarOfDay then close
 else prevday[1];

def firstbar = if bn == 1 or aftertoday then na else if firstBarOfDay then close else firstbar[1];

def bar1higher = if !firstBarOfDay then bar1higher[1] 
 else if firstbar > prevday then 1 else 0;


addlabel(1, " ", color.black);
input label = yes;
addlabel(label, 
(if bar1higher then "UP" else "DOWN"), 
(if bar1higher then color.green else color.red) );

input show_lines = yes;
plot z1 = if show_lines then prevday else na;
z1.SetPaintingStrategy(PaintingStrategy.HORIZONTAL);
z1.SetDefaultColor(Color.magenta);
#x.setlineweight(1);
z1.hidebubble();

plot z2 = if show_lines then firstbar else na;
z2.SetPaintingStrategy(PaintingStrategy.HORIZONTAL);
z2.SetDefaultColor(Color.cyan);
#x.setlineweight(1);
z2.hidebubble();


#--------------------------
input test1 = no;
addchartbubble(test1, low,
bn + "\n" +
GetDay() + "\n" +
getlastday() + "\n" +
aftertoday + " a\n" +
 bar1higher + "\n" +
(if bar1higher then "UP" else "DOWN")
#(if bar1higher then color.green else color.red) );
, color.yellow, no);

#