Draw Horizontal Line on Specific Candles

[BiggySmall]

Can someone help with code to draw a horizontal line 26 candles back, and have that line extend for say, 5 candles.
So the horizontal line would be on the highest candle of candles 26,25,24,23,22

 

[SleepyZ]

Can someone help with code to draw a horizontal line 26 candles back, and have that line extend for say, 5 candles.
So the horizontal line would be on the highest candle of candles 26,25,24,23,22

This will find the highest high in a range, limited by a lookback and plot limit.

input plotlimit = 5;
input lookback  = 26;

def bn          = BarNumber();
def lastbn      = HighestAll(
                  if !IsNaN(close) and IsNaN(close[-1])
                   then bn
                  else Double.NaN);
def hirange     = if Between(bn, lastbn - lookback, lastbn - lookback + plotlimit)
                   then high
                  else hirange[1];
plot hhigh      = if Between(bn, lastbn - lookback, lastbn - lookback + plotlimit)
                   then HighestAll(hirange)
                  else Double.NaN;
hhigh.SetPaintingStrategy(PaintingStrategy.HORIZONTAL);

 

[BiggySmall]

Worked! Thank you so much!
I tried altering your code to also plot the lowest low but I'm not doing it correctly. I tried reversing "high" with "low" and HighestAll" with LowestAll".
If you have time, may I ask for a little more help here? Thanks.

 

[SleepyZ]

Worked! Thank you so much!
I tried altering your code to also plot the lowest low but I'm not doing it correctly. I tried reversing "high" with "low" and HighestAll" with LowestAll".
If you have time, may I ask for a little more help here? Thanks.

Here is both high/low in one script

#HHLL_in_DefinedRange_Limit_Plot_to_Range
input plotlimit = 5;
input lookback  = 26;

def bn          = BarNumber();
def lastbn      = HighestAll(
                  if !IsNaN(close) and IsNaN(close[-1])
                   then bn
                  else Double.NaN);
def range       = Between(bn, lastbn - lookback, lastbn - lookback + plotlimit);

#Highest High in Range
def hirange     = if range
                   then high
                  else hirange[1];
plot hhigh      = if range
                   then HighestAll(if range
                                    then hirange
                                   else double.nan)
                  else Double.NaN;
hhigh.SetPaintingStrategy(PaintingStrategy.HORIZONTAL);

#Lowest Low in Range
def lorange    = if range
                  then low
                 else lorange[1];
plot llow      = if range
                  then lowestall(if range
                                  then lorange
                                 else double.nan)
                 else double.nan;
llow.SetPaintingStrategy(PaintingStrategy.HORIZONTAL);