Help modify the default Volume Flow Indicator

[stormy77]

Below is the default code for the VolumeFlowIndicator

declare lower;

input length = 130;
input maxVolumeCutOff = 2.5;

assert(maxVolumeCutOff > 0, "'max volume cut off' must be positive: " + maxVolumeCutOff);

def cutOff = 0.2 * stdev(log(hlc3) - log(hlc3[1]), 30) * close;
def hlcChange = hlc3 - hlc3[1];
def avgVolume = Average(volume, length)[1];
def minVolume = Min(volume, avgVolume * maxVolumeCutOff);
def dirVolume = if hlcChange > cutOff
    then minVolume
    else if hlcChange < -cutOff
        then -minVolume
        else 0;

plot VFI = ExpAverage(sum(dirVolume, length) / avgVolume, 3);
plot ZeroLine = 0;

VFI.setDefaultColor(getColor(8));
ZeroLine.setDefaultColor(getColor(8));

I draw this as bars going above and below the zero line. (see screenshot)
I would like some help changing it so the bars below zero show a different color (configured in the settings section)

Thank you

 

[Goingdark365]

try this change color in the globales

declare lower;

input length = 130;
input maxVolumeCutOff = 2.5;

assert(maxVolumeCutOff > 0, "'max volume cut off' must be positive: " + maxVolumeCutOff);

def cutOff = 0.2 * stdev(log(hlc3) - log(hlc3[1]), 30) * close;
def hlcChange = hlc3 - hlc3[1];
def avgVolume = Average(volume, length)[1];
def minVolume = Min(volume, avgVolume * maxVolumeCutOff);
def dirVolume = if hlcChange > cutOff
then minVolume
else if hlcChange < -cutOff
then -minVolume
else 0;

plot VFI = ExpAverage(sum(dirVolume, length) / avgVolume, 3);
plot ZeroLine = 0;

#VFI.setDefaultColor(getColor(8));
ZeroLine.setDefaultColor(getColor(8));
DefineGlobalColor("above", (color.green));
DefineGlobalColor("below", (color.red));


VFI.SetPaintingStrategy(PaintingStrategy.Histogram);

VFI.AssignValueColor(if VFI > ZeroLine then (GlobalColor("above")) else (GlobalColor("below")));

 

[stormy77]

Thanks so much @Goingdark365. works great.