CCI Upper Bands with Volatility Squeeze for ThinkorSwim

[chewie76]

This is the CCI on the upper chart using 100 and 150 levels as bands. It also indicates squeezes in volatility. These squeezes are highlighted in cyan color bars, shaded areas, and cyan dots. Below is the SPY on a 1 hour chart. Notice the squeeze zones and the breakouts. These are good areas to place a straddle option trade as you know a move will take place, but not sure what direction. The sensitivity of the squeezes can be adjusted in the setting. Default is 0.618.

Color bars can be turned off in the settings. You can also turn off the bands in the settings.

#-----------------------------------------------
# CCI Upper Chart Bands Indicator
# Shows price bands corresponding to CCI = +150/+100/0/-100/-150
# Assembled by Chewie 10/2025
#-----------------------------------------------

input colorbar = no;
input length = 14;
input first = yes;
input second = yes;
input price = close;

# --- CCI Levels ---
input cciHigh = 100;
input cciLow = -100;
input cciHigh2 = 150;
input cciLow2 = -150;
input cciMid = 0;

#-----------------------------------------------
# Core CCI and Derived Bands
#-----------------------------------------------
def mean = Average(price, length);
def dev = Average(AbsValue(price - mean), length);

# Convert CCI levels into price levels
def bandHigh  = mean + cciHigh  * 0.015 * dev;
def bandLow   = mean + cciLow   * 0.015 * dev;
def bandHigh2 = mean + cciHigh2 * 0.015 * dev;
def bandLow2  = mean + cciLow2  * 0.015 * dev;
def bandMid   = mean + cciMid   * 0.015 * dev;

#-----------------------------------------------
# Plot CCI Price Bands
#-----------------------------------------------
plot CCIu  = if first then bandHigh  else Double.NaN;
plot CCId  = if first then bandLow   else Double.NaN;
plot CCIu2 = if second then bandHigh2 else Double.NaN;
plot CCId2 = if second then bandLow2  else Double.NaN;
plot CCIm  = bandMid;

CCIu.SetDefaultColor(Color.RED);
CCId.SetDefaultColor(Color.GREEN);
CCIu2.SetDefaultColor(Color.RED);
CCId2.SetDefaultColor(Color.GREEN);
CCIm.SetDefaultColor(Color.YELLOW);
ccim.setlineWeight(2);

#-----------------------------------------------
# Optional Clouds between Bands
#-----------------------------------------------
AddCloud(CCIu2, CCIu, Color.DARK_RED, Color.DARK_RED);
AddCloud(CCId, CCId2, Color.DARK_GREEN, Color.DARK_GREEN);


#-----------------------------------------------
# Optional Bar Coloring by CCI Level
#-----------------------------------------------
def CCI = if dev != 0 then (price - mean) / (0.015 * dev) else 0;

#AssignPriceColor(
#    if !colorbar then Color.CURRENT
 #   else if CCI >= cciHigh2 then Color.RED
  #  else if CCI >= cciHigh then Color.DARK_RED
   # else if CCI <= cciLow2 then Color.GREEN
    #else if CCI <= cciLow then Color.DARK_GREEN
    #else Color.gray);



#-----------------------------------------------
# Band Squeeze Detection
#-----------------------------------------------

input squeezeThreshold = 0.618;  # 0.5 = very sensitive, 1.0 = only tightest periods

def bandWidth = bandHigh2 - bandLow2;   # Total distance between outer bands
def avgWidth = Average(bandWidth, length);  # Smooth average width
def squeeze = bandWidth < avgWidth * squeezeThreshold;  # "Tight" if less than 75% of normal width

# Optional visual marker
plot SqueezeSignal = if squeeze then bandMid else Double.NaN;
SqueezeSignal.SetPaintingStrategy(PaintingStrategy.POINTS);
SqueezeSignal.SetDefaultColor(Color.CYAN);
SqueezeSignal.SetLineWeight(3);

# Optional background color highlight
AddCloud(
    if squeeze then bandHigh else Double.NaN,
    if squeeze then bandLow else Double.NaN,
    Color.GRAY,
    Color.GRAY
);

AssignPriceColor(
    if squeeze then Color.CYAN
    else if !colorbar then Color.CURRENT
    else if CCI >= cciHigh2 then Color.RED
    else if CCI >= cciHigh then Color.DARK_RED
    else if CCI <= cciLow2 then Color.GREEN
    else if CCI <= cciLow then Color.DARK_GREEN
    else Color.GRAY
);

# END CODE

 

[antwerks]

How to Read It

• When price touches or breaks above the +150 (red) band → strong upside momentum or potential exhaustion.
• When price touches or breaks below the –150 (green) band → strong downside momentum or potential exhaustion.
• The yellow midline (0 CCI) is your mean reversion anchor.
• The clouds between ±100/±150 bands show momentum zones:
  • Red cloud above = overbought/momentum expansion zone.
  • Green cloud below = oversold/momentum expansion zone.

