find the lowest low after highest bar in first hour of trading

[hellomvrk]

Even though I went through lots of code, I could not find a code to which finds the lowest low in 2nd hour of trading after the highest bar in the first hour of trading

 

[SleepyZ]

Even though I went through lots of code, I could not find a code to which finds the lowest low in 2nd hour of trading after the highest bar in the first hour of trading

Here is a mod of a script that I previously did to limit the High to the 1st Hour and the Low to the 2nd Hour.

input endof1stHour = 1030;
input endof2ndHour = 1130;

#Highest High during 1st Jpir
def h        =
               if GetTime() crosses above RegularTradingStart(GetYYYYMMDD())
               then high
               else if SecondsFromTime(endof1stHour) < 0
               then Max(high, h[1])
               else h[1];

def hbn      = if GetDay() == GetLastDay() and SecondsFromTime(endof1stHour) < 0
               then if high == h
                    then BarNumber()
                    else hbn[1]
               else 0;

def hday     = if BarNumber() == HighestAll(hbn)
               then high
               else hday[1];

plot highday = hday;
highday.SetPaintingStrategy(PaintingStrategy.HORIZONTAL);

#Lowest Low in 2nd Hour after High of 1st Hour
def l       = if BarNumber() == HighestAll(hbn + 1)
              then low
              else if SecondsFromTime(endof2ndHour) < 0
              then Min(low, l[1])
              else l[1];
def lbn     = if GetDay() == GetLastDay() and SecondsFromTime(endof2ndHour) < 0
              then if low == l
                   then BarNumber()
                   else lbn[1]
              else 0;
def lday    = if BarNumber() == HighestAll(lbn) then l else lday[1];
plot lowday = lday;
lowday.SetPaintingStrategy(PaintingStrategy.HORIZONTAL);

input verticals = yes;
AddVerticalLine(verticals and SecondsFromTime(endof1stHour) == 0, "1st Hour End", Color.WHITE);
AddVerticalLine(verticals and SecondsFromTime(endof2ndHour) == 0, "2nd Hour End", Color.WHITE);

#