Draw Vertical Line for Awesome Oscillator

[rajaodu1]

HI @SleepyZ

As you helped to create vertical lines for MACD crossover (link for reference), can you please help me to create vertical lines for Awesome oscillator? Thanks

https://usethinkscript.com/threads/draw-vertical-line-for-macd-crossover.9318/#post-149337

declare lower;
declare zerobase;

plot ZeroLine = 0;
ZeroLine.SetDefaultColor(GetColor(5));

plot AO1 = Average(hl2, 5) - Average(hl2, 34);
AO1.SetPaintingStrategy(PaintingStrategy.LINE);
AO1.SetLineWeight(3);
AO1.AssignValueColor(if AO1 > AO1[1] then Color.GREEN else Color.RED);

 

[rajaodu1]

All four category of vertical lines similar to MACD crossover vertical line

DefineGlobalColor("Above-Above", Color.GREEN);
DefineGlobalColor("Above-Below", Color.LIME);
DefineGlobalColor("Below-Below", Color.RED);
DefineGlobalColor("Below-Above", Color.PINK);

 

[SleepyZ]

All four category of vertical lines similar to MACD crossover vertical line

DefineGlobalColor("Above-Above", Color.GREEN);
DefineGlobalColor("Above-Below", Color.LIME);
DefineGlobalColor("Below-Below", Color.RED);
DefineGlobalColor("Below-Above", Color.PINK);

Here are directional changes, up or dn, depicted by optional labels, bubbles and/or vertical lines.
The bubbles and lines are limited to show by input limit_lines_bubbles

declare lower;
declare zerobase;

input limit_lines_bubbles = 6;

plot ZeroLine = 0;
ZeroLine.SetDefaultColor(GetColor(5));

plot AO1 = Average(hl2, 5) - Average(hl2, 34);
AO1.SetPaintingStrategy(PaintingStrategy.LINE);
AO1.SetLineWeight(3);
AO1.AssignValueColor(if AO1 > AO1[1] then Color.GREEN else Color.RED);

def up = AO1 > AO1[1];
def dn = AO1 < AO1[1];
def count = if BarNumber() == 1 then 0 else if !IsNaN(close) and ((dn[1] and up) or (up[1] and dn)) then count[1] + 1 else count[1];
def cond  = HighestAll(count) - count + 1;

def last_cross = if cond[1] == 2 and cond == 1 and AO1 > AO1[1] then 1 else if cond[1] == 2 and cond == 1 and AO1 < AO1[1] then 0 else last_cross[1];

DefineGlobalColor("Above-Above", Color.GREEN);
DefineGlobalColor("Below-Below", Color.RED);

input label =  yes;
AddLabel(label and last_cross == 1, "Last Direction :  UP "
, GlobalColor("Above-Above"));
AddLabel(label and last_cross == 0, "Last Direction :  DN "
, GlobalColor("Below-Below"));

input bubbles = yes;
input bubbleoffset = 3;
AddChartBubble(bubbles and cond <= limit_lines_bubbles and dn[1] and up, AO1 , "Up" , GlobalColor("Above-Above"), no);
AddChartBubble(bubbles and cond <= limit_lines_bubbles and up[1] and dn, AO1, "Dn" ,  GlobalColor("Below-Below"), yes);

input verticalline = yes;
AddVerticalLine(verticalline and cond <= limit_lines_bubbles and dn[1] and up , "", GlobalColor("Above-Above"), Curve.LONG_DASH);
AddVerticalLine(verticalline and cond <= limit_lines_bubbles and up[1] and dn, "", GlobalColor("Below-Below"), Curve.LONG_DASH);

#

 

[rajaodu1]

HI @SleepyZ

Thanks. Instead of 2 category as Up and down. Can you please add 4 category as shown in the picture.
1. Up and above zero line
2. Down and above zero line
3. Up and below zero line
4. Down and below zero line

Thanks again for your support.

 

[SleepyZ]

HI @SleepyZ

Thanks. Instead of 2 category as Up and down. Can you please add 4 category as shown in the picture.
1. Up and above zero line
2. Down and above zero line
3. Up and below zero line
4. Down and below zero line

Thanks again for your support.

Here you go

declare lower;
declare zerobase;

input limit_lines_bubbles = 6;

plot ZeroLine = 0;
ZeroLine.SetDefaultColor(GetColor(5));

plot AO1 = Average(hl2, 5) - Average(hl2, 34);
AO1.SetPaintingStrategy(PaintingStrategy.LINE);
AO1.SetLineWeight(3);
AO1.AssignValueColor(if AO1 > AO1[1] then Color.GREEN else Color.RED);

def up = AO1 > AO1[1];
def dn = AO1 < AO1[1];
def count = if BarNumber() == 1 then 0 else if !IsNaN(close) and ((dn[1] and up) or (up[1] and dn)) then count[1] + 1 else count[1];
def cond  = HighestAll(count) - count + 1;

def last_cross = if cond[1] == 2 and cond == 1 and AO1 > AO1[1] then 1 else if cond[1] == 2 and cond == 1 and AO1 < AO1[1] then 0 else last_cross[1];

def last_cross_ = if cond[1] == 2 and cond == 1 and AO1 > 0 then 1 else if  cond[1] == 2 and cond == 1  then 0 else last_cross_[1];

DefineGlobalColor("Above-Above", Color.GREEN);
DefineGlobalColor("Above-Below", Color.LIME);
DefineGlobalColor("Below-Below", Color.RED);
DefineGlobalColor("Below-Above", Color.PINK);


input label =  yes;
AddLabel(label and last_cross == 1, "Last Direction :  UP  when " + (if last_cross_ then  " Above 0 line" else " Below 0 line")
, if last_cross_ == 1 then GlobalColor("Above-Above") else GlobalColor("Above-Below"));
AddLabel(label and last_cross == 0, "Last Direction :  DN when " + (if last_cross_ then  " Above 0 line" else " Below 0 line")
, if last_cross_ == 0  then GlobalColor("Below-Below") else GlobalColor("Below-Above"));


input bubbles = yes;
input bubbleoffset = 3;
AddChartBubble(bubbles and cond <= limit_lines_bubbles and dn[1] and up, AO1 , "Up" , if AO1 > 0  then GlobalColor("Above-Above") else GlobalColor("Above-Below"), no);
AddChartBubble(bubbles and cond <= limit_lines_bubbles and up[1] and dn, AO1, "Dn" ,  if AO1 < 0 then GlobalColor("Below-Below") else GlobalColor("Below-Above"), yes);

input verticalline = yes;
AddVerticalLine(verticalline and cond <= limit_lines_bubbles and dn[1] and up , "", if AO1 > 0 then GlobalColor("Above-Above") else GlobalColor("Above-Below"), Curve.LONG_DASH);
AddVerticalLine(verticalline and cond <= limit_lines_bubbles and up[1] and dn, "", if AO1 < 0  then GlobalColor("Below-Below") else GlobalColor("Below-Above"), Curve.LONG_DASH);

#

 

[rajaodu1]

Awesome. Thank you @SleepyZ