How to put SPY /macd into other underlying as a indicator

[BaliMonk]

So looking to find a indicator that will show the spy performance as MACD histogram or RSI. This is my first post and this has been on of my mind for some time when trading options.

 

[Chemmy]

So looking to find a indicator that will show the spy performance as MACD histogram or RSI. This is my first post and this has been on of my mind for some time when trading options.

Interesting idea, if what you mean by this is to just use the SPY data as a replacement for the underlying stock chart data to create a MACD study, then this should be what you want -- all you really need to do is replace the close value with the close of SPY:

declare lower;

input fastLength = 12;
input slowLength = 26;
input MACDLength = 9;
input averageType = AverageType.EXPONENTIAL;
input showBreakoutSignals = no;

def SPY = close(symbol = "SPY");


plot Value = MovingAverage(averageType, SPY, fastLength) - MovingAverage(averageType, SPY, slowLength);
plot Avg = MovingAverage(averageType, Value, MACDLength);

plot Diff = Value - Avg;
plot ZeroLine = 0;

plot UpSignal = if Diff crosses above ZeroLine then ZeroLine else Double.NaN;
plot DownSignal = if Diff crosses below ZeroLine then ZeroLine else Double.NaN;

UpSignal.SetHiding(!showBreakoutSignals);
DownSignal.SetHiding(!showBreakoutSignals);

Value.SetDefaultColor(GetColor(1));
Avg.SetDefaultColor(GetColor(8));
Diff.SetDefaultColor(GetColor(5));
Diff.SetPaintingStrategy(PaintingStrategy.HISTOGRAM);
Diff.SetLineWeight(3);
Diff.DefineColor("Positive and Up", Color.GREEN);
Diff.DefineColor("Positive and Down", Color.DARK_GREEN);
Diff.DefineColor("Negative and Down", Color.RED);
Diff.DefineColor("Negative and Up", Color.DARK_RED);
Diff.AssignValueColor(if Diff >= 0 then if Diff > Diff[1] then Diff.color("Positive and Up") else Diff.color("Positive and Down") else if Diff < Diff[1] then Diff.color("Negative and Down") else Diff.color("Negative and Up"));
ZeroLine.SetDefaultColor(GetColor(0));
UpSignal.SetDefaultColor(Color.UPTICK);
UpSignal.SetPaintingStrategy(PaintingStrategy.ARROW_UP);
DownSignal.SetDefaultColor(Color.DOWNTICK);
DownSignal.SetPaintingStrategy(PaintingStrategy.ARROW_DOWN);

The same logic should hold true if you want to do the same type of thing with RSI as well -- let me know if you have any questions about this