• Get $40 off VIP by signing up for a free account! Sign Up

high of certain period before certain time

Alex17

New member
Hello everyone,
I'm wondering if there is a way to possible have an indicator or maybe a column in the watchlist that shows the time of the current High of the Day? Meaning it will show the time, for example 14:56, at which the HOD was set. I really need this feature, and I hope someone can help me out!

Perhaps a column that doesn't have to be maintained thorough the day, meaning it will work only at the end of the day, so that it requires less coding. I just want to look at my watchlist at the end of the day and see the high and its time. What do you mean by checking it in the center? I checked out the learning center a bit, but I haven't seen custom scripts there or something. I also contacted the customer support and they told me to come here and ask.
 
Last edited by a moderator:
Hello everyone,
I'm wondering if there is a way to possible have an indicator or maybe a column in the watchlist that shows the time of the current High of the Day? Meaning it will show the time, for example 14:56, at which the HOD was set. I really need this feature, and I hope someone can help me out!
See if this helps. TOS has a warning that it could take time to load as it is somewhat complex. You must have the watchlist column at the same time setting as the chart being viewed. You can choose the timezone format for the time in the code. See the attached example of how CMG will display the time in the watchlist. The chart has the same code as the watchlist with the high also being displayed.
Code:
#Watchlist Column - High of Day and Time Occurred
#20210529 Sleepyz = UseThinkscript Request
#Watchlist Time must match Chart Time being Viewed

#Time Defined
input timezone = {default "ET", "CT", "MT", "PT"};

def starthour  = (if timezone == timezone."ET"
                        then 9
                        else if timezone == timezone."CT"
                        then 8
                        else if timezone == timezone."MT"
                        then 7
                        else 6) ;
def hour = Floor(((starthour * 60 + 30) + (GetTime() - RegularTradingStart(GetYYYYMMDD())) / 60000) / 60);
def minutes = (GetTime() - RegularTradingStart(GetYYYYMMDD())) / 60000 - ((hour - starthour) * 60 + 30) + 60;

#Highest High during RTH
def begin      = CompoundValue(1, if gettime() crosses above regularTradingStart(getyyyYMMDD())
                                       then high
                                       else if high > begin[1]
                                       then high
                                       else begin[1]
                                  , begin[1]);
def beginbn    = if GetDay() == GetLastDay()
                 then if high == begin
                      then BarNumber()
                      else beginbn[1]
                 else 0;
def highday    = if BarNumber() == HighestAll(beginbn)
                 then high
                 else highday[1];
def hihr    = if  high == highday then hour else hihr[1];
def himin   = if  high == highday then minutes else himin[1];

AddLabel(1, (hihr + ":") +
           (if himin < 10
            then "0" + himin
            else  "" + himin), Color.WHITE);
Capture.jpg
 

Join useThinkScript to post your question to a community of 21,000+ developers and traders.

See if this helps. TOS has a warning that it could take time to load as it is somewhat complex. You must have the watchlist column at the same time setting as the chart being viewed. You can choose the timezone format for the time in the code. See the attached example of how CMG will display the time in the watchlist. The chart has the same code as the watchlist with the high also being displayed.
Wow, thank you, but I don't understand any of that. If it's not difficult for you, can briefly explain how to use this code to find the Time of HOD. Also what do you mean by "You must have the watchlist column at the same time setting as the chart being viewed"? What time? I just want the column to be based on today's action.
 
Wow, thank you, but I don't understand any of that. If it's not difficult for you, can briefly explain how to use this code to find the Time of HOD. Also what do you mean by "You must have the watchlist column at the same time setting as the chart being viewed"? What time? I just want the column to be based on today's action.
If you look at the watchlist, you will see that CMG reached its daily high at 13:15 ET yesterday, the same as the time displayed on the chart label. The chart has 10:15 on the time line, which is what I use set on Pacific Time and did not change in the example, but would be 13:15 also on the ET timezone. The time is meant to be based on today's action. I just wrote this and have not had a chance to test it live as watchlist columns do not work well in ONDEMAND.

