Help with AssignBackgroundColor for triple screening indicator

[jimw]

I have written an indicator that I want to be a triple screen that will change the background color to green when true. The screen is as follows:
1. The close is above the EMA 10 and the EMA 10 is above the EMA 65.
2. The Slow Stochastics is greater than 20.
3. The MACD is displaying a buy signal.

Here is the code:
# TripleScreen
# 1. EMA screen
def EMA10 = ExpAverage(close[-0], 10);
def EMA65 = ExpAverage(close[-0], 65);

def A = if close > EMA10 and EMA10 > EMA65 then 1 else 0;

# **************************************************
# 2. Slow Stochastics screen
def SStoch51 = reference StochasticFull(80, 20, 5, 1, high, low, close, 3, AverageType.SIMPLE).FullK;

def B = if SStoch51 > 20 then 1 else 0;


# **************************************************
# 3. MACD screen
#
# NOTE: (Value cross above Avg) > ZeroLine = BUY SIGNAL
# Value Above ZeroLine Bullish and below Bearish
# Value Cyan
# Avg white
# Diff Histogram
# https://tlc.thinkorswim.com/center/reference/Tech-Indicators/studies-library/M-N/MACD

declare lower;

input fastLength = 12;
input slowLength = 26;
input MACDLength = 9;
input averageType = AverageType.EXPONENTIAL;
input showBreakoutSignals = no;

plot Value = MovingAverage(averageType, close, fastLength) - MovingAverage(averageType, close, slowLength);
plot Avg = MovingAverage(averageType, Value, MACDLength);

plot Diff = Value - Avg;
plot ZeroLine = 0;

#plot UpSignal = if Diff crosses above ZeroLine then ZeroLine else Double.NaN;
#plot DownSignal = if Diff crosses below ZeroLine then ZeroLine else Double.NaN;

plot UpSignal = if Value > ZeroLine and Diff > ZeroLine then ZeroLine else Double.NaN;
plot DownSignal = if Value < ZeroLine and Diff < ZeroLine then ZeroLine else Double.NaN;

UpSignal.SetHiding(!showBreakoutSignals);
DownSignal.SetHiding(!showBreakoutSignals);

Value.SetDefaultColor(GetColor(1));
Avg.SetDefaultColor(GetColor(8));
Diff.SetDefaultColor(GetColor(5));
Diff.SetPaintingStrategy(PaintingStrategy.HISTOGRAM);
Diff.SetLineWeight(3);
Diff.DefineColor("Positive and Up", Color.GREEN);
Diff.DefineColor("Positive and Down", Color.DARK_GREEN);
Diff.DefineColor("Negative and Down", Color.RED);
Diff.DefineColor("Negative and Up", Color.DARK_RED);
Diff.AssignValueColor(if Diff >= 0 then if Diff > Diff[1] then Diff.Color("Positive and Up") else Diff.Color("Positive and Down") else if Diff < Diff[1] then Diff.Color("Negative and Down") else Diff.Color("Negative and Up"));
ZeroLine.SetDefaultColor(GetColor(5));
UpSignal.SetDefaultColor(Color.WHITE);
UpSignal.SetLineWeight(5);
UpSignal.SetPaintingStrategy(PaintingStrategy.ARROW_UP);
DownSignal.SetDefaultColor(Color.DOWNTICK);
DownSignal.SetPaintingStrategy(PaintingStrategy.ARROW_DOWN);
DownSignal.SetLineWeight(5);

#AddLabel(yes, if close > open then if close > Average(close, 20) then "Uptrend Green" else "Downtrend Green" else if close > Average(close, 20) then "Uptrend RED" else "Downtrend RED");

AddLabel(yes, if Value > ZeroLine then "OK BULLISH" else "BEARISH", if Value > ZeroLine then Color.LIGHT_GREEN else Color.PINK);

#AddLabel(yes, if Value > Avg then "" else "CAUTIOUS Raise STOP", if value > Avg then Color.GRAY else Color.YELLOW);

AddLabel(yes, "Watch White Arrows", Color.WHITE);


