How to add a simple bollinger band to this lower custom study?

[tempestlight]

Hi there,

Is there a way to add a 20-day moving average bollinger band to this code?

declare lower;
plot StockPrice = close(GetUnderlyingSymbol(), priceType=PriceType.LAST );

Also, is there a way to make the lower study display in candle sticks? Thanks!

 

[Pensar]

@tempestlight Here you go. I simply added the default Bollinger Band code to a candlestick code.
Edit: I realized that you are likely trading options by the use of GetUnderlyingSymbol(), so the code is corrected to use the underlying for both the Bollinger Bands and candlesticks.

declare lower;

def o = open(GetUnderlyingSymbol());
def c = close(GetUnderlyingSymbol());
def h = high(GetUnderlyingSymbol());
def l = low(GetUnderlyingSymbol());
def n = double.nan;

input displace = 0;
input length = 20;
input Num_Dev_Dn = -2.0;
input Num_Dev_up = 2.0;
input averageType = AverageType.SIMPLE;

def sDev = StDev(data = c[-displace], length = length);

plot MidLine = MovingAverage(averageType, data = c[-displace], length = length);
plot LowerBand = MidLine + Num_Dev_Dn * sDev;
plot UpperBand = MidLine + Num_Dev_up * sDev;

LowerBand.SetDefaultColor(GetColor(0));
MidLine.SetDefaultColor(GetColor(1));
UpperBand.SetDefaultColor(GetColor(5));

AddChart(high = if c > o then h else n,
         low = if c > o then l else n,
         close = if c > o then c else n,
         open = if c > o then o else n,
         ChartType.CANDLE, Color.GREEN);
AddChart(high = if c < o then h else n,
         low = if c < o then l else n,
         open = if c < o then o else n,
         close = if c < o then c else n,
         ChartType.CANDLE, Color.RED);
AddChart(high = if c == o then h else n,
         low = if c == o then l else n,
         open = if c == o then o else n,
         close = if c == o then c else n,
         ChartType.CANDLE, Color.WHITE);

 

[tempestlight]

@tempestlight Here you go. I simply added the default Bollinger Band code to a candlestick code.
Edit: I realized that you are likely trading options by the use of GetUnderlyingSymbol(), so the code is corrected to use the underlying for both the Bollinger Bands and candlesticks.

This is perfect man, really appreciate it!!

 

[tempestlight]

@tempestlight Here you go. I simply added the default Bollinger Band code to a candlestick code.
Edit: I realized that you are likely trading options by the use of GetUnderlyingSymbol(), so the code is corrected to use the underlying for both the Bollinger Bands and candlesticks.

Quick question, do you know if it's possible to add the closing bar price here?

 

[Pensar]

@tempestlight Add this to your code -

def x = if !isnan(c) && isnan(c[-1]) then c else x[1];
plot line = if isnan(c[-1]) then x else n;
line.setdefaultcolor(color.white);