The watchlist column has a time basis just like you can select on the chart. The watchlist column's code must have the same time selected as the chart being viewed for the time to match between the two. Both the chart and the watchlist in the example used 1 minute chart times.
 
If you look at the watchlist, you will see that CMG reached its daily high at 13:15 ET yesterday, the same as the time displayed on the chart label. The chart has 10:15 on the time line, which is what I use set on Pacific Time and did not change in the example, but would be 13:15 also on the ET timezone. The time is meant to be based on today's action. I just wrote this and have not had a chance to test it live as watchlist columns do not work well in ONDEMAND.

The watchlist column has a time basis just like you can select on the chart. The watchlist column's code must have the same time selected as the chart being viewed for the time to match between the two. Both the chart and the watchlist in the example used 1 minute chart times.
Yeah I see, but when I put the code you sent me to my watchlist, it just gives me the same “1:00” for every stock. What do I need to change it in so it works? Very appreciate your help!
 
See if this helps. TOS has a warning that it could take time to load as it is somewhat complex. You must have the watchlist column at the same time setting as the chart being viewed. You can choose the timezone format for the time in the code. See the attached example of how CMG will display the time in the watchlist. The chart has the same code as the watchlist with the high also being displayed.
If a stock has reached its high multiple times intraday, the code would show the last time. How can I make it show the first time it sets HOD

Additionally, how do I get the time for Low of day ?
 
If a stock has reached its high multiple times intraday, the code would show the last time. How can I make it show the first time it sets HOD

Additionally, how do I get the time for Low of day ?

This first code below displays the time happened in optional labels for the First New higher high after the start of regular trading hours and the Highest High for regular trading hour.

The second code displays the time happened in optional labels for the First New lower low after the start of regular trading hour and the Lowest Low for regular trading hours.

Ruby:
#Watchlist Column - High of Day and Time Occurred
#20210529 Sleepyz = UseThinkscript Request
#Watchlist Time must match Chart Time being Viewed

input showlabel_HH       = yes;
input showlabel_First_HH = yes;
#Time Defined
input timezone = {default "ET", "CT", "MT", "PT"};

def starthour  = (if timezone == timezone."ET"
                        then 9
                        else if timezone == timezone."CT"
                        then 8
                        else if timezone == timezone."MT"
                        then 7
                        else 6) ;
def hour = Floor(((starthour * 60 + 30) + (GetTime() - RegularTradingStart(GetYYYYMMDD())) / 60000) / 60);
def minutes = (GetTime() - RegularTradingStart(GetYYYYMMDD())) / 60000 - ((hour - starthour) * 60 + 30) + 60;
def bn  = BarNumber();

#Highest High during RTH
def begin      = CompoundValue(1,
                  if GetTime() crosses above RegularTradingStart(GetYYYYMMDD())
                   then high else
                  if high > begin[1]
                   then high
                  else begin[1], begin[1]);

def beginbn    = if GetDay() == GetLastDay()
                 then if high == begin
                      then BarNumber()
                      else beginbn[1]
                 else 0;
def highday    = if BarNumber() == HighestAll(beginbn)
                 then high
                 else highday[1];
def hihr    = if  high == highday then hour else hihr[1];
def himin   = if  high == highday then minutes else himin[1];

AddLabel(showlabel_HH, (hihr + ":") +
           (if himin < 10
            then "0" + himin
            else  "" + himin), Color.WHITE);

#Time of First new high bar after high of the opening for Regular Trading Hours
def higherhigh  = if GetTime() crosses above RegularTradingStart(GetYYYYMMDD()) and
                      beginbn
                    then 1 else
                   if beginbn != beginbn[1]
                    then higherhigh[1] + 1
                   else higherhigh[1];