def C = if UpSignal then 1 else 0;


# **************************************************
# 4. BGColor change if all the above are true

DefineGlobalColor("TRUE",Color.GREEN);
DefineGlobalColor("FALSE",Color.RED);
DefineGlobalColor("default",Color.CURRENT);

#AssignBackgroundColor(if A = 1 && B = 1 && C = 1 then GlobalColor("TRUE") else if A = 0 && B = 0 && C = 0 then GlobalColor("FALSE") else GlobalColor("default");

# **************************************************
# End code------------------------------------------

I am having problems with #4. above Assigning Background Color. As an example here is a chart that should have the Background Color changed to Green. Any help with the code is appreciated.

 

[halcyonguy]

I have written an indicator that I want to be a triple screen that will change the background color to green when true. The screen is as follows:
1. The close is above the EMA 10 and the EMA 10 is above the EMA 65.
2. The Slow Stochastics is greater than 20.
3. The MACD is displaying a buy signal.

Here is the code:
# TripleScreen
# 1. EMA screen
def EMA10 = ExpAverage(close[-0], 10);
def EMA65 = ExpAverage(close[-0], 65);

def A = if close > EMA10 and EMA10 > EMA65 then 1 else 0;

# **************************************************
# 2. Slow Stochastics screen
def SStoch51 = reference StochasticFull(80, 20, 5, 1, high, low, close, 3, AverageType.SIMPLE).FullK;

def B = if SStoch51 > 20 then 1 else 0;


# **************************************************
# 3. MACD screen
#
# NOTE: (Value cross above Avg) > ZeroLine = BUY SIGNAL
# Value Above ZeroLine Bullish and below Bearish
# Value Cyan
# Avg white
# Diff Histogram
# https://tlc.thinkorswim.com/center/reference/Tech-Indicators/studies-library/M-N/MACD

declare lower;

input fastLength = 12;
input slowLength = 26;
input MACDLength = 9;
input averageType = AverageType.EXPONENTIAL;
input showBreakoutSignals = no;

plot Value = MovingAverage(averageType, close, fastLength) - MovingAverage(averageType, close, slowLength);
plot Avg = MovingAverage(averageType, Value, MACDLength);

plot Diff = Value - Avg;
plot ZeroLine = 0;

#plot UpSignal = if Diff crosses above ZeroLine then ZeroLine else Double.NaN;
#plot DownSignal = if Diff crosses below ZeroLine then ZeroLine else Double.NaN;

plot UpSignal = if Value > ZeroLine and Diff > ZeroLine then ZeroLine else Double.NaN;
plot DownSignal = if Value < ZeroLine and Diff < ZeroLine then ZeroLine else Double.NaN;

UpSignal.SetHiding(!showBreakoutSignals);
DownSignal.SetHiding(!showBreakoutSignals);

Value.SetDefaultColor(GetColor(1));
Avg.SetDefaultColor(GetColor(8));
Diff.SetDefaultColor(GetColor(5));
Diff.SetPaintingStrategy(PaintingStrategy.HISTOGRAM);
Diff.SetLineWeight(3);
Diff.DefineColor("Positive and Up", Color.GREEN);
Diff.DefineColor("Positive and Down", Color.DARK_GREEN);
Diff.DefineColor("Negative and Down", Color.RED);
Diff.DefineColor("Negative and Up", Color.DARK_RED);
Diff.AssignValueColor(if Diff >= 0 then if Diff > Diff[1] then Diff.Color("Positive and Up") else Diff.Color("Positive and Down") else if Diff < Diff[1] then Diff.Color("Negative and Down") else Diff.Color("Negative and Up"));
ZeroLine.SetDefaultColor(GetColor(5));
UpSignal.SetDefaultColor(Color.WHITE);
UpSignal.SetLineWeight(5);
UpSignal.SetPaintingStrategy(PaintingStrategy.ARROW_UP);
DownSignal.SetDefaultColor(Color.DOWNTICK);
DownSignal.SetPaintingStrategy(PaintingStrategy.ARROW_DOWN);
DownSignal.SetLineWeight(5);

