Help with some coding please

[BBDPDC]

Hello folks

Long story short I'm stuck. The way i've cobbled this together has resulted in more signals (up arrows) than i want and i can't work out how to just get the signal to fire when the histogram starts to move back in a positive direction.

How do I amend the Upsignal instruction to only show on the first bar when momentum switches from negative to positive? It continues to fire until momentum turns negative.

I'd very much appreciate some advice from those of you with more experience if you have time please

declare upper;

input fastLength = 6;
input slowLength = 13;
input MACDLength = 5;
input averageType = AverageType.EXPONENTIAL;

def Value = MACD(fastLength, slowLength, MACDLength, averageType).Value;
def Avg = MACD(fastLength, slowLength, MACDLength, averageType).Avg;
def ZeroLine = 0;

def pos         = Value >= 0;
def neg         = Value < 0;
def up         = Value >= Value[1];
def dn         = Value < Value[1];

def PosUp = pos and up;
def PosDn = pos and dn;
def NegDn = neg and dn;
def NegUp = neg and up;

def pos1         = Avg >= 0;
def neg1         = Avg < 0;
def up1        = Avg >= Avg[1];
def dn1         = Avg < Avg[1];

def PosUp1 = pos1 and up1;
def PosDn1 = pos1 and dn1;
def NegDn1 = neg1 and dn1;
def NegUp1 = neg1 and up1;

#cloud
AddCloud(if Value < 0 then Double.POSITIVE_INFINITY else Double.NaN, if Value < 0 then Double.NEGATIVE_INFINITY else Double.NaN, Color.RED);
#AddCloud(if Value >= 0 then Double.POSITIVE_INFINITY else Double.NaN, if Value < 0 then Double.NEGATIVE_INFINITY else Double.NaN, Color.GREEN);

#Labels

#AddLabel (yes, if pos or up then " BULL " else "", Color.GREEN);
#AddLabel (yes, if pos1 or up1 then " BULL " else "", Color.GREEN);

#signals

input Klength = 10;
input price = close;

def K = (Highest(high, Klength) + Lowest(low, Klength)) /
2 + ExpAverage(close, Klength);
def Momo = Inertia(price - K / 2, Klength);

plot Upsignal = if Momo > Momo[1] and up then Momo else double.NaN;
Upsignal.SetDefaultColor(Color.WHITE);
upsignal.SetPaintingStrategy(PaintingStrategy.boolean_points);
upsignal.SetLineWeight(5);

 

[mashume]

Your condition for momentum:

plot Upsignal = if Momo > Momo[1] and up then Momo else double.NaN;

needs to be altered. It's firing on every candle where the condition (momentum is rising) it true, just as you described. You can look for minimums by adding an additional condition:

plot Upsignal = if Momo > Momo[1] and momo[1] < momo[2] and up then Momo else double.NaN;

See how that says 'only when the latest value is higher than the previous AND that previous is lower than the one before it'? We're looking for a low point, so momo[1] has to be the lowest of the three (momo, momo[1], and momo[2])

Perhaps that gets you going in the right direction. Good luck,

happy trading,
mashume

 

[BBDPDC]

Your condition for momentum:

plot Upsignal = if Momo > Momo[1] and up then Momo else double.NaN;

needs to be altered. It's firing on every candle where the condition (momentum is rising) it true, just as you described. You can look for minimums by adding an additional condition:

plot Upsignal = if Momo > Momo[1] and momo[1] < momo[2] and up then Momo else double.NaN;

See how that says 'only when the latest value is higher than the previous AND that previous is lower than the one before it'? We're looking for a low point, so momo[1] has to be the lowest of the three (momo, momo[1], and momo[2])

Perhaps that gets you going in the right direction. Good luck,

happy trading,
mashume

@mashume thank you sir, this is exactly what I needed and I've now learned something new!

I should mention I use this strategy along with your Hull Concavity Turning Points indicator with great success!