HiLoActivator

[David45]

Does anyone know how to make the following changes to this indicator?

1. Paint the candlesticks the same color as the lines above and below the candlesticks

2. Have an option to change the moving average type (simple, exponential, weighted, wilders, hull)

https://tlc.thinkorswim.com/center/reference/Tech-Indicators/studies-library/G-L/HiLoActivator

input length = 3;

def maHigh = Average(high, length);
def maLow = Average(low, length);
def state = {default init, short, long};
if (close > maHigh) {
state = state.long;
} else if (close < maLow) {
state = state.short;
} else {
state = state[1];
}

plot BuyStop = if state == state.short or state != state[1] then maHigh else Double.NaN;
plot SellStop = if state == state.long or state != state[1] then maLow else Double.NaN;

BuyStop.SetDefaultColor(GetColor(0));
SellStop.SetDefaultColor(GetColor(1));

 

[Joshua]

input length = 3;
input AvgType = AverageType.SIMPLE;

def maHigh = MovingAverage(AvgType,high, length);
def maLow = MovingAverage(AvgType,low, length);
def state = {default init, short, long};

if (close > maHigh) {
state = state.long;
} else if (close < maLow) {
state = state.short;
} else {
state = state[1];
}

plot BuyStop = if state == state.short or state != state[1] then maHigh else Double.NaN;
plot SellStop = if state == state.long or state != state[1] then maLow else Double.NaN;

BuyStop.SetDefaultColor(GetColor(0));
SellStop.SetDefaultColor(GetColor(1));

AssignPriceColor(if State == State.Long then SellStop.takevalueColor() else BuyStop.takevalueColor());

 

[David45]

input length = 3;
input AvgType = AverageType.SIMPLE;

def maHigh = MovingAverage(AvgType,high, length);
def maLow = MovingAverage(AvgType,low, length);
def state = {default init, short, long};

if (close > maHigh) {
state = state.long;
} else if (close < maLow) {
state = state.short;
} else {
state = state[1];
}

plot BuyStop = if state == state.short or state != state[1] then maHigh else Double.NaN;
plot SellStop = if state == state.long or state != state[1] then maLow else Double.NaN;

BuyStop.SetDefaultColor(GetColor(0));
SellStop.SetDefaultColor(GetColor(1));

AssignPriceColor(if State == State.Long then SellStop.takevalueColor() else BuyStop.takevalueColor());

Okay so I had a crazy idea. Instead of using (simple, exponential, weighted, wilders, or hull) is there a way to use the McGinley Dynamic Moving Average with this indictor instead?

Here is the simplified code for the McGinely Dymanic Moving Average as seen in Post #1 here:
https://usethinkscript.com/threads/mcginley-dynamic-indicator-for-thinkorswim.338/

input periods = 10;

rec _md = CompoundValue( 1, _md[1] + (( close - _md[1] ) / ( periods * Power( close / _md[1], 4 ) ) ), close );

plot MD = _md;

 

[Joshua]

input periods  = 3;
def maHigh = CompoundValue( 1, maHigh[1] + (( high - maHigh[1] ) / ( periods * Power( high / maHigh[1], 4 ) ) ), high );
def maLow = CompoundValue( 1, maLow[1] + (( low - maLow[1] ) / ( periods * Power( low / maLow[1], 4 ) ) ), low );
def state = {default init, short, long};

if (close > maHigh) {
state = state.long;
} else if (close < maLow) {
state = state.short;
} else {
state = state[1];
}

plot BuyStop = if state == state.short or state != state[1] then maHigh else Double.NaN;
plot SellStop = if state == state.long or state != state[1] then maLow else Double.NaN;

BuyStop.SetDefaultColor(GetColor(0));
SellStop.SetDefaultColor(GetColor(1));

AssignPriceColor(if State == State.Long then SellStop.takevalueColor() else BuyStop.takevalueColor());

 

[David45]

Would anyone like to take a stab at creating a Heikin Ashi version of the HiLoActivator indicator? It would be very interesting to see how it would plot vs the standard version in TOS or the McGinley version above which @Joshua so graciously created.

 

[Joshua]

I'm not familiar with meme bars to be honest, and I am posting from my phone. Can't you just change the chart type from the style menu?

 

[SleepyZ]

Would anyone like to take a stab at creating a Heikin Ashi version of the HiLoActivator indicator? It would be very interesting to see how it would plot vs the standard version in TOS or the McGinley version above which @Joshua so graciously created.

See if this is what you wanted

#
# TD Ameritrade IP Company, Inc. (c) 2020-2022
#

input length = 3;

def HAclose   =  (open + high + low + close) / 4;
def HAopen    = CompoundValue( 1, ( HAopen[1] + HAclose[1] ) / 2, HAclose );
def HAhigh    = Max( high, Max( HAopen, HAclose ) );
def HAlow     = Min( low, Min( HAopen, HAclose ) );

def maHigh = Average(HAhigh, length);
def maLow = Average(HAlow, length);
def state = {default init, short, long};
if (HAclose > maHigh) {
    state = state.long;
} else if (HAclose < maLow) {
    state = state.short;
} else {
    state = state[1];
}

plot BuyStop = if state == state.short or state != state[1] then maHigh else Double.NaN;
plot SellStop = if state == state.long or state != state[1] then maLow else Double.NaN;

BuyStop.SetDefaultColor(GetColor(0));
SellStop.SetDefaultColor(GetColor(1));

AssignPriceColor(if State == State.Long then SellStop.takevalueColor() else BuyStop.takevalueColor());

BuyStop.SetDefaultColor(GetColor(0));
SellStop.SetDefaultColor(GetColor(1));

 

[Gellidus]

Are you able to share the code?

 

[SleepyZ]

Are you able to share the code?

It is below the image in post #7. Click the Click to Expand and it is below the image.

 

[David45]

I'm not familiar with meme bars to be honest, and I am posting from my phone. Can't you just change the chart type from the style menu?

Thanks so much for your reply Joshua! SleepyZ was able to figure this one out for me.

 

[David45]

See if this is what you wanted

Yes! Nailed it. This is exactly what I was trying to do but I could not figure it out despite numerous attempts. Thank you so much!