#AddLabel(yes, if close > open then if close > Average(close, 20) then "Uptrend Green" else "Downtrend Green" else if close > Average(close, 20) then "Uptrend RED" else "Downtrend RED");

AddLabel(yes, if Value > ZeroLine then "OK BULLISH" else "BEARISH", if Value > ZeroLine then Color.LIGHT_GREEN else Color.PINK);

#AddLabel(yes, if Value > Avg then "" else "CAUTIOUS Raise STOP", if value > Avg then Color.GRAY else Color.YELLOW);

AddLabel(yes, "Watch White Arrows", Color.WHITE);


def C = if UpSignal then 1 else 0;


# **************************************************
# 4. BGColor change if all the above are true

DefineGlobalColor("TRUE",Color.GREEN);
DefineGlobalColor("FALSE",Color.RED);
DefineGlobalColor("default",Color.CURRENT);

#AssignBackgroundColor(if A = 1 && B = 1 && C = 1 then GlobalColor("TRUE") else if A = 0 && B = 0 && C = 0 then GlobalColor("FALSE") else GlobalColor("default");

# **************************************************
# End code------------------------------------------

I am having problems with #4. above Assigning Background Color. As an example here is a chart that should have the Background Color changed to Green. Any help with the code is appreciated.

don't know what you mean by, wanting a triple screen?

you say Slow Stochastics , but are using Stochasticsfull

what does this mean? what is a buy signal? #3. The MACD is displaying a buy signal.

macd , upsignal, why did you replace crosses with > ? instead of just one signal at the beginning, you will have many signals.

--------------------

i fixed your AssignBackgroundColor() formula,
. need to use double == in formulas,
. if A == 1 then ....

i haven't seen any back color changed, so i added labels to display A, B, C.

looking at the code, C is either 0 or N/A
so the logic is bad. you should rewrite the code that determines C.

plot ZeroLine = 0;
plot UpSignal = if Value > ZeroLine and Diff > ZeroLine then ZeroLine else Double.NaN;
def C = if UpSignal then 1 else 0;

i changed the formulas for upSignal and downSignal.
i used def, and set them to 1 or 0. i try not to use double.nan in logic formulas, just plots.
then in the plots i used double.nan

i think this works... didn't test it much as TOS stalled out on me just after i saved it ( picking a different symbol just showed a blank chart and a spinning icon. )

---------------------
update , i logged back in and checked this. updated C formula. no more errors.
it does change the background color.

#backcolor2

#https://usethinkscript.com/threads/help-with-assignbackgroundcolor-for-triple-screening-indicator.18330/
#Help with AssignBackgroundColor for triple screening indicator
#jimw  Mar 30, 2024

#i have written an indicator that I want to be a triple screen that will change the background color to green when true. The screen is as follows:
#1. The close is above the EMA 10 and the EMA 10 is above the EMA 65.
#2. The Slow Stochastics is greater than 20.
#3. The MACD is displaying a buy signal.



# TripleScreen
# 1. EMA screen
def EMA10 = ExpAverage(close, 10);
def EMA65 = ExpAverage(close, 65);

def A = if close > EMA10 and EMA10 > EMA65 then 1 else 0;

# **************************************************
# 2. Slow Stochastics screen
def SStoch51 = reference StochasticFull(80, 20, 5, 1, high, low, close, 3, AverageType.SIMPLE).FullK;

def B = if SStoch51 > 20 then 1 else 0;


# **************************************************
# 3. MACD screen
#
# NOTE: (Value cross above Avg) > ZeroLine = BUY SIGNAL
# Value Above ZeroLine Bullish and below Bearish
# Value Cyan
# Avg white
# Diff Histogram
# https://tlc.thinkorswim.com/center/reference/Tech-Indicators/studies-library/M-N/MACD

declare lower;

input fastLength = 12;
input slowLength = 26;
input MACDLength = 9;
input averageType = AverageType.EXPONENTIAL;
input showBreakoutSignals = yes;