def Firstnewhigh = if higherhigh == 2 and higherhigh[1] == 1
                    then bn
                   else Double.NaN;

def firsthr    = if bn == HighestAll(firstnewhigh) then hour else firsthr[1];
def firstmin   = if bn == HighestAll(firstnewhigh) then minutes else firstmin[1];

AddLabel(showlabel_First_HH,
           (firsthr + ":") +
           (if firstmin < 10
            then "0" + firstmin
            else  "" + firstmin), Color.YELLOW);

Ruby:
#First_LL_Watchlist_TimeHappened
#Watchlist Time must match Chart Time being Viewed

input showlabel_LL       = yes;
input showlabel_First_LL = yes;
input timezone = {default "ET", "CT", "MT", "PT"};

def starthour  = (if timezone == timezone."ET"
                        then 9
                        else if timezone == timezone."CT"
                        then 8
                        else if timezone == timezone."MT"
                        then 7
                        else 6) ;
def hour = Floor(((starthour * 60 + 30) + (GetTime() - RegularTradingStart(GetYYYYMMDD())) / 60000) / 60);
def minutes = (GetTime() - RegularTradingStart(GetYYYYMMDD())) / 60000 - ((hour - starthour) * 60 + 30) + 60;

#Lowest Low During RTH
def bn     = BarNumber();
def begin1 = CompoundValue(1,  if GetTime() crosses above RegularTradingStart(GetYYYYMMDD())
                               then low
                               else if low < begin1[1]
                               then low
                               else begin1[1],
                              low);
def beginbn1    = if GetDay() == GetLastDay()
                  then if low == begin1
                       then bn
                       else beginbn1[1]
                  else 0;
def lowday     = if bn == HighestAll(beginbn1)
                 then low
                 else lowday[1];

def lowhr    = if low == lowday then hour else lowhr[1];
def lowmin   = if low == lowday then minutes else lowmin[1];
AddLabel(showlabel_LL,
           (lowhr + ":") +
           (if lowmin < 10
            then "0" + lowmin 
            else  "" + lowmin ) , Color.WHITE);

#Time of First new low bar after low of the opening for Regular Trading Hours
def lowerlow     = if GetTime() crosses above RegularTradingStart(GetYYYYMMDD()) and
                      beginbn1
                    then 1 else
                   if beginbn1 != beginbn1[1]
                    then lowerlow[1] + 1
                   else lowerlow[1];
def Firstnewlow = if lowerlow == 2 and lowerlow[1] == 1
                    then bn
                   else Double.NaN;

def firsthr    = if bn == HighestAll(Firstnewlow) then hour else firsthr[1];
def firstmin   = if bn == HighestAll(Firstnewlow) then minutes else firstmin[1];

AddLabel(showlabel_First_LL,
           (firsthr + ":") +
           (if firstmin < 10
            then "0" + firstmin
            else  "" + firstmin), Color.YELLOW);
 
This first code below displays the time happened in optional labels for the First New higher high after the start of regular trading hours and the Highest High for regular trading hour.

The second code displays the time happened in optional labels for the First New lower low after the start of regular trading hour and the Lowest Low for regular trading hours.
Thanks, the code contain 2 labels, the first one during RTH is good for me.

But it still has that problem: The code would pick the 'last time' rather than the 'first time' to show, if a stock set the same High or same Low multiple times throughout the day. How do I adjust it so that it can show the 'first time'
 
Thanks, the code contain 2 labels, the first one during RTH is good for me.

But it still has that problem: The code would pick the 'last time' rather than the 'first time' to show, if a stock set the same High or same Low multiple times throughout the day. How do I adjust it so that it can show the 'first time'

Each code has both the first and last time of either highs or lows. See image below

 
Each code has both the first and last time of either highs or lows. See image below
Just saw the picture you sent, there‘s some misunderstanding on this

I refer to just one high, the high of day, not something like 'first high' and 'last high' you mark in the picture

