How do I create a subset of data?

[Arrive8848]

My goal is to Average the green candlestick bodies and the red candlestick bodies separately. I can easily parse out the green candlesticks over a range, but I cannot seem to figure out a way to ignore the red values. For example, using a simple "if/then" statement I can differentiate between green and red. But I have to do something with the red. If I set it to zero or any positive number, the average is skewed. I need to actually just ignore it altogether, i.e. creating a subset of the whole. I am not used to languages that require an "else" to the "if" statement! In every other language I know, I would just have an "if" statement by itself. This would automatically discard anything that does not satisfy the "if" statement requirements.

Figure 1: Example dataset with various results

Figure 2: Example code for column "RPL w/ avg" above

def greenCandles;
switch(METRIC) {
    case "open/close":
        if(close > open) { # Green candle
            greenCandles = 100 - (open / close) * 100;
        } else { # Red candle
            greenCandles = Average((100 - (open / close) * 100), LENGTH);
        }
    case "low/high":
        if(close > open) {
            greenCandles = 100 - (low / high) * 100;
        } else {
            greenCandles = Average((100 - (low / high) * 100), LENGTH);
        }
}

 

[mashume]

So ToS doesn't work quite like you may think. ThinkScript is a largely functional programming language.

This script will give you the average of the up and down bars in the last 20 bars, or whatever you set it to. It DOES NOT give you the average of the last 20 up bars or down bars. That's beyond by ability.

-mashume

declare lower;

input lookback = 50;

def upBodySize = if close > open then close - open else Double.NaN;
def isUpCandle =  if close > open then 1 else 0;


def dnBodySize = if close < open then  -(close - open) else Double.NaN;
def isDnCandle =  if close < open then 1 else 0;

def upCandleCount = Sum(isUpCandle, lookback);
def dnCandleCount = Sum(isDnCandle, lookback);


def upCandleSums = fold i = 0 to lookback with s do s + if !isNan(upBodySize[i]) then upBodySize[i] else 0;

def dnCandleSums = fold k = 0 to lookback with d do d + if !isNan(dnBodySize[k]) then dnBodySize[k] else 0;


plot avgUpCandleSize = upCandleSums / upCandleCount;
plot avgDnCandleSize = dnCandleSums / dnCandleCount;

avgUpCandleSize.SetDefaultColor(color.dark_green);
avgDnCandleSize.SetDefaultColor(color.dark_red);

AddLabel(yes, "  Last " + lookback + " bars: " + upCandleCount + " up bars     " , Color.DARK_GREEN);
AddLabel(yes, "  Last " + lookback + " bars: " + dnCandleCount + " down bars     " , Color.DARK_RED);

# AddLabel(yes, "  Current Up sum: " + upCandleSums + "    ", color.dark_green);
# AddLabel(yes, "  Current Down sum: " + dnCandleSums + "    ", color.dark_red);

 

[Jman831]

My goal is to Average the green candlestick bodies and the red candlestick bodies separately. I can easily parse out the green candlesticks over a range, but I cannot seem to figure out a way to ignore the red values. For example, using a simple "if/then" statement I can differentiate between green and red. But I have to do something with the red. If I set it to zero or any positive number, the average is skewed. I need to actually just ignore it altogether, i.e. creating a subset of the whole. I am not used to languages that require an "else" to the "if" statement! In every other language I know, I would just have an "if" statement by itself. This would automatically discard anything that does not satisfy the "if" statement requirements.

Figure 1: Example dataset with various results

View attachment 22821

Figure 2: Example code for column "RPL w/ avg" above

def greenCandles;
switch(METRIC) {
    case "open/close":
        if(close > open) { # Green candle
            greenCandles = 100 - (open / close) * 100;
        } else { # Red candle
            greenCandles = Average((100 - (open / close) * 100), LENGTH);
        }
    case "low/high":
        if(close > open) {
            greenCandles = 100 - (low / high) * 100;
        } else {
            greenCandles = Average((100 - (low / high) * 100), LENGTH);
        }
}

I think I may have a solution for separating them, not to take away from mashume's solution, I have nothing but respect for mashume and his contributions.

Plug this code in and let me know if it's what you're looking for or if I misunderstood something.

declare lower;

input lookBack = 50;

def greenbody = if close > open then close - open else 0;
def redbody = if close < open then open - close else 0;

def totgreenbody = sum(greenbody, lookBack);
def totredbody = sum(redbody, lookBack);

def avggreenbody = totgreenbody / sum(close > open, lookBack);
def avgredbody = totredbody / sum(close < open, lookBack);

plot AverageGreenBody = avggreenbody;
plot AverageRedBody = avgredbody;

AverageGreenBody.setDefaultColor(color.GREEN);
AverageRedBody.setDefaultColor(color.RED);