Help with If then

[blconnell308]

I need an If then statement to set the BuySignal and SellSignal depending on which way the EMA is moving. I want to Go Long (BuySignal) if EMA is up and use BuySignal to get out of the sell if EMA is going down. Here is the code I'm using. I cannot seem to get it right and looking for some expert advice.

input iEMALength = 9;
input iEMA_SMALength = 9;
input iEMA_LMALength = 5;

# EMA or EMA Crossovers
def EMA = MovAvgExponential(CLOSE, iEMALength, 0);
def EMA_MA1 = MovAvgExponential(EMA, iEMA_SMALength, 0);
def EMA_MA2 = MovAvgExponential(EMA_MA1, iEMA_LMALength, 0);

# PLOT EMA ON CHART
plot pEMA = EMA;
pEMA.SetDefaultColor(Color.Gray);
plot pEMA_MA1 = EMA_MA1;
pEMA_MA1.SetDefaultColor(Color.Green);
plot pEMA_MA2 = EMA_MA2;
peMA_MA2.SetDefaultColor(Color.Yellow);

# EMA Logic
def LbEMA = EMA_MA1 crosses above EMA_MA2;
def LsEMA = EMA_MA1 crosses below EMA_MA2;
def LongEMA = EMA_MA1 > EMA_MA2;
def ShortEMA = EMA_MA1 < EMA_MA2;

# Heiken Ashi Logic
def xClose = ( open + high + low + close ) / 4;
rec xOpen = CompoundValue( 1, ( xOpen[1] + xClose[1] ) / 2, xClose );
def Bullish = if ( xClose - xOpen ) >= 0 then yes else no;
def Bearish = if ( xClose - xOpen ) <= 0 then yes else no;
def BullishChange = if ( xClose - xOpen ) >= 0 and ( xClose[1] - xOpen[1] ) <= 0 then yes else no;
def BearishChange = if ( xClose - xOpen ) <= 0 and ( xClose[1] - xOpen[1] ) >= 0 then yes else no;

#--- DISPLAY INFORMATION ---
#Long
#def BuySignal = (LongEMA and BullishChange) or (LBEma and Bullish);
#def SellSignal = (LongEMA and BearishChange) or (LSEma);

#Short
def SellSignal = (ShortEMA and BearishChange) or (LSEma and Bearish);
def BuySignal = (ShortEMA and BullishChange) or (LBEma);

 

[halcyonguy]

I need an If then statement to set the BuySignal and SellSignal depending on which way the EMA is moving. I want to Go Long (BuySignal) if EMA is up and use BuySignal to get out of the sell if EMA is going down. Here is the code I'm using. I cannot seem to get it right and looking for some expert advice.

input iEMALength = 9;
input iEMA_SMALength = 9;
input iEMA_LMALength = 5;

# EMA or EMA Crossovers
def EMA = MovAvgExponential(CLOSE, iEMALength, 0);
def EMA_MA1 = MovAvgExponential(EMA, iEMA_SMALength, 0);
def EMA_MA2 = MovAvgExponential(EMA_MA1, iEMA_LMALength, 0);

# PLOT EMA ON CHART
plot pEMA = EMA;
pEMA.SetDefaultColor(Color.Gray);
plot pEMA_MA1 = EMA_MA1;
pEMA_MA1.SetDefaultColor(Color.Green);
plot pEMA_MA2 = EMA_MA2;
peMA_MA2.SetDefaultColor(Color.Yellow);

# EMA Logic
def LbEMA = EMA_MA1 crosses above EMA_MA2;
def LsEMA = EMA_MA1 crosses below EMA_MA2;
def LongEMA = EMA_MA1 > EMA_MA2;
def ShortEMA = EMA_MA1 < EMA_MA2;

# Heiken Ashi Logic
def xClose = ( open + high + low + close ) / 4;
rec xOpen = CompoundValue( 1, ( xOpen[1] + xClose[1] ) / 2, xClose );
def Bullish = if ( xClose - xOpen ) >= 0 then yes else no;
def Bearish = if ( xClose - xOpen ) <= 0 then yes else no;
def BullishChange = if ( xClose - xOpen ) >= 0 and ( xClose[1] - xOpen[1] ) <= 0 then yes else no;
def BearishChange = if ( xClose - xOpen ) <= 0 and ( xClose[1] - xOpen[1] ) >= 0 then yes else no;

#--- DISPLAY INFORMATION ---
#Long
#def BuySignal = (LongEMA and BullishChange) or (LBEma and Bullish);
#def SellSignal = (LongEMA and BearishChange) or (LSEma);

#Short
def SellSignal = (ShortEMA and BearishChange) or (LSEma and Bearish);
def BuySignal = (ShortEMA and BullishChange) or (LBEma);

this is a strategy , not a study

here is something to experiment with
i added addorder functtions

added bubbles to display values to help debug

#if_then_help_buy_strat

#https://usethinkscript.com/threads/help-with-if-then.20280/
#Help with If then
#blconnell308  Jan 18, 2025

