how to add a different timeframe level condition?

[oldyoungguy]

I have the following thinkscript and I plan to use it in 1 minute charts.

def mve13 = MovAvgExponential("length" = 13);

def mve24 = MovAvgExponential("length" = 24);

plot Buy =mve13 crosses above mve24;

Buy.SetPaintingStrategy(PaintingStrategy.BOOLEAN_ARROW_UP);



Now I want to add another condition that should come from the 5 minutes timeframe. The condition is this:

def isGreen = HeikinAshiDiff() > 0;

So the result plot statement may look like this:

plot Buy =mve13 crosses above mve24 && isGreen;

But how can I tell thinkScript to get the "isGreen" from a higher level timeframe?

 

[SleepyZ]

I have the following thinkscript and I plan to use it in 1 minute charts.

def mve13 = MovAvgExponential("length" = 13);

def mve24 = MovAvgExponential("length" = 24);

plot Buy =mve13 crosses above mve24;

Buy.SetPaintingStrategy(PaintingStrategy.BOOLEAN_ARROW_UP);



Now I want to add another condition that should come from the 5 minutes timeframe. The condition is this:

def isGreen = HeikinAshiDiff() > 0;

So the result plot statement may look like this:

plot Buy =mve13 crosses above mve24 && isGreen;

But how can I tell thinkScript to get the "isGreen" from a higher level timeframe?

In this situation where there is not an aggregationperiod that is available in using the reference to the HeikinAshiDiff() indicator, you need to include the relevant portions of the indicator in your scipt to def isgreen. See below.

def mve13 = MovAvgExponential("length" = 13);
def mve24 = MovAvgExponential("length" = 24);

input agg = AggregationPeriod.FIVE_MIN;
def o = open(period = agg);
def h = high(period = agg);
def l = low(period = agg);
def c = close(period = agg);

def haclose = (o + h + l + c) / 4;
def haopen = CompoundValue(1, (haopen[1] + haclose[1]) / 2, (o[1] + c[1]) / 2);
def HAdiff = haclose - haopen;

def isGreen = HAdiff > 0;

plot Buy =mve13 crosses above mve24 && isGreen;
Buy.SetPaintingStrategy(PaintingStrategy.BOOLEAN_ARROW_UP);
# End Code