For example, stock A's high of day is $10, it reaches $10 at 9:45, and then had some pull back. Later at 10:40, it reaches $10 again. In cases like this, your code would show the HOD time as 10:40. How do I make it show 9:45 ?
 
Just saw the picture you sent, there‘s some misunderstanding on this

I refer to just one high, the high of day, not something like 'first high' and 'last high' you mark in the picture

For example, stock A's high of day is $10, it reaches $10 at 9:45, and then had some pull back. Later at 10:40, it reaches $10 again. In cases like this, your code would show the HOD time as 10:40. How do I make it show 9:45 ?

Thank you for explaining. Here is the high/low of day displaying the time that it first occurred if there were multiple times the high/low of the day were reached.

High of Day
Ruby:
#Watchlist Column - High of Day and Time Occurred
#20210529 Sleepyz = UseThinkscript Request
#Watchlist Time must match Chart Time being Viewed

input showlabel_HH       = yes;
input showlabel_First_HH = yes;
#Time Defined
input timezone = {default "ET", "CT", "MT", "PT"};

def starthour  = (if timezone == timezone."ET"
                        then 9
                        else if timezone == timezone."CT"
                        then 8
                        else if timezone == timezone."MT"
                        then 7
                        else 6) ;

def hour = Floor(((starthour * 60 + 30) + (GetTime() - RegularTradingStart(GetYYYYMMDD())) / 60000) / 60);

def minutes = (GetTime() - RegularTradingStart(GetYYYYMMDD())) / 60000 - ((hour - starthour) * 60 + 30) + 60;

#Highest High during RTH
def bn  = BarNumber();
def rth = Between(GetTime(), RegularTradingStart(GetYYYYMMDD()), RegularTradingEnd(GetYYYYMMDD()));

def multihighs = if GetDay() == GetLastDay() and rth
                 then if high == high(period = AggregationPeriod.DAY)
                      then multihighs[1] + 1
                      else multihighs[1]
                 else 0;

def firsthibn    = if multihighs[1] == 0 and multihighs == 1
                   then bn
                   else firsthibn[1];

def hihr    = if Bn == HighestAll(firsthibn) then hour else hihr[1];
def himin   = if Bn == HighestAll(firsthibn) then minutes else himin[1];

AddLabel(showlabel_HH, (hihr + ":") +
           (if himin < 10
            then "0" + himin
            else  "" + himin), Color.light_green);

Low of Day
Ruby:
#Watchlist Column - Low of Day and Time Occurred
#20210529 Sleepyz = UseThinkscript Request
#Watchlist Time must match Chart Time being Viewed


input showlabel_First_LL = yes;
#Time Defined
input timezone = {default "ET", "CT", "MT", "PT"};

def starthour  = (if timezone == timezone."ET"
                        then 9
                        else if timezone == timezone."CT"
                        then 8
                        else if timezone == timezone."MT"
                        then 7
                        else 6) ;

def hour = Floor(((starthour * 60 + 30) + (GetTime() - RegularTradingStart(GetYYYYMMDD())) / 60000) / 60);

def minutes = (GetTime() - RegularTradingStart(GetYYYYMMDD())) / 60000 - ((hour - starthour) * 60 + 30) + 60;

#Lowest Low during RTH
def bn  = BarNumber();
def rth = Between(GetTime(), RegularTradingStart(GetYYYYMMDD()), RegularTradingEnd(GetYYYYMMDD()));

def multilows = if GetDay() == GetLastDay() and rth
                 then if low == low(period = AggregationPeriod.DAY)
                      then multilows[1] + 1
                      else multilows[1]
                 else 0;

def firstlowbn    = if multilows[1] == 0 and multilows == 1
                    then bn
                    else firstlowbn[1];

def lowhr    = if Bn == HighestAll(firstlowbn) then hour else lowhr[1];
def lowmin   = if Bn == HighestAll(firstlowbn) then minutes else lowmin[1];

