capture the low (or the high) of the bar preceding the bar in which my AddOrder() is fired

[MitchInSF]

Ok, I give. I'm tired and I can't figure it out. I would like to capture the low (or the high) of the bar preceding the bar in which my AddOrder() is fired and use that as a stop for said order.

def longEntry = close > open; #simple example
def stopLevel = "the low of the bar prior to the bar in which close > open" <-- how the heck do i capture this?

AddOrder(OrderType.BUY_TO_OPEN, longEntry , close, 2, Color.WHITE, Color.WHITE, "LONG: " + close);

AddOrder(OrderType.SELL_TO_CLOSE, low < stopLevel, close, 2, Color.WHITE, Color.WHITE, "LONG STOP @ " + close + " for " + (close-EntryPrice()) + "pts");

 

[maverickmitch]

Here you go

https://tos.mx/zEejC7r

FYI The low candle stop loss of the candle will update every time there is a PPS up signal, so it may update while you are in a trade if you get another buy signal.

Cool name btw

## STRATEGY

def ArrowBuy = if PPS()."BuySignal" is true then 1 else 0;
def ArrowBuyExit = if PPS()."SellSignal" is true then 1 else 0;

def Long_Entry = ArrowBuy >= 1;

## RISK MANAGEMENT

def LongStopCriteria = low; #I USE --> low - (2*ticksize());

def LongStopLoss;
def LongLow = if Long_Entry then LongStopCriteria else LongLow[1];
if Long_Entry {
LongStopLoss = LongStopCriteria;
} else if low < LongLow {
LongStopLoss = Double.NaN;
} else {
LongStopLoss = LongStopLoss[1];
}
plot EntryLow = LongStopLoss;

EntryLow.setPaintingStrategy(paintingStrategy.DASHES);

def StoppedLong = if low < LongStopLoss[1] then 1 else Double.NaN;



## ORDER EXIT

def Long_Exit = ArrowBuyExit + StoppedLong >= 1;

def GoLong;
if Long_Entry is true {
GoLong = yes;
} else if Long_Exit is true {
GoLong = no;
} else {
GoLong = GoLong[1];
}
plot LongEntry = GoLong and !GoLong[1];

def ExitLong;
if Long_Exit is true {
ExitLong = yes;
} else if Long_Entry is true {
ExitLong = no;
} else {
ExitLong = ExitLong[1];
}
plot LongExit = ExitLong and !ExitLong[1];

LongEntry.SetPaintingStrategy(PaintingStrategy.BOOLEAN_ARROW_UP);
LongExit.SetPaintingStrategy(PaintingStrategy.BOOLEAN_ARROW_DOWN);

LongEntry.SetLineWeight(5);
LongExit.SetLineWeight(5);

LongEntry.SetDefaultColor(Color.GREEN);
LongExit.SetDefaultColor(Color.YELLOW);


AddOrder(OrderType.BUY_TO_OPEN, LongEntry, tickcolor = Color.GREEN, arrowcolor = Color.GREEN, name = "BUY");
AddOrder(OrderType.SELL_TO_CLOSE, LongExit, tickcolor = Color.WHITE, arrowcolor = Color.WHITE, name = "EXIT");

 

[MitchInSF]

Well, Howdy, Mitch! Just saw the update here. Thanks for the idea! Sadly, I need to revisit cuz I tripped on this too late in the evening. Was just saying earlier today that I need 48 hour days.