# gaps_narrow_wide_bars_01_upper
#https://usethinkscript.com/threads/chart-labels-wide-narrow-range-bars-gaps-overlapping-bars-counts.12984/
#Chart Labels: Wide/Narrow range bars, Gaps, Overlapping bars, Counts
#TheAlchemist17
#Hello, I am looking for help creating an indicator. I have searched the website threads but have not been able to find anything that accomplishes what I am looking for. Unfortunately, I do not have any coding skills but I have tried to communicate the details as clearly as possible. Hopefully, someone out there can help me to create the code for this. Thank you!
def na = double.nan;
def bn = barnumber();
def rng = high - low;
# definitions
# nr = narrow range , bar has a small price range, from low to high
# nru = narrow range up
# nrd = narrow range down
def v = volume;
input vol_avg_len = 30;
def v_avg = average(v, vol_avg_len);
def up = close > open;
def down = close < open;
#-----------------------------
# ATR
# TD Ameritrade
input length = 10;
input averageType = AverageType.WILDERS;
#plot ATR = MovingAverage(averageType, TrueRange(high, close, low), length);
#ATR.SetDefaultColor(GetColor(8));
def ATR = MovingAverage(averageType, TrueRange(high, close, low), length);
def bar_atr_per = floor(100 * (rng/atr));
#-----------------------------
# bubble vertical offset from bars
def vert = 0.004;
#-----------------------------
# Narrow Range Bar Up/Down (NRU / NRD)
# Current period range < 30% the average true range over the past 10 periods
# Adjustable parameters for % and period count
# Mark the bar as "NR"
#===== add nru , nrd
# When volume is 120% > average volume past 30 periods
# Adjustable parameters for % and average period lookback
# Mark the bar as "NRUV" "NRDV"
# Default = on
input show_narrow_range = yes;
input show_narrow_range_volume_up = yes;
#input narrow_range_max_per = 30;
input narrow_range_max_per = 60;
def nr = (rng < ( narrow_range_max_per/100 * atr));
def nru = (nr and up);
def nrd = (nr and down);
input narrow_vol_level1_per_min = 120;
def isnarrow_vol_level1 = (v > narrow_vol_level1_per_min/100 * v_avg);
def nruv = (nru and isnarrow_vol_level1);
def nrdv = (nrd and isnarrow_vol_level1);
addchartbubble(show_narrow_range and nru, high*(1+vert), "NRU", color.green, yes);
addchartbubble(show_narrow_range and nrd, low*(1-vert), "NRD", color.red, no);
addchartbubble(show_narrow_range_volume_up and nruv, high*(1+vert), "NRUV", color.green, yes);
addchartbubble(show_narrow_range_volume_up and nrdv, low*(1-vert), "NRDV", color.red, no);
#-----------------------------
# Wide Range Bars Up/Down (WRU / WRD)
# Must be at least greater than a recent NR bar
# Must be >60% (make this number an adjustable parameter) the average true range
# Mark the bar as "WRU" and "WRD"
#---- add WR
# When volume is 120% > average volume past 30 periods
# Adjustable parameters for % and average period lookback
# Mark the bar as "WRUV" and "WRDV"
# Default = on
input show_wide_range = yes;
input show_wide_range_volume_up = yes;
#input wide_range_max_per = 60;
input wide_range_max_per = 140;
def wr = (rng > (wide_range_max_per/100 * atr));
def wru = (wr and up);
def wrd = (wr and down);
input wide_vol_level1_per_min = 120;
def iswide_vol_level1 = (v > wide_vol_level1_per_min/100 * v_avg);
def wruv = (wru and iswide_vol_level1);
def wrdv = (wrd and iswide_vol_level1);
addchartbubble(show_wide_range and wru, high*(1+vert), "WRU", color.green, yes);
addchartbubble(show_wide_range and wrd, low*(1-vert), "WRD", color.red, no);
addchartbubble(show_wide_range_volume_up and wruv, high*(1+vert), "WRUV", color.green, yes);
addchartbubble(show_wide_range_volume_up and wrdv, low*(1-vert), "WRDV", color.red, no);
#-----------------------------
# Gap Down (GD)
# High of the period < close of the previous period
# Mark the period as "GD"
# Consecutive Down Gap count: "Consecutive" means that there has not been an Up Gap since the last Down Gap. The count #would start again after it was interrupted by an Up Gap. If there was a Down Gap on bar 1 and then there were no gaps for #several bars and then another down gap occurred, this down gap would count as number 2.
# ?? same thing-- High of the current period < close of the previous period
# ?? same thing-- Mark the bar as "GD?"
# Adjustable parameter to display/not display count
# Default=on
input show_gaps = yes;
# changed , from close to low. gap up uses high and low
def gd = high < low[1];
addchartbubble(show_gaps and gd, low*(1-vert), "GD", color.red, no);
#-----------------------------
# Gap Up (GU)
# Low of the period > High of the previous period
# Mark the period as "GU"
# Consecutive Up Gap count (same concept as Consecutive Down Gap count)
# ?? same thing-- Low of the current period > High of the previous period
# ?? same thing-- Mark the bar as "GU?"
# Adjustable parameter to display/not display count
# Default=on
def gu = low > high[1];
addchartbubble(show_gaps and gu, high*(1+vert), "GU", color.green, yes);
#-----------------------------
def gap = gd or gu;
# gap counts
def gap_dir = if bn == 1 then 0
else if gu then 1
else if gd then -1
else gap_dir[1];
def gap_cnt = if bn == 1 then 0
else if gu and gap_dir[1] > 0 then gap_cnt[1] + 1
else if gu and gap_dir[1] < 0 then 1
else if gd and gap_dir[1] < 0 then gap_cnt[1] + 1
else if gd and gap_dir[1] > 0 then 1
else gap_cnt[1];
#-----------------------------
# Overlapping bars up (LU)
# Open > previous period Close and Open < previous period High
# Mark as "LU"
# Default=on
input show_overlapping_bars = yes;
def lu = open > close[1] and open < high[1];
addchartbubble(show_overlapping_bars and lu, high*(1+vert), "LU", color.green, yes);
#-----------------------------
# Overlapping bars down (LD)
# Open < previous period Close and Open > previous period Low
# Mark as "LD"
# Default=on
def ld = open < close[1] and open > low[1];
addchartbubble(show_overlapping_bars and ld, low*(1-vert), "LD", color.red, no);
#-----------------------------
def l = lu or ld;
#-----------------------------
# Strong Close Up/Down (SCU / SCD)
# Mark the period as "SCU" if the Close is within 25% of the High of the period
# Mark the period as "SCD" if the Close is within 25% of the Low of the period
# Default=on
# 25% ? of the candle height ? , range
input show_strong_close = yes;
input near_close_per = 25;
def rng_near = (rng * near_close_per/100);
def scu = (close > (high - rng_near));
def scd = (close < (low + rng_near));
def sc = scu or scd;
addchartbubble(show_strong_close and scu, high*(1+vert), "SCU", color.green, yes);
addchartbubble(show_strong_close and scd, low*(1-vert), "SCD", color.red, no);
#-----------------------------
#addlabel(1, "Gap dir " + gap_dir, color.yellow);
addlabel(1, "Gap count " + gap_cnt, (if gap_dir > 0 then color.green else color.red));
#