AddLabel(showlabel_First_LL,
           (lowhr + ":") +
           (if lowmin < 10
            then "0" + lowmin
            else  "" + lowmin), Color.pink);
 
Thank you for explaining. Here is the high/low of day displaying the time that it first occurred if there were multiple times the high/low of the day were reached.

High of Day


Low of Day
Your codes are well written

Do you know how I can get the time of high for a certain period ? For example, time of high after 12:00

Another one I think of is, the time of high before a certain price, such as time of high before 'Low of Day'
 
Your codes are well written

Do you know how I can get the time of high for a certain period ? For example, time of high after 12:00

Another one I think of is, the time of high before a certain price, such as time of high before 'Low of Day'

Here are your two requests in one script

Capture.jpg
Ruby:
#Time Defined
input timezone = {default "ET", "CT", "MT", "PT"};

def starthour  = (if timezone == timezone."ET"
                        then 9
                        else if timezone == timezone."CT"
                        then 8
                        else if timezone == timezone."MT"
                        then 7
                        else 6) ;

def hour = Floor(((starthour * 60 + 30) + (GetTime() - RegularTradingStart(GetYYYYMMDD())) / 60000) / 60);

def minutes = (GetTime() - RegularTradingStart(GetYYYYMMDD())) / 60000 - ((hour - starthour) * 60 + 30) + 60;
def  bn = BarNumber();


#Time of Highest High after Startfrom Time

input startfrom = 1200;
AddVerticalLine(SecondsFromTime(startfrom) == 0, startfrom, Color.BLUE, stroke = Curve.FIRM);

def h           = CompoundValue(1,
                  if SecondsFromTime(startfrom) == 0
                  then high[-1]
                  else if high > h[1]
                  then high
                  else h[1], h[1]);

def hbn         = if high == h  and GetTime() <= RegularTradingEnd(GetYYYYMMDD())
                  then bn
                  else Double.NaN;

def highday     = if bn == HighestAll(hbn) 
                  then high
                  else highday[1];

def hihr        = if  high == highday then hour else hihr[1];
def himin       = if  high == highday then minutes else himin[1];

AddChartBubble( SecondsFromTime(startfrom) >= 0 and  GetTime() <= RegularTradingEnd(GetYYYYMMDD()) and high == highday, high, "HHigh after \n" + AsPrice(startfrom) + " @ " + hihr + ":" + (if himin < 10 then "0" else "") + himin, Color.GREEN);


#Time of Highest High before Low Day

#Low Day Defined
def l           = CompoundValue(1, 
                  if GetTime() crosses above RegularTradingStart(GetYYYYMMDD())
                  then low
                  else if low < l[1]
                  then low
                  else l[1],
                            low);
def lbn         = if GetDay() == GetLastDay()
                  then if low == l
                       then bn
                       else lbn[1]
                  else 0;
def lowday      = if bn == HighestAll(lbn)
                  then low
                  else lowday[1];

def lowhr      = if low == lowday then hour else lowhr[1];
def lowmin     = if low == lowday then minutes else lowmin[1];

AddChartBubble(low == lowday, low, "Low Day @ " + hour + ":" + (if minutes < 10 then "0" else "") + minutes , Color.RED, no);

#Time of Highest High before Low of Day

def hhlday   = if GetDay() == GetLastDay() and bn < HighestAll(lbn)
               then if GetTime() crosses above RegularTradingStart(GetYYYYMMDD())
                    then high
                     else if high > hhlday[1]
                     then high
                     else hhlday[1]
               else hhlday[1];

def hhldaybn = if GetDay() == GetLastDay() and bn < HighestAll(lbn)
               then if high == hhlday       
                    then bn
                    else hhldaybn[1]
               else 0;

def hh       = if bn == HighestAll(hhldaybn)
               then high
               else hh[1];

