Fold Function Counter

[StoneMan]

I am trying to plot the Z score of the true range as a percentile. In order to do that, at each bar I need to fold through my sample period and count how many Z-Score values are lower than my current bars Z score value. If all Z-Score values in the sample period are lower the output will be 1.0. My issue is with getting the counting logic utilizing the fold function right. I can't quite seem to get it.

input Length = 10;

#Calculating volitility Z-Score, true range used as volitility metric
def TrueRange = TrueRange(high, close, low); #Observed value
def TR_Average = Average(TrueRange, Length); #Mean of sample
def TR_StDev = StDev(TrueRange, Length);     #Standard Deviation of sample

def TR_Z_Score = (TrueRange - TR_Average) / TR_StDev;

def TR_Z_Percent_Count =
           fold i = 0
           to Length
           with S = 0
           do if (TR_Z_Score > getValue(TR_Z_Score, i, Length))
           then TR_Z_Percent_Count[1] + 1
           else TR_Z_Percent_Count[1];

def TR_Percentile = TR_Z_Percent_Count / Length;

plot Data = TR_Percentile;

 

[halcyonguy]

I am trying to plot the Z score of the true range as a percentile. In order to do that, at each bar I need to fold through my sample period and count how many Z-Score values are lower than my current bars Z score value. If all Z-Score values in the sample period are lower the output will be 1.0. My issue is with getting the counting logic utilizing the fold function right. I can't quite seem to get it.

input Length = 10;

#Calculating volitility Z-Score, true range used as volitility metric
def TrueRange = TrueRange(high, close, low); #Observed value
def TR_Average = Average(TrueRange, Length); #Mean of sample
def TR_StDev = StDev(TrueRange, Length);     #Standard Deviation of sample

def TR_Z_Score = (TrueRange - TR_Average) / TR_StDev;

def TR_Z_Percent_Count =
           fold i = 0
           to Length
           with S = 0
           do if (TR_Z_Score > getValue(TR_Z_Score, i, Length))
           then TR_Z_Percent_Count[1] + 1
           else TR_Z_Percent_Count[1];

def TR_Percentile = TR_Z_Percent_Count / Length;

plot Data = TR_Percentile;

see if this is what you are looking for.
within a fold loop, you reference the temp variable, s, not the primary output variable.
s holds values during all the iterations. the primary variable gets a value when it is done looping.

i made this a lower study

# zscore_fold_counter

#https://usethinkscript.com/threads/fold-function-counter.15604/
#Fold Function Counter
#StoneMan  5/26

declare lower;

input Length = 10;

#Calculating volitility Z-Score, true range used as volitility metric
def TrueRange = TrueRange(high, close, low); #Observed value
def TR_Average = Average(TrueRange, Length); #Mean of sample
def TR_StDev = StDev(TrueRange, Length);     #Standard Deviation of sample

def TR_Z_Score = (TrueRange - TR_Average) / TR_StDev;

#def TR_Z_Percent_Count =
#           fold i = 0
#           to Length
#           with S = 0
#           do if (TR_Z_Score > getValue(TR_Z_Score, i, Length))
#           then TR_Z_Percent_Count[1] + 1
#           else TR_Z_Percent_Count[1];

def TR_Z_Percent_Count =
    fold i = 0
    to Length
    with S = 0
    do s + if (TR_Z_Score > getValue(TR_Z_Score, i, Length)) then 1 else 0;

def TR_Percentile = TR_Z_Percent_Count / Length;

plot Data = TR_Percentile;
#

 

[StoneMan]

That's what I was looking for. This question is answered. Thanks a bunch @halcyonguy!

 

[StoneMan]

I found and fixed an important bug: in the previous code a sample period (Length) of 3 you get discreet "percentile" levels of 0, .33, and .66. We want this to oscillate from 0 to 1. To get that behavior we have to divide the count by Lenght - 1. The following code includes that change.

#zscore_fold_counter
#Gets z score percentile of true range
#https://usethinkscript.com/threads/fold-function-counter.15604/
#Fold Function Counter
#StoneMan  5/26/2023
#Bug fix 5/28/2023: Now divide count by Lenght-1 to get proper oscillating behavior

declare lower;

input Length = 10;

#Calculating volitility Z-Score, true range used as volitility metric
def TrueRange = TrueRange(high, close, low); #Observed value
def TR_Average = Average(TrueRange, Length); #Mean of sample
def TR_StDev = StDev(TrueRange, Length);     #Standard Deviation of sample

def TR_Z_Score = (TrueRange - TR_Average) / TR_StDev;

def TR_Z_Percent_Count =
    fold i = 0
    to Length
    with S = 0
    do s + if (TR_Z_Score > getValue(TR_Z_Score, i, Length)) then 1 else 0;

def TR_Percentile = TR_Z_Percent_Count / (Length - 1);

plot TRpercent = TR_Percentile;