Enhanced RevEngRSI indicator (extension and alerts)

Aliikhatami

New member
VIP
Hi. can someone extend this study to the right and also is there a way to set alerts on it as if a candle crosses it?

Code:
#
# TD Ameritrade IP Company, Inc. (c) 2009-2020
#

input length = 14;
input price = close;
input rsiValue = 50;
input onExpansion = Yes;
input smoothingType = {default Wilders, EMA};

def coeff = rsiValue / (100 - rsiValue);
def chg = price - price[1];
def diff;
switch (smoothingType) {
case Wilders:
    diff =  (length - 1) * (WildersAverage(Max(-chg, 0), length) * coeff - WildersAverage(Max(chg, 0), length));
case EMA:
    diff =  (length - 1) * (ExpAverage(Max(-chg, 0), length) * coeff - ExpAverage(Max(chg, 0), length)) / 2;
}

def value = price + if diff >= 0 then diff else diff / coeff;
plot RevEngRSI = compoundValue(1, value[1], Double.NaN);

RevEngRSI.DefineColor("Up", GetColor(1));
RevEngRSI.DefineColor("Down", GetColor(0));
RevEngRSI.AssignValueColor(if RevEngRSI > RevEngRSI[1] then RevEngRSI.color("Up") else RevEngRSI.color("Down"));
 
Last edited by a moderator:
This study shows how you can extend any indicator into the expansion area. It also shows how you can add Alerts to your study. These can be confirmed by also showing chart bubbles, but your charts will be cleaner with them off once you are done with this visual debugging aid.

pprTeux.png



Code

Code:
#
# Enhancements to RevEngRSI study.
#
# Author: Kory Gill, @korygill
#

input length = 14;
input price = close;
input rsiValue = 50;
input onExpansion = Yes;
input smoothingType = {default Wilders, EMA};
input showChartBubbles = yes;
input showAlerts = yes;

def coeff = rsiValue / (100 - rsiValue);
def chg = price - price[1];
def diff;
switch (smoothingType) {
case Wilders:
    diff =  (length - 1) * (WildersAverage(Max(-chg, 0), length) * coeff - WildersAverage(Max(chg, 0), length));
case EMA:
    diff =  (length - 1) * (ExpAverage(Max(-chg, 0), length) * coeff - ExpAverage(Max(chg, 0), length)) / 2;
}

def value = price + if diff >= 0 then diff else diff / coeff;

def nan = double.NaN;
def lastBar = !IsNaN(price) && IsNaN(price[-1]);
def lastClose = if lastBar then value else if onExpansion and IsNaN(price) then lastClose[1] else value;

plot RevEngRSI = compoundValue(1, lastClose, Double.NaN);

RevEngRSI.DefineColor("Up", GetColor(1));
RevEngRSI.DefineColor("Down", GetColor(0));
RevEngRSI.AssignValueColor(if RevEngRSI > RevEngRSI[1] then RevEngRSI.color("Up") else RevEngRSI.color("Down"));

# alerts
def crossAbove = Crosses(price, RevEngRSI, CrossingDirection.ABOVE);
def crossBelow = Crosses(price, RevEngRSI, CrossingDirection.BELOW);

AddChartBubble(showChartBubbles and crossAbove, price, "Cross Above", GetColor(1), yes);
AddChartBubble(showChartBubbles and crossBelow, price, "Cross Below", GetColor(0), no);

Alert(showAlerts and crossAbove, "Cross Above!", Alert.BAR);
Alert(showAlerts and crossBelow, "Cross Below!", Alert.BAR);

Link to the flexible grid and study

https://tos.mx/GOuPgWJ


Happy trading,
Kory Gill, @korygill
 

Join useThinkScript to post your question to a community of 21,000+ developers and traders.

Similar threads

Not the exact question you're looking for?

Start a new thread and receive assistance from our community.

87k+ Posts
315 Online
Create Post

Similar threads

Similar threads

The Market Trading Game Changer

Join 2,500+ subscribers inside the useThinkScript VIP Membership Club
  • Exclusive indicators
  • Proven strategies & setups
  • Private Discord community
  • ‘Buy The Dip’ signal alerts
  • Exclusive members-only content
  • Add-ons and resources
  • 1 full year of unlimited support

Frequently Asked Questions

What is useThinkScript?

useThinkScript is the #1 community of stock market investors using indicators and other tools to power their trading strategies. Traders of all skill levels use our forums to learn about scripting and indicators, help each other, and discover new ways to gain an edge in the markets.

How do I get started?

We get it. Our forum can be intimidating, if not overwhelming. With thousands of topics, tens of thousands of posts, our community has created an incredibly deep knowledge base for stock traders. No one can ever exhaust every resource provided on our site.

If you are new, or just looking for guidance, here are some helpful links to get you started.

What are the benefits of VIP Membership?
VIP members get exclusive access to these proven and tested premium indicators: Buy the Dip, Advanced Market Moves 2.0, Take Profit, and Volatility Trading Range. In addition, VIP members get access to over 50 VIP-only custom indicators, add-ons, and strategies, private VIP-only forums, private Discord channel to discuss trades and strategies in real-time, customer support, trade alerts, and much more. Learn all about VIP membership here.
How can I access the premium indicators?
To access the premium indicators, which are plug and play ready, sign up for VIP membership here.
Back
Top