AddChartBubble(bn <= HighestAll(lbn) and high == hh, high, "HH @ " + hour + ":" + (if minutes < 10 then "0" else "") + minutes + "\nbefore Lowday", Color.GREEN);
 
Hello folks,

I am new to ThinkScript but have good experience in other trading languages like MQL4 so go easy on me here.

Here is what I am trying to do: I am trying to make a script that looks at the last 14 days and gives me the average time of the HoD (if the daily candle closed red) or the LoD (if the daily candle closed green). If this has already been done then immaculate! please link!

If not I have some other simpler questions below.

I am having issues understanding how arrays work.
How can I scan every 1m candle in the previous X days to find the high or low? I will probably use the GetTime() formula on the HoD LoD candle and an IF statement to decide to grab Hod or LoD, so that part isn't an issue. But how do I do this scanning process for 14 different days? Getting the average of those 14 days will be easy, so will displaying the average.

Answers to any of the questions or helpful links on arrays would be incredible.

Thank you :)
Bubba
 
Last edited:
Here are your two requests in one script
SleepyZ, thank you so much for posting this! You are helping me build what I am trying to build. with this. But I am struggiling with altering you code to look back at previous days.

If a day is a red day I want to grab the time of the high of that day. If it is green day I want the time of the low. I want to get the last 14 days worth of times of the highs and lows averaged out and that average time displayed on the chart.

This will essentially give you the average time the stock will reverse and can help with entering / exiting positions. Pretty useful in my opinion.

I have searched the internet far wand wide for this and this is the closest thing I have found to what I am looking for so hopefully you see this!

thank you so much, I know how annoying it is for people asking for code online but here I am.
 
SleepyZ, thank you so much for posting this! You are helping me build what I am trying to build. with this. But I am struggiling with altering you code to look back at previous days.

If a day is a red day I want to grab the time of the high of that day. If it is green day I want the time of the low. I want to get the last 14 days worth of times of the highs and lows averaged out and that average time displayed on the chart.

This will essentially give you the average time the stock will reverse and can help with entering / exiting positions. Pretty useful in my opinion.

I have searched the internet far wand wide for this and this is the closest thing I have found to what I am looking for so hopefully you see this!

thank you so much, I know how annoying it is for people asking for code online but here I am.

This seems to work. It excludes the current day (thisday == 0). Test data can be hidden.

Capture.jpg
Ruby:
input begin = 0930;
input end   = 1600;
input agg   = AggregationPeriod.DAY;

def rthrs   = SecondsFromTime(begin) >= 0 and SecondsTillTime(end) >= 0;
def bn = BarNumber();
def hd = if rthrs and high == high(period = agg) then bn else hd[1];
def ld = if rthrs and low == low(period = agg) then bn else ld[1];
def c  = close(period = agg);
def o  = open(period = agg);

#Defining Each Day
def ymd      = GetYYYYMMDD();
def candles  = !IsNaN(close);
def capture  = candles and ymd != ymd[1];
def dayCount = CompoundValue(1, if capture then dayCount[1] + 1 else dayCount[1], 0);
def thisDay  = (HighestAll(dayCount) - dayCount) ;

#Time Defined
input timezone = {default "ET", "CT", "MT", "PT"};

def starthour  = (if timezone == timezone."ET"
                        then 9
                        else if timezone == timezone."CT"
                        then 8
                        else if timezone == timezone."MT"
                        then 7
                        else 6) ;

def hour = Floor(((starthour * 60 + 30) + (GetTime() - RegularTradingStart(GetYYYYMMDD())) / 60000) / 60);

def minutes = (GetTime() - RegularTradingStart(GetYYYYMMDD())) / 60000 - ((hour - starthour) * 60 + 30) + 60;

#Time of High each Day Averaged over input days when Close >= Open   ====
input days   = 14;

def thisbar  = if bn == hd
               then thisDay else thisbar[1];