Trading Ideas and Tactics
1. Mean Reversion Trades
This is the classic way to use CCI-type bands.

• Setup:
  • Price extends into red (above +100 or +150) or green (below –100 or –150) cloud.
  • Wait for a rejection candle or cross back inside the cloud.
• Trade:
  • Short after a rejection from the red zone.
  • Long after a rejection from the green zone.
• Exit: at the yellow midline (mean level).
  This approach assumes the move is overextended and due to revert.

2. Momentum Continuation Trades
If you prefer trend trading:

• Setup:
  • Price closes above +150 with rising volume → breakout continuation.
  • Price closes below –150 → breakdown continuation.
• Trade:
  • Enter with the direction of the move (buy strength, short weakness).
  • Place stop-loss just inside the ±100 band.
• Exit: when price crosses back into the neutral (gray) zone or hits the opposite ±100 band.

This approach assumes the move is expanding volatility, not reverting.

3. Confluence Trading (Best Practice)
Combine this CCI Bands indicator with:

• Trend filter (e.g., 21 EMA or VWAP) — only take longs above it, shorts below it.
• Volume confirmation — look for expansion as price exits ±100 zones.
• Momentum tools — like RSI or MACD confirming direction.

That helps you distinguish trend continuation from false reversals.

Quick Reference Table

Signal Type	Zone	Bias	Entry Trigger	Exit Target
Overbought reversal	Above +100/+150	Bearish	Close back below band	Midline
Oversold reversal	Below –100/–150	Bullish	Close back above band	Midline
Bullish breakout	Above +150	Bullish	Strong close + volume	Pullback or –100 band
Bearish breakout	Below –150	Bearish	Strong close + volume	Pullback or +100 band

 

[antwerks]

This is the CCI on the upper chart using 100 and 150 levels as bands. I like the 8 period length, but adjust as you see fit. Below is the SPX on a 5 minute chart. Color bars can be turned off in the settings. You can also turn off the bands in the settings.

View attachment 25920

#-----------------------------------------------
# CCI Upper Chart Bands Indicator
# Shows price bands corresponding to CCI = +150/+100/0/-100/-150
# Assembled by Chewie 10/2025
#-----------------------------------------------

input colorbar = yes;
input length = 8;
input first = yes;
input second = yes;
input price = close;

# --- CCI Levels ---
input cciHigh = 100;
input cciLow = -100;
input cciHigh2 = 150;
input cciLow2 = -150;
input cciMid = 0;

#-----------------------------------------------
# Core CCI and Derived Bands
#-----------------------------------------------
def mean = Average(price, length);
def dev = Average(AbsValue(price - mean), length);

# Convert CCI levels into price levels
def bandHigh  = mean + cciHigh  * 0.015 * dev;
def bandLow   = mean + cciLow   * 0.015 * dev;
def bandHigh2 = mean + cciHigh2 * 0.015 * dev;
def bandLow2  = mean + cciLow2  * 0.015 * dev;
def bandMid   = mean + cciMid   * 0.015 * dev;

#-----------------------------------------------
# Plot CCI Price Bands
#-----------------------------------------------
plot CCIu  = if first then bandHigh  else Double.NaN;
plot CCId  = if first then bandLow   else Double.NaN;
plot CCIu2 = if second then bandHigh2 else Double.NaN;
plot CCId2 = if second then bandLow2  else Double.NaN;
plot CCIm  = bandMid;

CCIu.SetDefaultColor(Color.DARK_RED);
CCId.SetDefaultColor(Color.DARK_GREEN);
CCIu2.SetDefaultColor(Color.RED);
CCId2.SetDefaultColor(Color.GREEN);
CCIm.SetDefaultColor(Color.YELLOW);

#-----------------------------------------------
#  Clouds between Bands
#-----------------------------------------------
AddCloud(CCIu2, CCIu, Color.DARK_RED, Color.DARK_RED);
AddCloud(CCId, CCId2, Color.DARK_GREEN, Color.DARK_GREEN);


#-----------------------------------------------
# Optional Bar Coloring by CCI Level
#-----------------------------------------------
def CCI = if dev != 0 then (price - mean) / (0.015 * dev) else 0;

AssignPriceColor(
    if !colorbar then Color.CURRENT
    else if CCI >= cciHigh2 then Color.RED
    else if CCI >= cciHigh then Color.DARK_RED
    else if CCI <= cciLow2 then Color.GREEN
    else if CCI <= cciLow then Color.DARK_GREEN
    else Color.gray);

# END CODE

Here is a scanner for bullish stocks meeting the CCI_Bands extreme conditions
https://tos.mx/!RL4gOif9