Fibonacci retracement on 30 minute bar

[hectorgasm]

Hello, would someone help me plot a fibonacci 50% retracement when the following condition is met?

close < close[20]

 

[SleepyZ]

Hello, would someone help me plot a fibonacci 50% retracement when the following condition is met?

close < close[20]

Not exactly sure what you expected, but maybe this will give you some ideas of one way to view your request. A little more description and a chart image mocked up will likely get more responses..

This excludes the current bar and when the condition is met, it will find the highs and lows to compute the retrace. The plot of these can be hidden.

A vertical line plots at the lookback point and a label will be green if the condition is met and gray otherwise.

input lookback = 20;
input vertical = yes;
input hl_plots = yes;
input label    = yes;

def bn        = BarNumber();
def lastbar   = HighestAll(if !IsNaN(close) then bn else 0);
def c         = if bn == lastbar then close else c[1];
def hh        = if IsNaN(c) then hh[1]
                else if bn == (lastbar - lookback) then high
                else if bn < (lastbar - 1 ) then Max(high, hh[1])
                else hh[1];

def ll        = if IsNaN(close) then ll[1]
                else if bn == (lastbar - lookback) then low
                else if bn < (lastbar - 1 ) then Min(low, ll[1])
                else ll[1];
def retrace50 = (hh + ll) / 2;

plot lookbackhigh = if bn >= lastbar and c < close[lookback] then hh
                    else Double.NaN;
plot lookbacklow  = if bn >= lastbar and c < close[lookback] then ll
                    else Double.NaN;
plot fib50        = if bn >= lastbar and c < close[lookback] then retrace50
                    else Double.NaN;
lookbackhigh.SetPaintingStrategy(PaintingStrategy.HORIZONTAL);
lookbacklow.SetPaintingStrategy(PaintingStrategy.HORIZONTAL);
fib50.SetPaintingStrategy(PaintingStrategy.HORIZONTAL);
lookbackhigh.SetHiding(!hl_plots);
lookbacklow.SetHiding(!hl_plots);

AddLabel(label, " Close: " + c + (if c < close[lookback] then "  <  " else "  >=  ") + "C[" + lookback + "]: " + close[lookback] , if c < close[lookback] then Color.LIGHT_GREEN else Color.GRAY);
;
AddVerticalLine(vertical and bn == (lastbar - lookback), "", Color.WHITE);