def hday     = if thisbar != thisbar[1] and bn == (hd)
               then 1 else 0;

def hhour    = if bn == 1
               then 0
               else if Between(thisDay, 1, days) and hday and c >= o
               then hhour[1] + hour else hhour[1];
def hminutes = if bn == 1
               then 0 else if Between(thisDay, 1, days) and c >= o and hday
               then hminutes[1] + minutes else hminutes[1];
def hcount   = if bn == 1
               then 0
               else if Between(thisDay, 1, days) and c >= o and hday
               then hcount[1] + 1 else hcount[1];


#Time of Low each Day Averaged over input days when Close < Open =======

def thisbar1 = if bn == ld
               then thisDay else thisbar1[1];
def lday     = if thisbar1 != thisbar1[1] and bn == ld
               then 1 else 0;

def lhour    = if bn == 1
               then 0
               else if Between(thisDay, 1, days) and lday and c < o
               then lhour[1] + hour else lhour[1];
def lminutes = if bn == 1
               then 0 else if Between(thisDay, 1, days) and c < o and lday
               then lminutes[1] + minutes else lminutes[1];
def lcount   = if bn == 1
               then 0
               else if Between(thisDay, 1, days) and c < o and lday
               then lcount[1] + 1 else lcount[1];

#Labels ========================================================

addlabel(1, "Average Time High Occurs on Green Candles : " + Floor(hhour / hcount) + ":" + Floor(hminutes / hcount), color.green);
addlabel(1, "Average Time Low Occurs on Red Candles : " + Floor(lhour / lcount) + ":" + Floor(lminutes / lcount), color.red);

#Testing =======================================================
input test   = yes;
AddLabel(test, "Total: Hours: " +Round(hhour, 0) + " || Minutes: " + Round(hminutes, 0) + " || Average Time: " + Floor(hhour / hcount) + ":" + Floor(hminutes / hcount) + " || Days " + days + " || Green " + hcount, Color.green);
AddChartBubble(hday, high, hhour, Color.GRAY);


AddLabel(test, "Total: Hours: " +Round(lhour, 0) + " || Minutes: " + Round(lminutes, 0) + " || Average Time: " + Floor(lhour / lcount) + ":" + Floor(lminutes / lcount) + " || Days " + days + " || Red " + lcount, Color.red);
;
 

Not the exact question you're looking for?

Start a new thread and receive assistance from our community.

87k+ Posts
326 Online
Create Post

The Market Trading Game Changer

Join 2,500+ subscribers inside the useThinkScript VIP Membership Club
  • Exclusive indicators
  • Proven strategies & setups
  • Private Discord community
  • ‘Buy The Dip’ signal alerts
  • Exclusive members-only content
  • Add-ons and resources
  • 1 full year of unlimited support

Frequently Asked Questions

What is useThinkScript?

useThinkScript is the #1 community of stock market investors using indicators and other tools to power their trading strategies. Traders of all skill levels use our forums to learn about scripting and indicators, help each other, and discover new ways to gain an edge in the markets.

How do I get started?

We get it. Our forum can be intimidating, if not overwhelming. With thousands of topics, tens of thousands of posts, our community has created an incredibly deep knowledge base for stock traders. No one can ever exhaust every resource provided on our site.

If you are new, or just looking for guidance, here are some helpful links to get you started.

What are the benefits of VIP Membership?
VIP members get exclusive access to these proven and tested premium indicators: Buy the Dip, Advanced Market Moves 2.0, Take Profit, and Volatility Trading Range. In addition, VIP members get access to over 50 VIP-only custom indicators, add-ons, and strategies, private VIP-only forums, private Discord channel to discuss trades and strategies in real-time, customer support, trade alerts, and much more. Learn all about VIP membership here.
How can I access the premium indicators?
To access the premium indicators, which are plug and play ready, sign up for VIP membership here.
Back
Top