How to count the number of EMA crossovers in the past days?

[thomas2004ch]

Hi,

I want to get the number of the EMA5 crosses above EMA20 in the past 10 days for example. Here is my script. But it outputs 0. There must be something wrong.

declare lower;

def MyEMA1 = expAverage(5);
def MyEMA2 = expAverage(15);

def CrossOver = MyEMA1 crosses above MyEMA2;

def MyCount = Sum(CrossOver, 10);

plot scan = MyCount;

 

[BenTen]

See this page https://usethinkscript.com/google-search/?q=count+the+number+crossovers

 

[halcyonguy]

Hi,

I want to get the number of the EMA5 crosses above EMA20 in the past 10 days for example. Here is my script. But it outputs 0. There must be something wrong.

your expAverage( ) code is wrong
you only put in 1 parameter, but the length is the 2nd parameter. your length numbers are being used as the first parameter, price levels. they are always the same, so no crosses.

if not using all the parameters in a function, should use the parameter names

def MyEMA1 = expAverage( data = close, length = avg_len1 );

https://toslc.thinkorswim.com/center/reference/thinkScript/Functions/Tech-Analysis/ExpAverage

side note, use more variables. this will allow you to change things . my first thought was the length was too short so i made it 50. nothing.
then i added average lines to the chart to verify what is happening.

declare lower;
input bars_back = 10;
input avg_len1 = 5;
input avg_len2 = 15;

def MyEMA1 = expAverage(close, avg_len1);
def MyEMA2 = expAverage(close, avg_len2);

def Crossup = MyEMA1 crosses above MyEMA2;
def upCount = Sum(Crossup, bars_back);
plot z = upCount;
#

---------------------------------------
average lines

# avgs3

def na = double.nan;
def bn = barnumber();

#https://toslc.thinkorswim.com/center/reference/thinkScript/Constants/AverageType
#input avg1_type = AverageType.Simple;
#input avg1_type = AverageType.exponential;
#input avg1_type = AverageType.hull;
#input avg1_type = AverageType.weighted;
#input avg1_type = AverageType.wilders;

def data = close;
input avg1_type = AverageType.Simple;
input avg1_length = 22;
def avg1 = MovingAverage(avg1_type, data, avg1_length );

input avg2_type = AverageType.Simple;
input avg2_length = 55;
def avg2 = MovingAverage(avg2_type, data, avg2_length );

input avg3_type = AverageType.Simple;
input avg3_length = 99;
def avg3 = MovingAverage(avg3_type, data, avg3_length );

input show_avg1_line = yes;
input show_avg2_line = no;
input show_avg3_line = no;
plot zavg1 = if show_avg1_line then avg1 else na;
plot zavg2 = if show_avg2_line then avg2 else na;
plot zavg3 = if show_avg3_line then avg3 else na;

zavg1.SetDefaultColor(Color.cyan);
zavg1.setlineweight(1);
zavg1.hidebubble();

zavg2.SetDefaultColor(Color.yellow);
zavg2.setlineweight(1);
zavg2.hidebubble();

zavg3.SetDefaultColor(Color.magenta);
zavg3.setlineweight(1);
zavg3.hidebubble();
#