plot Value = MovingAverage(averageType, close, fastLength) - MovingAverage(averageType, close, slowLength);
plot Avg = MovingAverage(averageType, Value, MACDLength);

plot Diff = Value - Avg;
plot ZeroLine = 0;

#plot UpSignal = if Diff crosses above ZeroLine then ZeroLine else Double.NaN;
#plot DownSignal = if Diff crosses below ZeroLine then ZeroLine else Double.NaN;

def UpSignal2 = if Value > ZeroLine and Diff > ZeroLine then 1 else 0;
def downSignal2 = if Value < ZeroLine and Diff < ZeroLine then 1 else 0;


plot UpSignal = if upsignal2 then zeroline else Double.NaN;
plot DownSignal = if downsignal2 then ZeroLine else Double.NaN;

UpSignal.SetHiding(!showBreakoutSignals);
DownSignal.SetHiding(!showBreakoutSignals);

Value.SetDefaultColor(GetColor(1));
Avg.SetDefaultColor(GetColor(8));
Diff.SetDefaultColor(GetColor(5));
Diff.SetPaintingStrategy(PaintingStrategy.HISTOGRAM);
Diff.SetLineWeight(3);
Diff.DefineColor("Positive and Up", Color.GREEN);
Diff.DefineColor("Positive and Down", Color.DARK_GREEN);
Diff.DefineColor("Negative and Down", Color.RED);
Diff.DefineColor("Negative and Up", Color.DARK_RED);
Diff.AssignValueColor(if Diff >= 0 then if Diff > Diff[1] then Diff.Color("Positive and Up") else Diff.Color("Positive and Down") else if Diff < Diff[1] then Diff.Color("Negative and Down") else Diff.Color("Negative and Up"));
ZeroLine.SetDefaultColor(GetColor(5));
UpSignal.SetDefaultColor(Color.WHITE);
UpSignal.SetLineWeight(5);
UpSignal.SetPaintingStrategy(PaintingStrategy.ARROW_UP);
DownSignal.SetDefaultColor(Color.DOWNTICK);
DownSignal.SetPaintingStrategy(PaintingStrategy.ARROW_DOWN);
DownSignal.SetLineWeight(5);

#AddLabel(yes, if close > open then if close > Average(close, 20) then "Uptrend Green" else "Downtrend Green" else if close > Average(close, 20) then "Uptrend RED" else "Downtrend RED");

AddLabel(yes, if Value > ZeroLine then "OK BULLISH" else "BEARISH", if Value > ZeroLine then Color.LIGHT_GREEN else Color.PINK);

#AddLabel(yes, if Value > Avg then "" else "CAUTIOUS Raise STOP", if value > Avg then Color.GRAY else Color.YELLOW);

AddLabel(yes, "Watch White Arrows", Color.WHITE);

#def C = if UpSignal then 1 else 0;
def C = if UpSignal2 then 1 else 0;


# **************************************************
# 4. BGColor change if all the above are true

DefineGlobalColor("TRUE",Color.GREEN);
DefineGlobalColor("FALSE",Color.RED);
DefineGlobalColor("default",Color.CURRENT);

AssignBackgroundColor(
 if A == 1 and B == 1 and C == 1 then GlobalColor("TRUE")
 else if A == 0 and B == 0 and C == 0 then GlobalColor("FALSE")
 else GlobalColor("default"));


addlabel(1, " ", color.black);
addlabel(1, "A " + a, (if isnan(a) then color.yellow else if a then color.green else color.red));
addlabel(1, "B " + b, (if isnan(b) then color.yellow else if b then color.green else color.red));
addlabel(1, "C " + c, (if isnan(c) then color.yellow else if c then color.green else color.red));
addlabel(1, " ", color.black);


#addlabel(1, Value, color.yellow);
#addlabel(1, Diff, color.yellow);

addchartbubble(0, 0,
Value + "\n" +
Diff + "\n" +
UpSignal2
, color.yellow, no);

# **************************************************
# End code------------------------------------------
#