#I need an If then statement to set the BuySignal and SellSignal depending on which way the EMA is moving. I want to Go Long (BuySignal) if EMA is up and use BuySignal to get out of the sell if EMA is going down. Here is the code I'm using. I cannot seem to get it right and looking for some expert advice.

input iEMALength = 9;
input iEMA_SMALength = 9;
input iEMA_LMALength = 5;

# EMA or EMA Crossovers
def EMA = MovAvgExponential(close, iEMALength, 0);
def EMA_MA1 = MovAvgExponential(EMA, iEMA_SMALength, 0);
def EMA_MA2 = MovAvgExponential(EMA_MA1, iEMA_LMALength, 0);

# PLOT EMA ON CHART
plot pEMA = EMA;
pEMA.SetDefaultColor(Color.GRAY);
plot pEMA_MA1 = EMA_MA1;
pEMA_MA1.SetDefaultColor(Color.GREEN);
plot pEMA_MA2 = EMA_MA2;
pEMA_MA2.SetDefaultColor(Color.YELLOW);

# EMA Logic
def LbEMA = EMA_MA1 crosses above EMA_MA2;
def LsEMA = EMA_MA1 crosses below EMA_MA2;
def LongEMA = EMA_MA1 > EMA_MA2;
def ShortEMA = EMA_MA1 < EMA_MA2;

# Heiken Ashi Logic
def xClose = ( open + high + low + close ) / 4;
rec xOpen = CompoundValue( 1, ( xOpen[1] + xClose[1] ) / 2, xClose );
def Bullish = if ( xClose - xOpen ) >= 0 then yes else no;
def Bearish = if ( xClose - xOpen ) <= 0 then yes else no;
def BullishChange = if ( xClose - xOpen ) >= 0 and ( xClose[1] - xOpen[1] ) <= 0 then yes else no;
def BearishChange = if ( xClose - xOpen ) <= 0 and ( xClose[1] - xOpen[1] ) >= 0 then yes else no;

#--- DISPLAY INFORMATION ---
#Long
def long_Buy = (LongEMA and BullishChange) or (LbEMA and Bullish);
def long_Sell = (LongEMA and BearishChange) or (LsEMA);

#Short
def short_Buy = (ShortEMA and BullishChange) or (LbEMA);
def short_Sell = (ShortEMA and BearishChange) or (LsEMA and Bearish);


input long_enable = no;
input short_enable = yes;
#AddOrder ( type , condition , price , tradeSize , tickColor , arrowColor , name );  

input trade_size = 1;
AddOrder(OrderType.BUY_TO_OPEN, long_enable and long_Buy, open[-1], tradeSize = trade_size, tickcolor = Color.GREEN, arrowcolor = Color.GREEN, name = "long buy");
AddOrder(OrderType.SELL_TO_CLOSE, long_enable and long_sell, open[-1], tradeSize = trade_size, tickcolor = Color.cyan, arrowcolor = Color.cyan, name = "long sell");


AddOrder(OrderType.sell_TO_OPEN, short_enable and short_Buy, open[-1], tradeSize = trade_size, tickcolor = Color.red, arrowcolor = Color.red, name = "short buy");
AddOrder(OrderType.buy_TO_CLOSE, short_enable and short_sell, open[-1], tradeSize = trade_size, tickcolor = Color.yellow, arrowcolor = Color.yellow, name = "short sell");


def y = 0.003;
input test_long = no;
#def long_Buy = (LongEMA and BullishChange) or (LBEma and Bullish);
AddChartBubble(test_long, low * (1-y),
 "long\n" +
 "buy\n" +
 (LongEMA and BullishChange) + "\n" +
 (LbEMA and Bullish) + "\n" +
 long_Buy + "\n" 
, (if long_Buy then Color.GREEN else Color.GRAY), no);


#def long_Sell = (LongEMA and BearishChange) or (LSEma);
AddChartBubble(test_long, low * (1-y),
 "long\n" +
 "sell\n" +
 (LongEMA and BearishChange) + "\n" +
 LsEMA + "\n" +
 long_Sell + "\n" 
, (if long_Sell then Color.CYAN else Color.GRAY), no);


input test_short = no;
#def short_Buy = (ShortEMA and BullishChange) or (LbEMA);
AddChartBubble(test_short, high * (1+y),
 "short\n" +
 "buy\n" +
 (ShortEMA and BullishChange) + "\n" +
 (LbEMA) + "\n" +
 short_Buy
, (if short_Buy then Color.red else Color.GRAY), yes);

#def short_Sell = (ShortEMA and BearishChange) or (LsEMA and Bearish);
AddChartBubble(test_short, high * (1+y),
 "short\n" +
 "sell\n" +
 (ShortEMA and BearishChange) + "\n" +
 (LsEMA and Bearish) + "\n" +
 short_Sell
, (if short_Sell then Color.yellow else Color.GRAY), yes);
#