Comparison Volatility Chart ?

[MTFY]

Is there a custom script for this?

Instead of a comparison chart that shows price differential between peer stocks, is there a custom script where you load symbols and it will chart the volatility between each equity? For example, chart historical volatility between $RIOT, $COIN, $MARA. I can not find any place where that is available......Thansk

 

[Joshua]

Here is a modified version of the built-in HV study, you can change the plots at the bottom if you want.

declare lower;
input length = 20;
input basis = {default Annual, Monthly, Weekly, Daily};
def ap = getAggregationPeriod();
assert(ap >= AggregationPeriod.MIN, "Study can only be calculated for time-aggregated charts: " + ap);
def barsPerDay = (regularTradingEnd(getYyyyMmDd()) - regularTradingStart(getYyyyMmDd())) / ap;
def barsPerYear =
    if ap > AggregationPeriod.WEEK then 12
    else if ap == AggregationPeriod.WEEK then 52
    else if ap >= AggregationPeriod.DAY then 252 * AggregationPeriod.DAY / ap
    else 252 * barsPerDay;
def basisCoeff;
switch (basis) {
case Annual:
    basisCoeff = 1;
case Monthly:
    basisCoeff = 12;
case Weekly:
    basisCoeff = 52;
case Daily:
    basisCoeff = 252;
}
Script HV {
    Input Sym = "";
    Input Length = 0;
    Input barsPerYear = 0;
    Input basisCoeff = 0;
    def clLog = log(close(Sym) / close(Sym)[1]);
    plot HV = stdev(clLog, length) * Sqrt(barsPerYear / basisCoeff * length / (length - 1));
}

plot X = HV("RIOT",Length,barsPerYear,basisCoeff);
plot Y = HV("COIN",Length,barsPerYear,basisCoeff);
plot Z = HV("MARA",Length,barsPerYear,basisCoeff);